interpol_quadra.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE interpol_quadra(PDAT,PNDAT,PVAL0,PVAL1,PVAL2,POUT)
!     #############################################################
!
!!**** *INTERPOL_QUADRA* Quadractic interpolation between 3 month, especially
!!                       relevant to conserv the SST (or other) monthly mean value.
!!
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    B. Decharme         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    08/2009
!!    18-11-2010 by F. Chauvin  : bugfix for temporal interpolation coeff.
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
REAL,                    INTENT(IN)    :: PDAT    ! Present date in the current month
REAL,                    INTENT(IN)    :: PNDAT   ! Number of date in the current month
REAL, DIMENSION(:),      INTENT(IN)    :: PVAL0   ! Value of the precedent month
REAL, DIMENSION(:),      INTENT(IN)    :: PVAL1   ! Value of the current month
REAL, DIMENSION(:),      INTENT(IN)    :: PVAL2   ! Value of the next month
REAL, DIMENSION(:),      INTENT(OUT)   :: POUT    ! Interpolated value
!
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(SIZE(PVAL0)) :: ZMID1   ! Mid point between t-1 and t
REAL, DIMENSION(SIZE(PVAL0)) :: ZMID2   ! Mid point between t+1 and t
REAL, DIMENSION(SIZE(PVAL0)) :: ZA      ! Interpolation coef
REAL, DIMENSION(SIZE(PVAL0)) :: ZB      ! Interpolation coef
REAL, DIMENSION(SIZE(PVAL0)) :: ZC      ! Interpolation coef
!
REAL                         :: ZSCARRE ! Quadratic coef
REAL                         :: ZSUM    ! Quadratic coef
!
INTEGER                      :: JDAT, INDAT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!----------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('INTERPOL_QUADRA',0,zhook_handle)
!
!*    1.     Initialization
!            --------------
!
zscarre = 0.0
zsum    = 0.0
!
indat = int(pndat)
!
DO jdat=1,indat
   zscarre = zscarre + REAL(jdat*jdat)
   zsum    = zsum    + REAL(jdat)
ENDDO
!
!*    2.     Mid points
!            ----------
! 
zmid1(:) = 0.5 * (pval1(:)+pval0(:))
zmid2(:) = 0.5 * (pval1(:)+pval2(:))
!
!
!*    3.     Coef calculation
!            ----------------
!
za(:) = ((pval1(:)-zmid1(:))*pndat - (zmid2(:)-zmid1(:))*(zsum-pndat)/pndat) &
      / ((zscarre-pndat)-(zsum-pndat)*(pndat+2.0))
!
zb(:) = ((zmid2(:)-zmid1(:)) - (pndat*(pndat+2.0) * za(:))) / pndat
!
zc(:) = zmid1(:) - za(:) - zb(:)
!
!*    3.     Final calculation
!            -----------------
!
pout(:) = za(:) * pdat**2 + zb(:) * pdat + zc(:)
!
!*    4.     End
!            ---
!
IF (lhook) CALL dr_hook('INTERPOL_QUADRA',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE interpol_quadra