fatale.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE fatale_fort                           &
&                     (fa,  krep, knumer, lderfa )
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Ce sous-programme permet d'activer ou de desactiver l'option
!     rendant fatale toute erreur detectee sur un fichier particulier,
!     ouvert pour le Logiciel de Fichiers ARPEGE, de meme pour l'option
!     correspondante du logiciel LFI.
!        Cependant, tant que le niveau global d'erreur fatale *FA%NRFAGA*
!     vaut 0 ou 2, l'option propre au fichier est inoperante.
!     *FA%NRFAGA* vaut par defaut 1, et est reglable via le s/p "FANERG".
!**
!     Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                 KNUMER (Entree) ==> Numero d'Unite Logique concernee;
!                 LDERFA (Entree) ==> Option d'Erreur Fatale (Vrai=oui).
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER
!
INTEGER (KIND=JPLIKB) IRANG, IREP, INIMES
!
LOGICAL LDERFA, LLRLFI
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FATALE_MT',0,zhook_handle)
clacti=''
CALL fanumu_fort                 &
&               (fa, knumer,irang)
!
IF (irang.NE.0) THEN
  fa%FICHIER(irang)%LERRFA=lderfa
  CALL lfierf_fort                            &
&                 (fa%LFI, irep,knumer,lderfa)
  llrlfi=irep.NE.0
ELSE
  irep=-51
  llrlfi=.false.
ENDIF
!
llfata=llmoer(irep,irang)
krep=irep
!
IF (llfata.OR.ixnvms(irang).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('FATALE_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FATALE'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', LDERFA= '',L1)') krep,knumer,lderfa
CALL faipar_fort                                     &
&               (fa, knumer,inimes,irep,llfata,clmess, &
&             clnspr,clacti,llrlfi)
!
IF (lhook) CALL dr_hook('FATALE_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

END SUBROUTINE fatale_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE fatale64              &
&           (krep, knumer, lderfa)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
LOGICAL                LDERFA                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fatale_fort                     &
&           (fa, krep, knumer, lderfa)

END SUBROUTINE fatale64

SUBROUTINE fatale                &
&           (krep, knumer, lderfa)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
LOGICAL                LDERFA                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fatale_mt                       &
&           (fa, krep, knumer, lderfa)

END SUBROUTINE fatale

SUBROUTINE fatale_mt                 &
&           (fa, krep, knumer, lderfa)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
LOGICAL                LDERFA                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)

CALL fatale_fort                     &
&           (fa, irep, inumer, lderfa)

krep       = int(      irep, jplikm)

END SUBROUTINE fatale_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF LDERFA        IN