lfilec.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfilec_fort                                          &
&                     (lfi, krep, knumer, cdnoma, ktab, klong )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        SOUS-PROGRAMME DE LECTURE D'UN ARTICLE (DE DONNEES) PAR *NOM*
!     SUR UNE UNITE LOGIQUE OUVERTE POUR LE LOGICIEL DE FICHIERS INDEXES
!     *LFI*; L'ARTICLE EN SORTIE EST UN "BLOC" DE DONNEES ADJACENTES.
!**
!    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                KNUMER (ENTREE) ==> LFI%NUMERO DE L'UNITE LOGIQUE;
!                CDNOMA (ENTREE) ==> NOM DE L'ARTICLE A RECHERCHER;
!                KTAB   (ENTREE) ==> PREMIER MOT A LIRE;
!                KLONG  (ENTREE) ==> LONGUEUR DE L'ARTICLE A LIRE.
!
!
TYPE(lficom) :: LFI
CHARACTER CDNOMA*(*), CLNOMA*(lfi%jpncpn)
!
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLONG
INTEGER (KIND=JPLIKB)  KTAB (klong)
INTEGER (KIND=JPLIKB) IREP, IRANG, ILCLNO, IREPX, ILCDNO 
INTEGER (KIND=JPLIKB) IDECBL, IPOSBL, IARTEX
INTEGER (KIND=JPLIKB) ILONEX, IRGPIM, IRGPIF, IPOSEX 
INTEGER (KIND=JPLIKB) IRETIN, INIMES, INBALO
!
LOGICAL LLVERF
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, garantissant l'initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFILEC_FORT',0,zhook_handle)

clacti=''

CALL lfinum_fort                    &
&               (lfi, knumer,irang)
llverf=.false.
irep=0
irepx=0
ilcdno=int(len(cdnoma), jplikb)
!
IF (ilcdno.LE.0) THEN
  irep=-15
  clnoma=lfi%CHINCO(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  GOTO 1001
ELSEIF (cdnoma.EQ.' ') THEN
  irep=-18
  clnoma=' '
  ilclno=1
  GOTO 1001
ENDIF
!
!        Recherche de la longueur "utile" du nom d'article specifie.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
101 CONTINUE
iposbl=idecbl+int(index(cdnoma(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilclno=ilcdno
ELSEIF (cdnoma(iposbl:).EQ.' ') THEN
  ilclno=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 101
ENDIF
!
IF (ilclno.LE.lfi%JPNCPN) THEN
  clnoma=cdnoma(:ilclno)
ELSE
  clnoma=cdnoma(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  irep=-15
  GOTO 1001
ENDIF
!
IF (klong.LE.0) THEN
  irep=-14
  GOTO 1001
ELSEIF (irang.EQ.0) THEN
  irep=-1
  GOTO 1001
ENDIF
!
 IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                (lfi, lfi%VERRUE(irang),'ON')
llverf=lfi%LMULTI
!
iartex=0
ilonex=0
inbalo=lfi%MDES1D(ixm(lfi%JPNALO,irang))
!
IF (inbalo.NE.0) THEN
!**
!     2.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DE L'ARTICLE LOGIQUE DEMANDE.
!-----------------------------------------------------------------------
!
  CALL lfiran_fort                                  &
&                 (lfi, irep,irang,clnoma(:ilclno), &
&                  irgpim,iartex,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
IF (iartex.EQ.0) THEN
  irep=-20
  clacti=clnoma(:ilclno)
  GOTO 1001
ENDIF
!
!        ON COMPLETE LES CARACTERISTIQUES DE L'ARTICLE.
!
irgpif=lfi%MRGPIF(irgpim)
!
IF (.NOT.lfi%LPHASP(irgpim)) THEN
!
  CALL lfipha_fort                                &
&                 (lfi, irep,irang,irgpim,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
ilonex=lfi%MLGPOS(ixm(2*iartex-1,irgpim))
iposex=lfi%MLGPOS(ixm(2*iartex,irgpim))
!
!       CONTROLE CROISE ENTRE LONGUEURS DEMANDEE ET TROUVEE SUR FICHIER.
!
IF (ilonex.GT.klong) THEN
  irep=-21
  llfata=llmoer(irep,irang)
!
  IF (llfata) THEN
    clacti=clnoma(:ilclno)
    GOTO 1001
  ENDIF
!
!        SI L'ERREUR (-21) N'A PAS ETE FATALE, ON VA LIRE SEULEMENT
!       LE DEBUT DE L'ARTICLE ( LECTURE PARTIELLE DE *KLONG* MOTS )
!
ELSEIF (ilonex.LT.klong) THEN
  irep=-22
  clacti=clnoma(:ilclno)
  GOTO 1001
ENDIF
!
irepx=irep
!**
!     3.  -  LECTURE DES DONNEES PROPREMENT DITE.
!-----------------------------------------------------------------------
!
CALL lfiled_fort                                                  &
&               (lfi, irep,irang,ktab,klong,irgpim,iposex,iretin)
!
IF (iretin.EQ.1) THEN
  GOTO 903
ELSEIF (iretin.EQ.2) THEN
  GOTO 904
ELSEIF (iretin.NE.0) THEN
  GOTO 1001
ENDIF
!
irep=irepx
!**
!     4.  -   MISE A JOUR DE STATISTIQUES ET DE TABLES.
!-----------------------------------------------------------------------
!
lfi%NBLECT(irang)=lfi%NBLECT(irang)+1
lfi%NBMOLU(irang)=lfi%NBMOLU(irang)+klong
lfi%NDERGF(irang)=lfi%JPNAPP*lfi%MFACTM(irang)*(irgpif-1)+iartex
lfi%CNDERA(irang)=clnoma(:ilclno)
lfi%NSUIVF(irang)=lfi%JPNIL
lfi%NPRECF(irang)=lfi%JPNIL
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!-----------------------------------------------------------------------
!
903 CONTINUE
clacti='WRITE'
GOTO 909
!
904 CONTINUE
clacti='READ'
!
909 CONTINUE
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (irang.NE.0) THEN
  lfi%NDEROP(irang)=2
  lfi%NDERCO(irang)=irep
   IF (llverf) CALL lfiver_fort                               &
&                              (lfi, lfi%VERRUE(irang),'OFF')
ENDIF
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFILEC_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFILEC'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', CDNOMA='''''',A,'''''', KLONG='',I7)')       &
&     krep,knumer,clnoma(:ilclno),klong
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFILEC_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixm.h"
#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfilec_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfilec64                           &
&           (krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKB)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfilec_fort                                    &
&           (lfi, krep, knumer, cdnoma, ktab, klong)

END SUBROUTINE lfilec64

SUBROUTINE lfilec                             &
&           (krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfilec_mt                                     &
&           (lfi, krep, knumer, cdnoma, ktab, klong)

END SUBROUTINE lfilec

SUBROUTINE lfilec_mt                               &
&           (lfi, krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILONG                                  ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
ilong      = int(     klong, jplikb)

CALL lfilec_fort                                    &
&           (lfi, irep, inumer, cdnoma, ktab, ilong)

krep       = int(      irep, jplikm)

END SUBROUTINE lfilec_mt

!INTF KREP            OUT                                                              
!INTF KNUMER        IN                                                                 
!INTF CDNOMA        IN                                                                 
!INTF KTAB          IN    DIMS=KLONG                     KIND=JPLIKB                   
!INTF KLONG         IN