fandax.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE fandax_fort                           &
&                     (fa,  krep, knumer, kdatef)
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Sous-programme de definition d'une (Nouvelle) Date sur un fichier
!     ARpege.
!**
!    Arguments : KREP   (Sortie)        ==> Code-reponse du sous-programme;
!                KNUMER (Entree)        ==> Numero de l'unite logique;
!     (Tableau)  KDATEF (Entree/Sortie) ==> Date elle-meme (FA%JPLDAT*2 mots).
!*
!        En cas de modification effective (si le fichier etait deja muni
!     d'une date), il y a messagerie de niveau 1.
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER
INTEGER (KIND=JPLIKB) KDATEF (fa%jpldat*2)
!
INTEGER (KIND=JPLIKB) IRANG, IREP, INIMES, J
!
LOGICAL LLVERF, LLRLFI, LLMODA
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLES DES PARAMETRES D'APPEL, PUIS INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FANDAX_MT',0,zhook_handle)
clacti=''
llverf=.false.
llrlfi=.false.
llmoda=.false.
CALL fanumu_fort                 &
&               (fa, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort                               &
&                              (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
!**
!     2.  -  DEFINITION PROPREMENT DITE VIA LE SOUS-PROGRAMME "FANDAI".
!            ( controles, puis mise a jour de FA%MADATE(.,IRANG) )
!-----------------------------------------------------------------------
!
CALL fandai_fort                                            &
&               (fa,irep,irang,kdatef(1:fa%JPLDAT),         &
&                kdatef(fa%JPLDAT+1:fa%JPLDAT*2),llmoda)
!
IF (irep.EQ.0) THEN
  IF (fa%FICHIER(irang)%LNOMME) THEN
!**
!     3.  -  ECRITURE DE LA DATE SUR LE FICHIER.
!-----------------------------------------------------------------------
!
    CALL lfiecr_fort                                                 &
&                   (fa%LFI, irep,knumer,fa%CPDATE,kdatef(1:fa%JPLDAT),fa%JPLDAT)
    CALL lfiecr_fort                                                 &
&                   (fa%LFI, irep,knumer,fa%CPDATX,kdatef(fa%JPLDAT+1:fa%JPLDAT*2),fa%JPLDAT)
    llrlfi=irep.NE.0
    fa%FICHIER(irang)%LCREAF=fa%FICHIER(irang)%LCREAF.AND.llrlfi
  ELSE
    llrlfi=.false.
    fa%FICHIER(irang)%LCREAF=.false.
  ENDIF
ENDIF
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort                                &
&                           (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSEIF (irep.NE.0) THEN
  inimes=0
ELSE
  inimes=ixnvms(irang)
ENDIF
!
IF (.NOT.llfata.AND.inimes.NE.2)  THEN
  IF (lhook) CALL dr_hook('FANDAX_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FANDAX'
!
IF (inimes.GE.1.AND.llmoda) THEN
  WRITE (unit=clmess,fmt=                                  &
&         '(''MODIFICATION DE LA DATE, UNITE'',I3)') knumer

  CALL faipar_fort                                        &
&                 (fa, knumer,inimes,irep,.false.,clmess, &
&                  clnspr,clacti,.false.)
ENDIF
!
IF (inimes.EQ.2) THEN
!***** FAZZZZ - KREP=iiii, KNUMER=iii, KDATEF(1:5)=iiiii/ii/ii iii:ii, *****
!*****          KDATEF(7:8)=iiiiii-iiiiii                              *****
  WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3,  &
&       '', KDATEF(1:5)='',I5,2(''/'',I2),I3,'':'',I2.2,   &
&       '', KDATEF(7:8)='',I6,''-'',I6)') krep,knumer,     &
&     (kdatef(j),j=1,5),(kdatef(j),j=7,8)
  CALL faipar_fort                                       &
&                 (fa, knumer,inimes,irep,llfata,clmess, &
&               clnspr,clacti,llrlfi)
ENDIF
!
IF (lhook) CALL dr_hook('FANDAX_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

END SUBROUTINE fandax_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE fandax64              &
&           (krep, knumer, kdatef)
USE fa_mod, ONLY : fa => fa_com_default, &
&                  fa_com_default_init,  &
&                  new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  KDATEF     (*)               ! INOUT

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fandax_fort                     &
&           (fa, krep, knumer, kdatef)

END SUBROUTINE fandax64

SUBROUTINE fandax                &
&           (krep, knumer, kdatef)
USE fa_mod, ONLY : fa => fa_com_default, &
&                  fa_com_default_init,  &
&                  new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KDATEF     (*)               ! INOUT

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL fandax_mt                       &
&           (fa, krep, knumer, kdatef)

END SUBROUTINE fandax

SUBROUTINE fandax_mt                 &
&           (fa, krep, knumer, kdatef)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
INTEGER (KIND=JPLIKM)  KDATEF     (fa%jpldat*2)               ! INOUT
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  IDATEF     (fa%jpldat*2)               ! INOUT
! Convert arguments

inumer     = int(    knumer, jplikb)
idatef     = int(    kdatef, jplikb)

CALL fandax_fort                     &
&           (fa, irep, inumer, idatef)

krep       = int(      irep, jplikm)
kdatef     = int(    idatef, jplikm)

END SUBROUTINE fandax_mt

!INTF KREP            OUT                               
!INTF KNUMER        IN                                  
!INTF KDATEF        INOUT DIMS=FA%JPLDAT*2