lfinim.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfinim_fort                             &
&                     (lfi, krep, knumer, knimes )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        CE SOUS-PROGRAMME PERMET D'AJUSTER LE NIVEAU DE MESSAGERIE
!     PROPRE AUX ACTIONS FAITES SUR UN FICHIER PARTICULIER, OUVERT POUR
!     LE LOGICIEL LFI.
!        CEPENDANT, TANT QUE LE NIVEAU DE MESSAGERIE GLOBAL *LFI%NIMESG*
!     VAUT 0 OU 2, LE NIVEAU PROPRE AU FICHIER EST INOPERANT.
!     *LFI%NIMESG* VAUT PAR DEFAUT 1, ET EST REGLABLE VIA LE S/P "LFINMG".
!**
!     ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                 KNUMER (ENTREE) ==> LFI%NUMERO D'UNITE LOGIQUE CONCERNEE;
!                 KNIMES (ENTREE) ==> NIVEAU DE MESSAGERIE SOUHAITE.
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KREP, KNUMER, KNIMES, IRANG
INTEGER (KIND=JPLIKB) IREP, INIMES, INIMEX
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFINIM_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
inimex=0
!
IF (irang.EQ.0) THEN
  irep=-1
ELSEIF (knimes.GE.0.AND.knimes.LE.2) THEN
  inimex=ixnims(irang)
  lfi%NIVMES(irang)=knimes
  lfi%NDEROP(irang)=5
  irep=0
ELSE
  irep=-2
ENDIF
!
krep=irep
llfata=llmoer(irep,irang)
!
IF (llfata.OR.max(ixnims(irang),inimex).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFINIM_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFINIM'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', KNIMES='',I3)') krep,knumer,knimes
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFINIM_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfinim_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfinim64              &
&           (krep, knumer, knimes)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  KNIMES                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfinim_fort                       &
&           (lfi, krep, knumer, knimes)

END SUBROUTINE lfinim64

SUBROUTINE lfinim                &
&           (krep, knumer, knimes)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KNIMES                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfinim_mt                        &
&           (lfi, krep, knumer, knimes)

END SUBROUTINE lfinim

SUBROUTINE lfinim_mt                  &
&           (lfi, krep, knumer, knimes)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KNIMES                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  INIMES                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
inimes     = int(    knimes, jplikb)

CALL lfinim_fort                       &
&           (lfi, irep, inumer, inimes)

krep       = int(      irep, jplikm)

END SUBROUTINE lfinim_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF KNIMES        IN