lfiafm.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe LFI

SUBROUTINE lfiafm_fort                             &
&                     (lfi, krep, knumer, kfactm)
USE lfimod, ONLY : lficom
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Sous-Programme permettant d'Attribuer un Facteur Multiplicatif
!     a une Unite Logique FORTRAN, destinee a etre ouverte
!     ULTERIEUREMENT par le Logiciel de Fichiers Indexes *LFI* .
!        Lors de cette ouverture ulterieure, LFIOUV essaiera de traiter
!     l'unite logique consideree comme un fichier a acces direct
!     non formatte de longueur d'article "Physique" LFI%JPLARD*KFACTM mots.
!**
!    ARGUMENTS : KREP   (Sortie) ==> Code-REPonse du sous-programme;
!                KNUMER (Entree) ==> NUMero de l'unite logique;
!                KFACTM (Entree) ==> FACteur Multiplicatif a attribuer.
!
!
TYPE(lficom) :: LFI
INTEGER (KIND=JPLIKB) KREP, KNUMER, KFACTM, IRANG 
INTEGER (KIND=JPLIKB) IREP, IRANFM, INIMES, IFACTM
!
LOGICAL LLVERG, LLEXUL
!
CHARACTER(LEN=LFI%JPLSPX) CLNSPR
CHARACTER(LEN=LFI%JPLMES) CLMESS
CHARACTER(LEN=LFI%JPLFTX) CLACTI
LOGICAL LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, INITIALISATIONS.
!-----------------------------------------------------------------------
!
!        Appel legerement anticipe a LFINUM, permettant une initialisa-
!     tion des variables globales du logiciel a la 1ere utilisation.
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('LFIAFM_FORT',0,zhook_handle)
clacti=''
ifactm=kfactm
llverg=.false.
CALL lfinum_fort                    &
&               (lfi, knumer,irang)
!
IF (kfactm.LE.0) THEN
  irep=-14
  GOTO 1001
ELSEIF (kfactm.GT.lfi%JPFACX) THEN
  irep=-28
  GOTO 1001
ELSEIF (irang.NE.0) THEN
  irep=-5
  GOTO 1001
ENDIF
!
!        Controle de validite FORTRAN du Numero d'Unite Logique.
!
IF (knumer > 0) THEN
  INQUIRE (unit=knumer,exist=llexul,err=901,iostat=irep)
ELSE
  llexul=.true.
ENDIF
!
IF (.NOT.llexul) THEN
  irep=-30
  GOTO 1001
ENDIF
!
!              Verrouillage Global eventuel.
!
 IF (lfi%LMULTI) CALL lfiver_fort                       &
&                                (lfi, lfi%VERGLA,'ON')
llverg=lfi%LMULTI
!**
!     2.  -  TRAVAIL EFFECTIF SUR LES TABLES DECRIVANT LES ASSOCIATIONS
!            UNITES LOGIQUES/FACTEURS.
!-----------------------------------------------------------------------
!
CALL lfifmp_fort                     &
&               (lfi, knumer,iranfm)
!
IF (iranfm.NE.0) THEN
!
!          Redefinition du facteur multiplicatif.
!
  ifactm=lfi%MFACTU(iranfm)
ELSEIF (lfi%NULOFM.GE.lfi%JPXUFM) THEN
!
!          Tables pleines...
!
  irep=-29
  GOTO 1001
ELSE
!
!          Cas standard.
!
  lfi%NULOFM=lfi%NULOFM+1
  iranfm=lfi%NULOFM
  lfi%MULOFM(iranfm)=knumer
  ifactm=kfactm
ENDIF
!
lfi%MFACTU(iranfm)=kfactm
irep=0
GOTO 1001
!**
!     9.  - CI-DESSOUS, ETIQUETTE DE BRANCHEMENT EN CAS D'ERREUR INQUIRE
!-----------------------------------------------------------------------
!
901 CONTINUE
clacti='INQUIRE'
!
!      AU CAS OU, ON FORCE LE CODE-REPONSE ENTREE/SORTIE A ETRE POSITIF.
!
irep=abs(irep)
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "LFIEMS" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
IF (llverg) CALL lfiver_fort                        &
&                           (lfi, lfi%VERGLA,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSEIF (irang.EQ.0) THEN
  inimes=lfi%NIMESG
ELSE
  inimes=ixnims(irang)
ENDIF
!
IF (inimes.EQ.0)  THEN 
  IF (lhook) CALL dr_hook('LFIAFM_FORT',1,zhook_handle)
  RETURN
ENDIF
clnspr='LFIAFM'
!
IF (inimes.EQ.2) THEN
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&         '', KFACTM='',I4)') krep,knumer,kfactm
  CALL lfiems_fort                                 &
&                 (lfi, knumer,inimes,irep,llfata, &
&                  clmess,clnspr,clacti)
ENDIF
!
IF (ifactm.EQ.kfactm) THEN
!
  IF (lfi%LFRANC) THEN
    WRITE (unit=clmess,fmt=                                &
&           '(''Attribution du Facteur Multiplicatif'',I3,  &
&             '' a l''''Unite Logique'',I3)') kfactm,knumer
  ELSE
    WRITE (unit=clmess,fmt='(''Multiply Factor'',I3, &
&           '' specified for Logical Unit'',          &
&             I3)') kfactm,knumer
  ENDIF
!
  CALL lfiems_fort                                         &
&                 (lfi, knumer,inimes,irep,.false.,clmess, &
&                  clnspr,clacti)
ELSE
!
  IF (lfi%LFRANC) THEN
    WRITE (unit=clmess,fmt='(''Unite Logique'',I3,               &
&           '': *NOUVEAU* Facteur Multiplicatif attribue='',I3)') &
&    knumer,kfactm
  ELSE
    WRITE (unit=clmess,fmt='(''Logical Unit'',I3,       &
&           '': *NEW* Multiply Factor specified='',I3)') &
&    knumer,kfactm
  ENDIF
!
  CALL lfiems_fort                                  &
&                 (lfi, knumer,inimes,irep,.false., &
&                  clmess,clnspr,clacti)
ENDIF
!
IF (lhook) CALL dr_hook('LFIAFM_FORT',1,zhook_handle)

CONTAINS

#include "lficom2.ixnims.h"
#include "lficom2.llmoer.h"

END SUBROUTINE lfiafm_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE lfiafm64              &
&           (krep, knumer, kfactm)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  KFACTM                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiafm_fort                       &
&           (lfi, krep, knumer, kfactm)

END SUBROUTINE lfiafm64

SUBROUTINE lfiafm                &
&           (krep, knumer, kfactm)
USE lfimod, ONLY : lfi => lficom_default, &
&                   lficom_default_init,   &
&                   new_lfi_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KFACTM                                 ! IN   

IF (.NOT. lficom_default_init) CALL new_lfi_default ()

CALL lfiafm_mt                        &
&           (lfi, krep, knumer, kfactm)

END SUBROUTINE lfiafm

SUBROUTINE lfiafm_mt                  &
&           (lfi, krep, knumer, kfactm)
USE lfimod, ONLY : lficom
USE lfi_precision
IMPLICIT NONE
! Arguments
type(lficom)          lfi                                    ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KFACTM                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  IFACTM                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
ifactm     = int(    kfactm, jplikb)

CALL lfiafm_fort                       &
&           (lfi, irep, inumer, ifactm)

krep       = int(      irep, jplikm)

END SUBROUTINE lfiafm_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF KFACTM        IN