fanime.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE fanime_fort                           &
&                     (fa,  krep, knumer, knimes )
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!        Ce sous-programme permet d'ajuster le Niveau de Messagerie
!     propre aux actions faites sur un fichier particulier, ouvert pour
!     le Logiciel de Fichiers ARPEGE, de meme que le Niveau correspon-
!     dant du logiciel LFI.
!        Cependant, tant que le Niveau de Messagerie Global *FA%NIMSGA*
!     vaut 0 ou 2, le niveau propre au fichier est inoperant.
!     *FA%NIMSGA* vaut par defaut 1, et est reglable via le s/p "FANMSG".
!**
!     Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                 KNUMER (Entree) ==> Numero d'Unite Logique concernee;
!                 KNIMES (Entree) ==> Niveau de Messagerie souhaite.
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER, KNIMES
!
INTEGER (KIND=JPLIKB) IREP, IRANG, INIMEX, INIMES
!
LOGICAL LLRLFI
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FANIME_MT',0,zhook_handle)
clacti=''
CALL fanumu_fort                 &
&               (fa, knumer,irang)
inimex=0
!
IF (irang.EQ.0) THEN
  irep=-51
ELSEIF (knimes.GE.0.AND.knimes.LE.2) THEN
  inimex=ixnvms(irang)
  fa%FICHIER(irang)%NIVOMS=knimes
  CALL lfinim_fort                            &
&                 (fa%LFI, irep,knumer,knimes)
  llrlfi=irep.NE.0
ELSE
  irep=-52
ENDIF
!
krep=irep
llfata=llmoer(irep,irang)
!
IF (llfata.OR.max(ixnvms(irang),inimex).EQ.2) THEN
  inimes=2
ELSE
  IF (lhook) CALL dr_hook('FANIME_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FANIME'
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', KNIMES='',I3)') krep,knumer,knimes
CALL faipar_fort                                     &
&               (fa, knumer,inimes,irep,llfata,clmess, &
&             clnspr,clacti,.false.)
!
IF (lhook) CALL dr_hook('FANIME_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

END SUBROUTINE fanime_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE fanime64              &
&           (krep, knumer, knimes)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  KNIMES                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fanime_fort                     &
&           (fa, krep, knumer, knimes)

END SUBROUTINE fanime64

SUBROUTINE fanime                &
&           (krep, knumer, knimes)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KNIMES                                 ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fanime_mt                       &
&           (fa, krep, knumer, knimes)

END SUBROUTINE fanime

SUBROUTINE fanime_mt                 &
&           (fa, krep, knumer, knimes)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KNIMES                                 ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  INIMES                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
inimes     = int(    knimes, jplikb)

CALL fanime_fort                     &
&           (fa, irep, inumer, inimes)

krep       = int(      irep, jplikm)

END SUBROUTINE fanime_mt

!INTF KREP            OUT 
!INTF KNUMER        IN    
!INTF KNIMES        IN