lficas.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lficas_fort                                    &
&                     (lfi, krep, knumer, cdnoma, klong,  &
&                      kposex, ldavan)
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        SOUS-PROGRAMME DONNANT LES CARACTERISTIQUES ( NOM, LONGUEUR,
!     POSITION ) DE L'ARTICLE LOGIQUE *DE DONNEES* SUIVANT, SUR UNE
!     UNITE LOGIQUE OUVERTE POUR LE LOGICIEL DE FICHIERS INDEXES *LFI* .
!**
!    ARGUMENTS : KREP   (SORTIE) ==> CODE-REPONSE DU SOUS-PROGRAMME;
!                KNUMER (ENTREE) ==> LFI%NUMERO DE L'UNITE LOGIQUE;
!                CDNOMA (SORTIE) ==> NOM DE L'ARTICLE SUIVANT;
!                KLONG  (SORTIE) ==> LONGUEUR DE L'ARTICLE SUIVANT;
!                KPOSEX (SORTIE) ==> POSITION ( DANS LE FICHIER, DU PRE-
!                                    MIER MOT ) DE L'ARTICLE SUIVANT;
!                LDAVAN (ENTREE) ==> VRAI SI ON DOIT "AVANCER" LE
!                                    POINTEUR DU FICHIER.
!
!     SI L'ON SOUHAITE LIRE ENSUITE L'ARTICLE EN QUESTION (VIA *LFILAS*)
!     IL FAUT PRECISER A L'APPEL LDAVAN=.FALSE. ; LDAVAN=.TRUE. SERT
!     ESSENTIELLEMENT A ANALYSER LE CONTENU DU FICHIER EN TERMES
!     D'ARTICLES LOGIQUES, SANS LIRE LES DONNEES.
!
!     SI LE FICHIER EST VIDE OU QUE LE DERNIER ARTICLE LOGIQUE LU ETAIT
!     LE DERNIER, LE SOUS-PROGRAMME "RETOURNE" KLONG=0, ET CDNOMA=' ' .
!
!
TYPE(lficom) :: LFI
CHARACTER CDNOMA*(*), CLNOMA*(lfi%jpncpn)
!
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLONG, KPOSEX 
INTEGER (KIND=JPLIKB) IREP, ILCDNO, IDECBL, IPOSBL
INTEGER (KIND=JPLIKB) ILCLNO, IRANG, IRGPIM, IARTIC 
INTEGER (KIND=JPLIKB) IRGPIF, INIMES, IRETIN
!
LOGICAL LDAVAN, LLVERF
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, garantissant l'initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFICAS_FORT',0,zhook_handle)
clacti=''
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
llverf=.false.
irep=0
klong=0
kposex=0
ilcdno=int(len(cdnoma), jplikb)
!
IF (ilcdno.LE.0) THEN
  irep=-15
  clnoma=lfi%CHINCO(:lfi%JPNCPN)
  ilclno=lfi%JPNCPN
  GOTO 1001
ELSE
  cdnoma=' '
  clnoma=' '
  ilclno=1
ENDIF
!
IF (irang.EQ.0) THEN
  irep=-1
  GOTO 1001
ENDIF
!
 IF (lfi%LMULTI) CALL lfiver_fort                              &
&                                (lfi, lfi%VERRUE(irang),'ON')
llverf=lfi%LMULTI
!**
!     2.  -  EXPLORATION DES (PAIRES DE) PAGES ET ARTICLES D'INDEX,
!            A LA RECHERCHE DE L'ARTICLE LOGIQUE DEMANDE,
!            DEFINI PAR SON RANG "A PRIORI" DANS LE FICHIER.
!-----------------------------------------------------------------------
!
CALL lficax_fort                                       &
&               (lfi, irep,irang,irgpim,iartic,iretin)
!
IF (iretin.EQ.1) THEN
  GOTO 903
ELSEIF (iretin.EQ.2) THEN
  GOTO 904
ELSEIF (iretin.NE.0.OR.iartic.EQ.0) THEN
  GOTO 1001
ENDIF
!*
!     2.1 -  ARTICLE DE DONNEES TROUVE... APRES CONTROLES SUPPLEMENTAI-
!            RES, ON RETOURNE SES CARACTERISTIQUES.
!-----------------------------------------------------------------------
!
irgpif=lfi%MRGPIF(irgpim)
!
IF (.NOT.lfi%LPHASP(irgpim)) THEN
!
  CALL lfipha_fort                                &
&                 (lfi, irep,irang,irgpim,iretin)
!
  IF (iretin.EQ.1) THEN
    GOTO 903
  ELSEIF (iretin.EQ.2) THEN
    GOTO 904
  ELSEIF (iretin.NE.0) THEN
    GOTO 1001
  ENDIF
