lfilap.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfilap_fort                                          &
&                     (lfi, krep, knumer, cdnoma, ktab, klong )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        SOUS-PROGRAMME DE LECTURE DE L'ARTICLE (DE DONNEES) *PRECEDENT*
!     SUR UNE UNITE LOGIQUE OUVERTE POUR LE LOGICIEL DE FICHIERS INDEXES
!     *LFI*; L'ARTICLE EN SORTIE EST UN "BLOC" DE DONNEES ADJACENTES.
!
!               ( "PRECEDENT" = PRECEDENT LE DERNIER *LU* )
!**
!    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                KNUMER (ENTREE) ==> LFI%NUMERO DE L'UNITE LOGIQUE;
!                CDNOMA (SORTIE) ==> NOM DE L'ARTICLE LU; CETTE VARIABLE
!                                    DOIT ETRE ASSEZ LONGUE POUR STOCKER
!                                    LE NOM DE L'ARTICLE ( BLANCS EN FIN
!                                    DE NOM EXCLUS, CEPENDANT );
!                KTAB   (ENTREE) ==> PREMIER MOT A LIRE;
!                KLONG  (ENTREE) ==> LONGUEUR DE L'ARTICLE A LIRE.
!
!          IL EST CHAUDEMENT RECOMMANDE DE N'UTILISER CE SOUS-PROGRAMME
!     QU'APRES AVOIR CONTROLE, PAR APPEL PREALABLE AU SOUS-PROGRAMME
!     *LFICAP*, L'EXISTENCE D'UN ARTICLE LOGIQUE DE DONNEES "PRECEDENT".
!     SINON, IL FAUT PREVOIR DE GERER L'ERREUR DE CODE (-26) ...
!     ENTRE AUTRES.
!
!
TYPE(lficom) :: LFI
CHARACTER CDNOMA*(*), CLNOMA*(lfi%jpncpn)
!
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLONG
INTEGER (KIND=JPLIKB)  KTAB (klong)
INTEGER (KIND=JPLIKB) IREP, IRANG, ILCLNO, IRGPIM 
INTEGER (KIND=JPLIKB) IARTIC, IRGPIF, ILONEX, IREPX
INTEGER (KIND=JPLIKB) IPOSEX, IDECBL, IPOSBL, IRETIN 
INTEGER (KIND=JPLIKB) INIMES, ILCDNO, IRANGF
!
LOGICAL LLVERF
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, garantissant l'initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFILAP_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
llverf=.false.
irep=0
irepx=0
ilcdno=int(len(cdnoma), jplikb)
!
IF (ilcdno.LE.0) THEN
  irep=-15
  clnoma=lfi%CHINCO(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  GOTO 1001
ELSE
  cdnoma=' '
  clnoma=' '
  ilclno=1
ENDIF
!
IF (klong.LE.0) THEN
  irep=-14
  GOTO 1001
ELSEIF (irang.EQ.0) THEN
  irep=-1
  GOTO 1001
ENDIF
!
 IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                (lfi, lfi%VERRUE(irang),'ON')
llverf=lfi%LMULTI
!**
!     2.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DE L'ARTICLE LOGIQUE DEMANDE,
!            DEFINI PAR SON RANG "A PRIORI" DANS LE FICHIER.
!-----------------------------------------------------------------------
!
CALL lficaq_fort                                       &
&               (lfi, irep,irang,irgpim,iartic,iretin)
!
IF (iretin.EQ.1) THEN
  GOTO 903
ELSEIF (iretin.EQ.2) THEN
  GOTO 904
ELSEIF (iretin.NE.0) THEN
  GOTO 1001
ELSEIF (iartic.EQ.0) THEN
  irep=-23
  GOTO 1001
ENDIF
!*
!     2.1 -  ARTICLE DE DONNEES TROUVE... CONTROLES SUPPLEMENTAIRES.
!-----------------------------------------------------------------------
!
irgpif=lfi%MRGPIF(irgpim)
!
IF (.NOT.lfi%LPHASP(irgpim)) THEN
!
  CALL lfipha_fort                                &
&                 (lfi, irep,irang,irgpim,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
ilonex=lfi%MLGPOS(ixm(2*iartic-1,irgpim))
iposex=lfi%MLGPOS(ixm(2*iartic,irgpim))
clnoma=lfi%CNOMAR(ixc(iartic,irgpim))
!
!        Recherche de la longueur "utile" du nom d'article.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
211 CONTINUE
iposbl=idecbl+int(index(clnoma(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilclno=lfi%JPNCPN
ELSEIF (clnoma(iposbl:).EQ.' ') THEN
  ilclno=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 211
ENDIF
!
IF (ilcdno.GE.ilclno) THEN
  cdnoma=clnoma(:ilclno)
ELSE
  irep=-24
  clacti=clnoma
  GOTO 1001
ENDIF
!
IF (klong.LT.ilonex) THEN
  irep=-21
  llfata=llmoer(irep,irang)
!
  IF (llfata) THEN
    clacti=clnoma
    GOTO 1001
  ENDIF
!
!        SI L'ERREUR (-21) N'A PAS ETE FATALE, ON VA LIRE SEULEMENT
!       LE DEBUT DE L'ARTICLE ( LECTURE PARTIELLE DE *KLONG* MOTS )
!
ELSEIF (klong.GT.ilonex) THEN
  irep=-22
  clacti=clnoma
  GOTO 1001
ENDIF
!
irepx=irep
!**
!     3.  -  LECTURE DES DONNEES PROPREMENT DITE.
!-----------------------------------------------------------------------
!
CALL lfiled_fort                                                  &
&               (lfi, irep,irang,ktab,klong,irgpim,iposex,iretin)
!
IF (iretin.EQ.1) THEN
  GOTO 903
ELSEIF (iretin.EQ.2) THEN
  GOTO 904
ELSEIF (iretin.NE.0) THEN
  GOTO 1001
ENDIF
!
irep=irepx
irangf=lfi%JPNAPP*lfi%MFACTM(irang)*(irgpif-1)+iartic
!**
!     4.  -   MISE A JOUR DE STATISTIQUES ET DE TABLES.
!-----------------------------------------------------------------------
!
lfi%NBLECT(irang)=lfi%NBLECT(irang)+1
lfi%NBMOLU(irang)=lfi%NBMOLU(irang)+klong
lfi%NDERGF(irang)=irangf
lfi%CNDERA(irang)=clnoma
lfi%NSUIVF(irang)=lfi%JPNIL
lfi%NPRECF(irang)=lfi%JPNIL
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!-----------------------------------------------------------------------
!
903 CONTINUE
clacti='WRITE'
GOTO 909
!
904 CONTINUE
clacti='READ'
!
909 CONTINUE
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (irang.NE.0) THEN
  lfi%NDEROP(irang)=16
  lfi%NDERCO(irang)=irep
   IF (llverf) CALL lfiver_fort                               &
&                              (lfi, lfi%VERRUE(irang),'OFF')
ENDIF
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFILAP_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFILAP'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', CDNOMA='''''',A,'''''', KLONG='',I7)')       &
&     krep,knumer,clnoma(:ilclno),klong
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFILAP_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixc.h"
#include "lficom2.ixm.h"
#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfilap_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfilap64                           &
&           (krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 !   OUT
INTEGER (KIND=JPLIKB)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfilap_fort                                    &
&           (lfi, krep, knumer, cdnoma, ktab, klong)

END SUBROUTINE lfilap64

SUBROUTINE lfilap                             &
&           (krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 !   OUT
INTEGER (KIND=JPLIKM)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfilap_mt                                     &
&           (lfi, krep, knumer, cdnoma, ktab, klong)

END SUBROUTINE lfilap

SUBROUTINE lfilap_mt                               &
&           (lfi, krep, knumer, cdnoma, ktab, klong)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 !   OUT
INTEGER (KIND=JPLIKM)  KLONG                                  ! IN   
INTEGER (KIND=JPLIKB)  KTAB       (klong)                     ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILONG                                  ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
ilong      = int(     klong, jplikb)

CALL lfilap_fort                                    &
&           (lfi, irep, inumer, cdnoma, ktab, ilong)

krep       = int(      irep, jplikm)

END SUBROUTINE lfilap_mt

!INTF KREP            OUT                                                              
!INTF KNUMER        IN                                                                 
!INTF CDNOMA          OUT                                                              
!INTF KTAB          IN    DIMS=KLONG                     KIND=JPLIKB                   
!INTF KLONG         IN