faisan.F90

Go to the documentation of this file.

! Oct-2012 P. Marguinaud 64b LFI
! Jan-2011 P. Marguinaud Thread-safe FA
SUBROUTINE faisan_fort                                           &
&                     (fa,  krep, knumer, cdnoma, kdonne, klongd)
USE fa_mod, ONLY : fa_com
USE parkind1, ONLY : jprb
USE yomhook , ONLY : lhook, dr_hook
USE lfi_precision
IMPLICIT NONE
!****
!      Sous-programme d'ecriture d'un article de donnees non assimila-
!     bles a un champ horizontal sur un fichier ARPEGE.
!       ( Integration Simple d'un Article Non code )
!**
!    Arguments : KREP   (Sortie) ==> Code-reponse du sous-programme;
!                KNUMER (Entree) ==> Numero de l'unite logique;
!                CDNOMA (Entree) ==> Nom de l'article;
!    ( Tableau ) KDONNE (Entree) ==> Donnees a ecrire;
!                KLONGD (Entree) ==> Nombre de mots a ecrire.
!
!
!
TYPE(fa_com) :: FA
INTEGER (KIND=JPLIKB) KREP, KNUMER, KLONGD
!
INTEGER (KIND=JPLIKB) ILCDNO, IRANG, IREP
INTEGER (KIND=JPLIKB) ILNOMA, INIMES, ILACTI
!
INTEGER (KIND=JPLIKB) KDONNE (klongd)
!
LOGICAL LLVERF, LLRLFI
!
CHARACTER CDNOMA*(*)
!
CHARACTER(LEN=FA%JPXNOM) CLACTI 
CHARACTER(LEN=FA%JPXNOM) CLNOMA
CHARACTER(LEN=FA%JPLMES) CLMESS 
CHARACTER(LEN=FA%JPLSPX) CLNSPR
LOGICAL                  LLFATA
LOGICAL                  LLECRI

!**
!     1.  -  CONTROLES ET INITIALISATIONS.
!-----------------------------------------------------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (lhook) CALL dr_hook('FAISAN_MT',0,zhook_handle)
clacti=''
llverf=.false.
llrlfi=.false.
ilcdno=int(len(cdnoma), jplikb)
CALL fanumu_fort                 &
&               (fa, knumer,irang)

!
IF (irang.EQ.0) THEN
  irep=-51
  GOTO 1001
ELSEIF (klongd.LE.0) THEN
  irep=-64
  GOTO 1001
ELSEIF (ilcdno.LE.0) THEN
  irep=-65
  GOTO 1001
ENDIF
!
!         Verrouillage eventuel du fichier.
!
IF (fa%LFAMUL) CALL lfiver_fort                               &
&                              (fa%LFI, fa%FICHIER(irang)%VRFICH,'ON')
llverf=fa%LFAMUL
!
IF (fa%FICHIER(irang)%LCREAF) THEN
  irep=-85
  GOTO 1001
ELSEIF (cdnoma.EQ.fa%CPCACH.OR.cdnoma.EQ.fa%CPCADI.OR.  &
&       cdnoma.EQ.fa%CPCAFS.OR.cdnoma.EQ.fa%CPCARP.OR.  &
&       cdnoma.EQ.fa%CPDATE.OR.cdnoma.EQ.fa%CPDATX.OR.  &
&       cdnoma.EQ.fa%FICHIER(irang)%CIDENT) THEN
  irep=-111
  GOTO 1001
ENDIF
!**
!     2.  -  ECRITURE DE L'ARTICLE DE DONNEES SUR LE FICHIER.
!-----------------------------------------------------------------------
!
ilnoma=min( fa%NCPCAD, int(len(cdnoma), jplikb) )
clnoma(1:ilnoma)=cdnoma(1:ilnoma)
!

llecri = .false.
IF (fa%FICHIER(irang)%NCOGRIF (12) > 0) THEN
  CALL wgrib1 (llecri)
ENDIF
IF (.NOT. llecri) THEN
  CALL lfiecr_fort                                       &
  &               (fa%LFI, irep,knumer,clnoma(1:ilnoma), &
  &                kdonne,klongd)
ENDIF
llrlfi=irep.NE.0
!**
!    10.  -  PHASE TERMINALE : MESSAGERIE, AVEC "ABORT" EVENTUEL,
!            VIA LE SOUS-PROGRAMME "FAIPAR" .
!-----------------------------------------------------------------------
!
1001 CONTINUE
krep=irep
llfata=llmoer(irep,irang)
!
!        Deverrouillage eventuel du fichier.
!
IF (llverf) CALL lfiver_fort                                &
&                           (fa%LFI, fa%FICHIER(irang)%VRFICH,'OFF')
!
IF (llfata) THEN
  inimes=2
ELSE
  inimes=ixnvms(irang)
ENDIF
!
IF (.NOT.llfata.AND.inimes.NE.2)  THEN 
  IF (lhook) CALL dr_hook('FAISAN_MT',1,zhook_handle)
  RETURN
ENDIF
!
clnspr='FAISAN'
!
IF (irep.NE.-65) THEN
  ilacti=min(ilcdno,fa%NCPCAD)
  clacti(1:ilacti)=cdnoma(:ilacti)
ELSE
  ilacti=8
  clacti(1:ilacti)=fa%CHAINC(:ilacti)
ENDIF
!
WRITE (unit=clmess,fmt='(''KREP='',I4,'', KNUMER='',I3, &
&       '', CDNOMA='''''',A,'''''', KLONGD='',I8)')     &
&   krep,knumer,clacti(1:ilacti),klongd
CALL faipar_fort                                       &
&               (fa, knumer,inimes,irep,llfata,clmess, &
&                clnspr, clacti(1:ilacti),llrlfi)
!
IF (lhook) CALL dr_hook('FAISAN_MT',1,zhook_handle)

CONTAINS

#include "facom2.llmoer.h"
#include "facom2.ixnvms.h"
#include "falgra.h"

SUBROUTINE wgrib1 (LDECRI)

LOGICAL :: LDECRI

INTEGER (KIND=JPLIKB), PARAMETER :: ILONGD = 5_jplikb

INTEGER (KIND=JPLIKB)  IDONNE (ilongd)
CHARACTER(LEN=16)      CLGRIB, CL7777
INTEGER (KIND=JPLIKB)  J, IL7777, INGRIB, IREP8, ILGRIBA, ILGRIBB, IGRIBED
LOGICAL                LLNOMM, LLERFA, LLIMST
CHARACTER (LEN=256)    CLNOMF, CLNOMD, CLNOMB
CHARACTER (LEN=16)     CLSTTU
INTEGER (KIND=JPLIKB)  INIMES
INTEGER (KIND=JPLIKM)  IREP4

ldecri = .false.

IF (klongd < 10) RETURN ! Trop petit pour etre un GRIB1

ingrib = kdonne(1)                        ! Methode de codage
clgrib = transfer(kdonne(4:5), clgrib)   ! Debut de l'entete GRIB1

IF ((ingrib /= 3) .AND. (.NOT. falgra(ingrib))) RETURN

IF (clgrib(1:4) /= 'GRIB') RETURN

igribed = mod(ichar(clgrib(8:8)), 256)

IF ((igribed /= 1) .AND. (igribed /= 2)) RETURN

! Recuperation de la longueur du message GRIB

ilgriba = 0

IF (igribed == 1) THEN
  DO j = 5, 7
    ilgriba = 256 * ilgriba + mod(ichar(clgrib(j:j)), 256)
  ENDDO
ELSE
  DO j = 9, 16
    ilgriba = 256 * ilgriba + mod(ichar(clgrib(j:j)), 256)
  ENDDO
ENDIF

! On cherche maintenant la fin du message GRIB1

cl7777 = transfer(kdonne(klongd-1:klongd), cl7777)
il7777 = len(cl7777)

DO j = 0, il7777-4
  IF (cl7777(il7777-j-3:il7777-j) == '7777') EXIT
ENDDO

IF (j == -1) RETURN

! Calcul de la longueur du message GRIB en octets

ilgribb = (klongd-3)*8 - j

! On verifie que les deux longueurs correspondent

IF (ilgriba /= ilgribb) RETURN

! Ouverture du fichier externe

IF (fa%FICHIER(irang)%NFILEP == 0) THEN
  CALL lfiopt_fort                                        &
&                 (fa%LFI, irep, knumer, llnomm, clnomf,  &
&                  clsttu, llerfa, llimst, inimes)
  IF (irep /= 0) RETURN
  CALL fileparse (clnomf, clnomd, clnomb)
  clnomf = trim(clnomd)//'GRIB'//trim(clnomb)
  CALL fi_fopen (fa%FICHIER(irang)%NFILEP, clnomf, "a")
  IF (fa%FICHIER(irang)%NFILEP == 0) THEN
    CALL fi_errno (irep4)
    irep = irep4
    RETURN
  ENDIF
ENDIF

! Ecriture de l'article GRIB

CALL fi_fwrite (irep8, kdonne(4), ilgriba, 1_jplikb, &
              & fa%FICHIER(irang)%NFILEP)
IF (irep8 /= 1) THEN
  CALL fi_errno (irep4)
  irep = irep4
ELSE
  irep = 0
ENDIF

fa%FICHIER(irang)%NOFFST = fa%FICHIER(irang)%NOFFST + ilgriba

! Ecriture d'un article referencant le champ GRIB

idonne(1:3) = kdonne(1:3)
idonne(4) = fa%FICHIER(irang)%NOFFST
idonne(5) = ilongd

CALL lfiecr_fort                                         &
&               (fa%LFI, irep, knumer, clnoma(1:ilnoma), &
&                idonne, ilongd)

IF (irep /= 0) RETURN

ldecri = .true.

END SUBROUTINE wgrib1

SUBROUTINE fileparse (CDNOMF, CDNOMD, CDNOMB)

CHARACTER (LEN=*) :: CDNOMF, CDNOMD, CDNOMB

INTEGER (KIND=JPLIKB) :: I

i = index(cdnomf, "/", .true.)

IF (i == 0) THEN
  cdnomd = ''
  cdnomb = cdnomf
ELSE
  cdnomd = cdnomf(1:i)
  cdnomb = cdnomf(i+1:)
ENDIF

END SUBROUTINE fileparse

END SUBROUTINE faisan_fort



! Oct-2012 P. Marguinaud 64b LFI
SUBROUTINE faisan64                              &
&           (krep, knumer, cdnoma, kdonne, klongd)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKB)  KREP                                   !   OUT
INTEGER (KIND=JPLIKB)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKB)  KLONGD                                 ! IN   
INTEGER (KIND=JPLIKB)  KDONNE (klongd)                        ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL faisan_fort                                     &
&           (fa, krep, knumer, cdnoma, kdonne, klongd)

