lfierf.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfierf_fort                             &
&                     (lfi, krep, knumer, lderfa )
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        CE SOUS-PROGRAMME PERMET D'ACTIVER OU DE DESACTIVER L'OPTION
!     RENDANT FATALE TOUTE ERREUR DETECTEE SUR UN FICHIER PARTICULIER,
!     OUVERT POUR LE LOGICIEL LFI.
!        CEPENDANT, TANT QUE LE NIVEAU GLOBAL D'ERREUR FATALE *LFI%NERFAG*
!     VAUT 0 OU 2, L'OPTION PROPRE AU FICHIER EST INOPERANTE.
!     *LFI%NERFAG* VAUT PAR DEFAUT 1, ET EST REGLABLE VIA LE S/P "LFINEG".
!**
!     ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                 KNUMER (ENTREE) ==> LFI%NUMERO D'UNITE LOGIQUE CONCERNEE;
!                 LDERFA (ENTREE) ==> OPTION D'ERREUR FATALE (VRAI=OUI).
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KREP, KNUMER, IRANG, IREP, INIMES
!
LOGICAL LDERFA
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIERF_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
!
IF (irang.NE.0) THEN
  lfi%LERFAT(irang)=lderfa
  lfi%NDEROP(irang)=4
  irep=0
ELSE
  irep=-1
ENDIF
!
llfata=llmoer(irep,irang)
krep=irep
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFIERF_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFIERF'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', LDERFA= '',L1)') krep,knumer,lderfa
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFIERF_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfierf_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfierf64              &
&           (krep, knumer, lderfa)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
LOGICAL                LDERFA                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfierf_fort                       &
&           (lfi, krep, knumer, lderfa)

END SUBROUTINE lfierf64

SUBROUTINE lfierf                &
&           (krep, knumer, lderfa)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
LOGICAL                LDERFA                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfierf_mt                        &
&           (lfi, krep, knumer, lderfa)

END SUBROUTINE lfierf

SUBROUTINE lfierf_mt                  &
&           (lfi, krep, knumer, lderfa)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
LOGICAL                LDERFA                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lfierf_fort                       &
&           (lfi, irep, inumer, lderfa)

krep       = int(      irep, jplikm)

END SUBROUTINE lfierf_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF LDERFA        IN