interpol_ts_water_mth.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE interpol_ts_water_mth (W)
!     #######################################################
!
!!****  *INTERPOL_TS_WATER_MTH* - Interpolation of monthly TS water
!!
!!    PURPOSE
!!    -------
!!
!!
!!**  METHOD
!!    ------
!!
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!      
!     B.Decharme  Meteo-France
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    28/01/10
!!      Modified    07/2015   B. Decharme : new linear interpolation
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
USE modd_watflux_n, ONLY : watflux_t
!
USE modi_interpol_quadra
USE modi_interpol_linear
!
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declaration of arguments
!------------------------
! 
!
TYPE(watflux_t), INTENT(INOUT) :: W
!
!*       0.2   Declaration of local variables
!              ------------------------------
!
REAL            :: ZDAT   ! current day in the current month
REAL            :: ZNDAT  ! number of days in the current month
INTEGER         :: IMTH0  ! previous month
INTEGER         :: IMTH1  ! current month 
INTEGER         :: IMTH2  ! next month
INTEGER         :: INDAYS ! number of days in KMONTH
!
INTEGER         :: IDELTA
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*       1.    Number of days in a month
!              -------------------------
!
IF (lhook) CALL dr_hook('INTERPOL_TS_WATER_MTH',0,zhook_handle)
SELECT CASE (w%TTIME%TDATE%MONTH)
    CASE(4,6,9,11)
      indays=30
    CASE(1,3,5,7:8,10,12)
      indays=31
    CASE(2)
      IF( ((mod(w%TTIME%TDATE%YEAR,4)==0).AND.(mod(w%TTIME%TDATE%YEAR,100)/=0)) .OR. (mod(w%TTIME%TDATE%YEAR,400)==0))THEN
        indays=29
      ELSE
        indays=28
      ENDIF
END SELECT
!
!
!-------------------------------------------------------------------------------
!
!*       2.    TS water Interpolation using previous, current and next month
!              -------------------------------------------------------------
!
zdat = REAL(w%ttime%tdate%day)
zndat= REAL(indays)
!
! The current month correspond to the indice 2 (or 3 if next month))
!
IF (w%TTIME%TDATE%MONTH==w%TZTIME%TDATE%MONTH) THEN 
   idelta=0
ELSE
   idelta=1
END IF
!
imth0=1+idelta
imth1=2+idelta
imth2=3+idelta
!
IF(w%CINTERPOL_TS=='QUADRA')THEN
  CALL interpol_quadra(zdat,zndat,w%XTS_MTH(:,imth0),w%XTS_MTH(:,imth1),w%XTS_MTH(:,imth2),w%XTS)
ELSEIF(w%CINTERPOL_TS=='LINEAR')THEN
  CALL interpol_linear(zdat,zndat,w%XTS_MTH(:,imth0),w%XTS_MTH(:,imth1),w%XTS_MTH(:,imth2),w%XTS)
ELSEIF(w%CINTERPOL_TS=='UNIF')THEN
  w%XTS(:) = w%XTS_MTH(:,imth1)
ELSE
  CALL abor1_sfx('INTERPOL_TS_WATER_MTH: interpolation method not supported')
ENDIF
!
IF (lhook) CALL dr_hook('INTERPOL_TS_WATER_MTH',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE interpol_ts_water_mth