END SUBROUTINE faisan64

SUBROUTINE faisan                                &
&           (krep, knumer, cdnoma, kdonne, klongd)
USE fa_mod, ONLY : fa => fa_com_default, &
&                   fa_com_default_init,  &
&                   new_fa_default
USE lfi_precision
IMPLICIT NONE
! Arguments
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONGD                                 ! IN   
INTEGER (KIND=JPLIKB)  KDONNE (klongd)                        ! IN   

IF (.NOT. fa_com_default_init) CALL new_fa_default ()

CALL faisan_mt                                       &
&           (fa, krep, knumer, cdnoma, kdonne, klongd)

END SUBROUTINE faisan

SUBROUTINE faisan_mt                                 &
&           (fa, krep, knumer, cdnoma, kdonne, klongd)
USE fa_mod, ONLY : fa_com
USE lfi_precision
IMPLICIT NONE
! Arguments
type(fa_com)          fa                                     ! INOUT
INTEGER (KIND=JPLIKM)  KREP                                   !   OUT
INTEGER (KIND=JPLIKM)  KNUMER                                 ! IN   
CHARACTER (LEN=*)      CDNOMA                                 ! IN   
INTEGER (KIND=JPLIKM)  KLONGD                                 ! IN   
INTEGER (KIND=JPLIKB)  KDONNE (klongd)                        ! IN   
! Local integers
INTEGER (KIND=JPLIKB)  IREP                                   !   OUT
INTEGER (KIND=JPLIKB)  INUMER                                 ! IN   
INTEGER (KIND=JPLIKB)  ILONGD                                 ! IN   
! Convert arguments

inumer     = int(    knumer, jplikb)
ilongd     = int(    klongd, jplikb)

CALL faisan_fort                                     &
&           (fa, irep, inumer, cdnoma, kdonne, ilongd)

krep       = int(      irep, jplikm)

END SUBROUTINE faisan_mt

!INTF KREP            OUT                               
!INTF KNUMER        IN                                  
!INTF CDNOMA        IN                                  
!INTF KDONNE        IN    KDIMS=KLONGD                  
!INTF KLONGD        IN