!
ENDIF
!
klong=lfi%MLGPOS(ixm(2*iartic-1,irgpim))
kposex=lfi%MLGPOS(ixm(2*iartic,irgpim))
clnoma=lfi%CNOMAR(ixc(iartic,irgpim))
!
!        Recherche de la longueur "utile" du nom d'article.
!        (c'est-a-dire sans tenir compte des blancs terminaux eventuels)
!
idecbl=0
!
211 CONTINUE
iposbl=idecbl+int(index(clnoma(idecbl+1:),' '), jplikb)
!
IF (iposbl.LE.idecbl) THEN
  ilclno=lfi%JPNCPN
ELSEIF (clnoma(iposbl:).EQ.' ') THEN
  ilclno=iposbl-1
ELSE
  idecbl=iposbl
  GOTO 211
ENDIF
!
IF (ilcdno.GE.ilclno) THEN
  cdnoma=clnoma(:ilclno)
ELSE
  irep=-24
  clacti=clnoma
  GOTO 1001
ENDIF
!
IF (ldavan) THEN
!
!          ON AVANCE LE "POINTEUR" DU FICHIER...
!       ET ON REINITIALISE LES "POINTEURS" SUIVANT ET PRECEDENT.
!
  lfi%NDERGF(irang)=lfi%JPNAPP*lfi%MFACTM(irang)*(irgpif-1)+iartic
  lfi%CNDERA(irang)=clnoma
  lfi%NSUIVF(irang)=lfi%JPNIL
  lfi%NPRECF(irang)=lfi%JPNIL
ENDIF
!
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTES DE BRANCHEMENT EN CAS D'ERREUR E/S.
!-----------------------------------------------------------------------
!
903 CONTINUE
clacti='WRITE'
GOTO 909
!
904 CONTINUE
clacti='READ'
!
909 CONTINUE
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (irang.NE.0) THEN
  lfi%NDEROP(irang)=11
  lfi%NDERCO(irang)=irep
   IF (llverf) CALL lfiver_fort                               &
&                              (lfi, lfi%VERRUE(irang),'OFF')
ENDIF
!
IF (llfata.OR.ixnims(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('LFICAS_FORT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='LFICAS'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3,        &
&    '', CDNOMA='''''',A,'''''', KLONG='',I7,'', KPOSEX='',I8, &
&    '', LDAVAN= '',L1)')                                      &
&  krep,knumer,clnoma(:ilclno),klong,kposex,ldavan
CALL lfiems_fort                                 &
&               (lfi, knumer,inimes,irep,llfata, &
&                clmess,clnspr,clacti)
!
IF (lhook) CALL dr_hook('LFICAS_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixc.h"
#include "lficom2.ixm.h"
#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lficas_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lficas64                                     &
&           (krep, knumer, cdnoma, klong, kposex, ldavan)
USE lfimod, ONLY : lfi => lficom_default, &
&                  lficom_default_init,   &
&                  new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 !   OUT
INTEGER (KIND=JPLIKB)  KLONG                                  !   OUT
INTEGER (KIND=JPLIKB)  KPOSEX                                 !   OUT
LOGICAL                LDAVAN                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lficas_fort                                              &
&           (lfi, krep, knumer, cdnoma, klong, kposex, ldavan)

END SUBROUTINE lficas64

SUBROUTINE lficas                                       &
&           (krep, knumer, cdnoma, klong, kposex, ldavan)
USE lfimod, ONLY : lfi => lficom_default, &
&                  lficom_default_init,   &
&                  new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 !   OUT
INTEGER (KIND=JPLIKM)  KLONG                                  !   OUT
INTEGER (KIND=JPLIKM)  KPOSEX                                 !   OUT
LOGICAL                LDAVAN                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lficas_mt                                               &
&           (lfi, krep, knumer, cdnoma, klong, kposex, ldavan)

END SUBROUTINE lficas

SUBROUTINE lficas_mt                                         &
&           (lfi, krep, knumer, cdnoma, klong, kposex, ldavan)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 !   OUT
INTEGER (KIND=JPLIKM)  KLONG                                  !   OUT
INTEGER (KIND=JPLIKM)  KPOSEX                                 !   OUT
LOGICAL                LDAVAN                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILONG                                  !   OUT
INTEGER (KIND=JPLIKB)  IPOSEX                                 !   OUT
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL lficas_fort                                              &
&           (lfi, irep, inumer, cdnoma, ilong, iposex, ldavan)

krep       = int(      irep, jplikm)
klong      = int(     ilong, jplikm)
kposex     = int(    iposex, jplikm)

END SUBROUTINE lficas_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF CDNOMA          OUT 
!INTF KLONG           OUT 
!INTF KPOSEX          OUT 
!INTF LDAVAN        IN