fautif.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE fautif_fort                           &
&                     (fa,  krep, knumer, cdiden )
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Sous-programme permettant de donner un NOM a l'Identificateur
!     d'un fichier ARPEGE.
!       ( l'Utilisateur Traite son Identificateur de Fichier )
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KNUMER (Entree) ==> Numero de l'unite logique;
!                CDIDEN (Entree) ==> Nom de l'identificateur.
!
!       Une messagerie de niveau 1 est emise dans les cas "normaux"
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER
!
INTEGER (KIND=JPLIKB) IREP, ILIDEN, IRANG, INIMES, ILACTI
!
LOGICAL LLVERF, LLRLFI
!
CHARACTER CDIDEN*(*)
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPXNOM) CLNOMA
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLES ET INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FAUTIF_MT',0,zhook_handle)
clacti=''
llverf=.false.
llrlfi=.false.
iliden=int(len(cdiden), jplikb)
CALL fanumu_fort                 &
&               (fa, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ELSEIF (iliden.LE.0) THEN
  irep=-65
  GOTO 1001
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort                               &
&                              (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
clnoma=fa%FICHIER(irang)%CIDENT
!
IF (cdiden.EQ.fa%CPCACH.OR.cdiden.EQ.fa%CPCADI.OR. &
&   cdiden.EQ.fa%CPCAFS.OR.cdiden.EQ.fa%CPCARP.OR. &
&   cdiden.EQ.fa%CPDATE.OR.cdiden.EQ.fa%CPDATX) THEN
  irep=-111
  GOTO 1001
ENDIF
!**
!     2.  -  ON RENOMME L'ARTICLE IDENTIFICATEUR, QUI EXISTE TOUJOURS SI
!            LE FICHIER EST OUVERT, AU MOINS AVEC UN NOM PAR DEFAUT.
!-----------------------------------------------------------------------
!
IF (cdiden.NE.fa%FICHIER(irang)%CIDENT) THEN
  CALL lfiren_fort                                             &
&                 (fa%LFI, irep,knumer,fa%FICHIER(irang)%CIDENT,cdiden)
  llrlfi=irep.NE.0
  IF (.NOT.llrlfi) fa%FICHIER(irang)%CIDENT=cdiden
ELSE
  irep=0
ENDIF
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort                                &
&                           (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSE
  inimes=ixnvms(irang)
ENDIF
!
IF (.NOT.llfata.AND.inimes.EQ.0)  THEN 
  IF (lhook) CALL dr_hook('FAUTIF_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FAUTIF'
!
IF (irep.NE.-65) THEN
  ilacti=fa%NCPCAD
  clacti(1:ilacti)=cdiden(1:min(iliden,ilacti))
ELSE
  ilacti=8
  clacti(1:ilacti)=fa%CHAINC(:ilacti)
ENDIF
!
IF (inimes.EQ.2) THEN
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&         '', CDIDEN='''''',A,'''''''')')                  &
&   krep,knumer,clacti(1:ilacti)
  CALL faipar_fort                              &
&                 (fa, knumer,inimes,irep,llfata, &
&               clmess,clnspr,                    &
&               clacti(1:ilacti),llrlfi)
ENDIF
!
!        La messagerie qui suit n'est pas emise en cas d'erreur fatale.
!
IF (inimes.GE.1.AND.irang.NE.0) THEN
  WRITE (unit=clmess,fmt=                               &
&  '(''Ancien Identificateur de l''''unite logique'',I3, &
&    '' : '''''',A,'''''', Nouveau: '''''',A,'''''''')') &
&  knumer,clnoma,fa%FICHIER(irang)%CIDENT
  CALL faipar_fort                                      &
&                 (fa, knumer,inimes,irep,.false.,clmess, &
&                  clnspr,clacti(1:ilacti),.false.)
ENDIF
!
IF (lhook) CALL dr_hook('FAUTIF_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

END SUBROUTINE fautif_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE fautif64              &
&           (krep, knumer, cdiden)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDIDEN                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fautif_fort                     &
&           (fa, krep, knumer, cdiden)

END SUBROUTINE fautif64

SUBROUTINE fautif                &
&           (krep, knumer, cdiden)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDIDEN                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fautif_mt                       &
&           (fa, krep, knumer, cdiden)

END SUBROUTINE fautif

SUBROUTINE fautif_mt                 &
&           (fa, krep, knumer, cdiden)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDIDEN                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL fautif_fort                     &
&           (fa, irep, inumer, cdiden)

krep       = int(      irep, jplikm)

END SUBROUTINE fautif_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF CDIDEN        IN