falais.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE falais_fort                                           &
&                     (fa,  krep, knumer, cdnoma, kdonne, klongd )
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Sous-programme de lecture d'un article de donnees non assimila-
!     bles a un champ horizontal sur un fichier ARPEGE.
!       ( Lecture d'un Article Integre Simplement, non code )
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KNUMER (Entree) ==> Numero de l'unite logique;
!                CDNOMA (Entree) ==> Nom de l'article;
!    ( Tableau ) KDONNE (Sortie) ==> Donnees a ecrire;
!                KLONGD (Entree) ==> Nombre de mots a ecrire.
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLONGD
!
INTEGER (KIND=JPLIKB) ILCDNO, IREP, IRANG
INTEGER (KIND=JPLIKB) ILNOMA, INIMES, ILACTI
!
INTEGER (KIND=JPLIKB) KDONNE (klongd)
!
LOGICAL LLVERF, LLRLFI
!
CHARACTER CDNOMA*(*)
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPXNOM) CLNOMA
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA

!**
!     1.  -  CONTROLES ET INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FALAIS_MT',0,zhook_handle)
clacti=''
llverf=.false.
llrlfi=.false.
ilcdno=int(len(cdnoma), jplikb)
CALL fanumu_fort                 &
&               (fa, knumer,irang)
!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ELSEIF (klongd.LE.0) THEN
  irep=-64
  GOTO 1001
ELSEIF (ilcdno.LE.0) THEN
  irep=-65
  GOTO 1001
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort                               &
&                              (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
!
IF (fa%FICHIER(irang)%LCREAF) THEN
  irep=-85
  GOTO 1001
ELSEIF (cdnoma.EQ.fa%CPCACH.OR.cdnoma.EQ.fa%CPCADI.OR. &
&    cdnoma.EQ.fa%CPCAFS.OR.cdnoma.EQ.fa%CPCARP.OR.     &
&    cdnoma.EQ.fa%CPDATE.OR.cdnoma.EQ.fa%CPDATX) THEN
  irep=-111
  GOTO 1001
ENDIF
!**
!     2.  -  LECTURE DE L'ARTICLE DE DONNEES SUR LE FICHIER.
!-----------------------------------------------------------------------
!
ilnoma=min( fa%NCPCAD, int(len(cdnoma), jplikb) )
clnoma(1:ilnoma)=cdnoma(1:ilnoma)
!
CALL lfilec_fort                                      &
&               (fa%LFI, irep,knumer,clnoma(1:ilnoma), &
&                kdonne,klongd)
llrlfi=irep.NE.0
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort                                &
&                           (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSE
  inimes=ixnvms(irang)
ENDIF
!
IF (.NOT.llfata.AND.inimes.NE.2)  THEN 
  IF (lhook) CALL dr_hook('FALAIS_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FALAIS'
!
IF (irep.NE.-65) THEN
  ilacti=min(ilcdno,fa%NCPCAD)
  clacti(1:ilacti)=cdnoma(:ilacti)
ELSE
  ilacti=8
  clacti(1:ilacti)=fa%CHAINC(:ilacti)
ENDIF
!
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', CDNOMA='''''',A,'''''', KLONGD='',I8)')      &
&   krep,knumer,clacti(1:ilacti),klongd
CALL faipar_fort                                     &
&               (fa, knumer,inimes,irep,llfata,clmess, &
&                clnspr,clacti(1:ilacti),llrlfi)
!
IF (lhook) CALL dr_hook('FALAIS_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"

END SUBROUTINE falais_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE falais64                              &
&           (krep, knumer, cdnoma, kdonne, klongd)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKB)  KLONGD                                 ! IN   
INTEGER (KIND=JPLIKB)  KDONNE     (klongd)                    ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL falais_fort                                     &
&           (fa, krep, knumer, cdnoma, kdonne, klongd)

END SUBROUTINE falais64

SUBROUTINE falais                                &
&           (krep, knumer, cdnoma, kdonne, klongd)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONGD                                 ! IN   
REAL (KIND=JPLIKB)     KDONNE     (klongd)                    ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL falais_mt                                       &
&           (fa, krep, knumer, cdnoma, kdonne, klongd)

END SUBROUTINE falais

SUBROUTINE falais_mt                                 &
&           (fa, krep, knumer, cdnoma, kdonne, klongd)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONGD                                 ! IN   
INTEGER (KIND=JPLIKB)  KDONNE     (klongd)                    ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILONGD                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
ilongd     = int(    klongd, jplikb)

CALL falais_fort                                     &
&           (fa, irep, inumer, cdnoma, kdonne, ilongd)

krep       = int(      irep, jplikm)

END SUBROUTINE falais_mt

!INTF KREP            OUT                               
!INTF KNUMER        IN                                  
!INTF CDNOMA        IN                                  
!INTF KDONNE        IN    DIMS=KLONGD                   
!INTF KLONGD        IN