facade_e_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
SUBROUTINE facade_e_budget(TOP, T, B, DMT, PTSTEP, PDN_RD, PRHOA, PAC_WL, PAC_BLD, &
                           PLW_RAD, PPS, PEXNS, PT_CANYON, PTS_RD, PTSN_RD, PTS_GD, &
                           PTS_FL, PLW_WA_TO_WB, PLW_R_TO_WA, PLW_R_TO_WB,          &
                           PLW_G_TO_WA, PLW_G_TO_WB, PLW_S_TO_WA, PLW_S_TO_WB,      &
                           PLW_NR_TO_WA,PLW_NR_TO_WB, PLW_WIN_TO_WA, PLW_WIN_TO_WB, &  
                           PLW_S_TO_WIN, PLW_WA_TO_WIN, PLW_WB_TO_WIN, PLW_R_TO_WIN,& 
                           PLW_G_TO_WIN, PLW_NR_TO_WIN, PFLX_BLD_WL_A, PDQS_WL_A,   &
                           PFLX_BLD_WL_B, PDQS_WL_B, PEMIT_LW_FAC, PIMB_WL,         &
                           PRADHT_IN, PRAD_RF_WL, PRAD_RF_WIN, PRAD_WL_FL,          &
                           PRAD_WL_MA, PRAD_WIN_FL, PRAD_WIN_MA, PCONV_WL_BLD,      &
                           PCONV_WIN_BLD, PAC_WIN,  PLOAD_IN_WL, PLOAD_IN_WIN )
!
!   ##########################################################################
!
!!****  *FACADE_E_BUDGET*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evolution of wall and window temperature from
!     wall_layer_e_budget et window_e_budget
!         
!     
!!**  METHOD
!     ------
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      G. Pigeon           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/11/2011 
!!      G. Pigeon     /09/2012: new conv. coef for indoor/outdoor 
!!      G. Pigeon     /10/2012: new arg. : solar heat load for indoor
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_teb_n, ONLY : teb_t
USE modd_bem_n, ONLY : bem_t
USE modd_diag_misc_teb_n, ONLY : diag_misc_teb_t
!
USE modd_surf_par, ONLY : xundef
USE modd_csts, ONLY : xcpd
!
USE modi_wall_layer_e_budget
USE modi_window_e_budget
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(teb_options_t), INTENT(INOUT) :: TOP
TYPE(teb_t), INTENT(INOUT) :: T
TYPE(bem_t), INTENT(INOUT) :: B
TYPE(diag_misc_teb_t), INTENT(INOUT) :: DMT
!
REAL,               INTENT(IN)    :: PTSTEP       ! time step
REAL, DIMENSION(:), INTENT(IN)    :: PDN_RD     ! snow-covered fraction on roads
REAL, DIMENSION(:), INTENT(IN)    :: PRHOA        ! rho
REAL, DIMENSION(:), INTENT(IN)    :: PAC_WL     ! aerodynamical conductance
!                                                 ! between wall and canyon
REAL, DIMENSION(:), INTENT(IN)    :: PAC_BLD      ! aerodynamical conductance
                                                  ! inside the building itself
REAL, DIMENSION(:), INTENT(IN)    :: PLW_RAD      ! atmospheric infrared radiation
REAL, DIMENSION(:), INTENT(IN)    :: PPS          ! pressure at the surface
REAL, DIMENSION(:), INTENT(IN)    :: PEXNS        ! surface Exner function
REAL, DIMENSION(:), INTENT(IN)    :: PT_CANYON    ! air canyon temperature
REAL, DIMENSION(:), INTENT(IN)    :: PTS_RD     ! road surface temperature
REAL, DIMENSION(:), INTENT(IN)    :: PTSN_RD  ! road snow temperature
REAL, DIMENSION(:), INTENT(IN)    :: PTS_GD   ! green area surface temperature
REAL, DIMENSION(:), INTENT(IN)    :: PTS_FL    ! floor layers temperatures [K]
!
REAL, DIMENSION(:), INTENT(IN)    :: PLW_WA_TO_WB ! LW interactions wall  -> wall (both versions)
REAL, DIMENSION(:), INTENT(IN)    :: PLW_R_TO_WA  ! LW interactions road -> wall ; DEF formulation 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_R_TO_WB  ! LW interactions road -> wall ; DEF formulation 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_G_TO_WA  ! LW interactions garden -> wall ; DEF formulation
REAL, DIMENSION(:), INTENT(IN)    :: PLW_G_TO_WB  ! LW interactions garden -> wall ; DEF formulation
REAL, DIMENSION(:), INTENT(IN)    :: PLW_S_TO_WA  ! LW interactions sky   -> wall 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_S_TO_WB  ! LW interactions sky   -> wall 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_NR_TO_WA ! LW interactions road(snow) -> wall 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_NR_TO_WB ! LW interactions road(snow) -> wall 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_WA_TO_WIN! Radiative heat trasfer coeff wall-window 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PLW_WB_TO_WIN! Radiative heat trasfer coeff wall-window 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PLW_S_TO_WIN ! Radiative heat trasfer coeff window-sky 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PLW_WIN_TO_WA! Radiative heat trasfer coeff window-wall
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_WIN_TO_WB! Radiative heat trasfer coeff window-wall
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_R_TO_WIN ! Radiative heat trasfer coeff window-road 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PLW_G_TO_WIN ! Radiative heat trasfer coeff window-garden
REAL, DIMENSION(:), INTENT(IN)    :: PLW_NR_TO_WIN! Radiative heat trasfer coeff window-snow
!
REAL, DIMENSION(:), INTENT(OUT)   :: PFLX_BLD_WL_A! flux from bld to wall
REAL, DIMENSION(:), INTENT(INOUT) :: PDQS_WL_A    ! heat storage inside the wall 
REAL, DIMENSION(:), INTENT(OUT)   :: PFLX_BLD_WL_B! flux from bld to wall
REAL, DIMENSION(:), INTENT(INOUT) :: PDQS_WL_B    ! heat storage inside the wall 
REAL, DIMENSION(:), INTENT(OUT)   :: PEMIT_LW_FAC ! LW flux emitted by the facade (W/m2 of facade)
REAL, DIMENSION(:), INTENT(OUT)   :: PIMB_WL    ! wall residual energy imbalance 
                                                  ! for verification [W m-2]
REAL, DIMENSION(:),   INTENT(IN)  :: PRADHT_IN     ! Indoor radiant heat transfer coefficient
                                                    ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PRAD_RF_WL ! rad. fluxes from roof to wall [W m-2(roof)]
REAL, DIMENSION(:), INTENT(IN)    :: PRAD_RF_WIN  ! rad. fluxes from roof to win [W m-2(roof)]
REAL, DIMENSION(:), INTENT(OUT)   :: PRAD_WL_FL! rad. fluxes from wall to floor [W m-2(wall)]
REAL, DIMENSION(:), INTENT(OUT)   :: PRAD_WL_MA ! rad. fluxes from wall to mass [W m-2(wall)]
REAL, DIMENSION(:), INTENT(OUT)   :: PRAD_WIN_FL ! rad. fluxes from window to floor [W m-2(win)]
REAL, DIMENSION(:), INTENT(OUT)   :: PRAD_WIN_MA  ! rad. fluxes from window to mass [W m-2(win)]
REAL, DIMENSION(:), INTENT(OUT)   :: PCONV_WL_BLD ! conv. fluxes from wall to bld [W m-2(wall)]
REAL, DIMENSION(:), INTENT(OUT)   :: PCONV_WIN_BLD  ! conv. fluxes from window to bld [W m-2(wind.)]
REAL, DIMENSION(:), INTENT(IN)    :: PAC_WIN        ! window aerodynamic conductance
!
REAL, DIMENSION(:), INTENT(IN)    :: PLOAD_IN_WL  ! solar + inter. heat gains W/m2 [wall]
REAL, DIMENSION(:), INTENT(IN)    :: PLOAD_IN_WIN   ! solar + inter. heat gains W/m2 [win]
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZRAD_WL_WIN   ! rad. fluxes between averaged wall and win [W m-2(wall)]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZRAD_WL_A_WIN ! rad. fluxes between one wall and win [W m-2(wall)]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZEMIS_WIN     ! window emissivity
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZEMIT_LW_WIN  ! Longwave radiation emitted by the window [W m-2(window)]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZEMIT_LW_WL_A ! Longwave radiation emitted by the wall [W m-2(wall)]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZEMIT_LW_WL_B ! Longwave radiation emitted by the wall [W m-2(wall)]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZTS_WL_A    ! surface temperature of wall A at previous time-step
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZTS_WL_B    ! surface temperature of wall B at previous time-step
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZTI_WL_A    ! internal temperature of wall A at previous time-step
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZTI_WL_B    ! internal temperature of wall B at previous time-step
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZTS_WL      ! surface temperature of averaged wall at new time-step
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZIMB_WL     ! wall residual energy imbalance for verification [W m-2]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZRAD_WL_FL! rad. fluxes from wall to floor [W m-2(wall)]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZRAD_WL_MA ! rad. fluxes from wall to mass [W m-2(wall)]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZCONV_WL_BLD ! conv. fluxes from wall to bld [W m-2(wall)]
REAL, DIMENSION(SIZE(B%XTI_BLD)) :: ZLW_W_TO_WIN   ! Radiative heat trasfer coeff wall-window [W K-1 m-2]
INTEGER                        :: IWL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('FACADE_E_BUDGET',0,zhook_handle)
!-------------------------------------------------------------------------------
prad_wl_fl= xundef
prad_wl_ma = xundef
prad_win_fl = xundef
prad_win_ma  = xundef
pconv_wl_bld = xundef
pconv_win_bld  = xundef
!
!* surface temperature of the opposite wall
!  ----------------------------------------
!
zts_wl_a(:) = t%XT_WALL_A(:,1)
zts_wl_b(:) = t%XT_WALL_B(:,1)
iwl = SIZE(t%XT_WALL_A,2)
zti_wl_a(:) = t%XT_WALL_A(:,iwl)
zti_wl_b(:) = t%XT_WALL_B(:,iwl)
!
! *Convection heat transfer coefficients [W m-2 K-1] from EP Engineering Reference
! --------------------------------------------------------------------------------
!
!
! *opaque balance of the facade for wall A
!  ---------------------------------------
!
 CALL wall_layer_e_budget(top, t, b, t%XT_WALL_A, zts_wl_b, zti_wl_b, ptstep, pdn_rd, &
                          prhoa, pac_wl, pac_bld, plw_rad, pps, pexns, dmt%XABS_SW_WALL_A,&
                          pt_canyon, pts_rd, ptsn_rd, pts_gd, pts_fl, plw_wa_to_wb,   &
                          plw_r_to_wa, plw_g_to_wa, plw_nr_to_wa, plw_win_to_wa,      &
                          plw_s_to_wa, pflx_bld_wl_a, pdqs_wl_a, dmt%XABS_LW_WALL_A, &
                          zemit_lw_wl_a, dmt%XH_WALL_A, zimb_wl, pradht_in, prad_rf_wl, &
                          zrad_wl_a_win, zrad_wl_fl, zrad_wl_ma, zconv_wl_bld,        &
                          pload_in_wl)
!
pimb_wl      = 0.5 * zimb_wl
prad_wl_fl   = 0.5 * zrad_wl_fl
prad_wl_ma   = 0.5 * zrad_wl_ma 
pconv_wl_bld = 0.5 * zconv_wl_bld 
zrad_wl_win  = 0.5 * zrad_wl_a_win
!
! *opaque balance of the facade for wall B
!  ---------------------------------------
!
IF (top%CWALL_OPT/='UNIF') THEN
 CALL wall_layer_e_budget(top, t, b, t%XT_WALL_B, zts_wl_a, zti_wl_a, ptstep, pdn_rd, &
                          prhoa, pac_wl, pac_bld, plw_rad, pps, pexns, dmt%XABS_SW_WALL_B, &
                          pt_canyon, pts_rd, ptsn_rd, pts_gd, pts_fl, plw_wa_to_wb,   &
                          plw_r_to_wb, plw_g_to_wb, plw_nr_to_wb, plw_win_to_wb,      &
                          plw_s_to_wb, pflx_bld_wl_b, pdqs_wl_b, dmt%XABS_LW_WALL_B,   &
                          zemit_lw_wl_b, dmt%XH_WALL_B, zimb_wl, pradht_in, prad_rf_wl,&
                          zrad_wl_a_win, zrad_wl_fl, zrad_wl_ma, zconv_wl_bld,        & 
                          pload_in_wl                                                )
ELSE
  t%XT_WALL_B    = t%XT_WALL_A
  dmt%XH_WALL_B        = dmt%XH_WALL_A
  dmt%XABS_LW_WALL_B   = dmt%XABS_LW_WALL_A
  pdqs_wl_b      = pdqs_wl_a
  pflx_bld_wl_b  = pflx_bld_wl_a
  zemit_lw_wl_b  = zemit_lw_wl_a
END IF
!
pimb_wl      = pimb_wl      + 0.5 * zimb_wl
prad_wl_fl   = prad_wl_fl   + 0.5 * zrad_wl_fl
prad_wl_ma   = prad_wl_ma   + 0.5 * zrad_wl_ma 
pconv_wl_bld = pconv_wl_bld + 0.5 * zconv_wl_bld 
zrad_wl_win  = zrad_wl_win  + 0.5 * zrad_wl_a_win
!
!-------------------------------------------------------------------------------
!
! *Energy Balance for windows (averaged on both walls)
!  ---------------------------------------------------
!
IF (top%CBEM == 'DEF') THEN
  zemit_lw_win(:) = 0.
END IF
!
IF (top%CBEM == 'BEM') THEN
   zemis_win(:) = 0.84 ! From Engineering Reference documentation p219 
                       ! (see http://apps1.eere.energy.gov/buildings/energyplus/
   zlw_w_to_win(:) = plw_wa_to_win(:) + plw_wb_to_win(:)
   zts_wl(:) = xundef
   WHERE (zlw_w_to_win(:)>0.) &
   zts_wl(:) = ( plw_wa_to_win(:)*t%XT_WALL_A(:,1)+plw_wb_to_win(:)*t%XT_WALL_B(:,1) ) / zlw_w_to_win(:)
   CALL window_e_budget(b, zemis_win, zlw_w_to_win, plw_r_to_win, plw_g_to_win, plw_nr_to_win, &
                        plw_s_to_win, prad_rf_win, zrad_wl_win, dmt%XABS_SW_WIN, plw_rad, pac_win, &
                        pradht_in, pts_fl, prhoa, pdn_rd,  pt_canyon, zts_wl, pts_rd, ptsn_rd, &
                        pts_gd, prad_win_fl, prad_win_ma, pconv_win_bld, zemit_lw_win,          &
                        dmt%XABS_LW_WIN, pload_in_win                                   )
ENDIF

!*        wall, and win emitted LW radiation on snow-free surfaces
!         ----------------------------------------------------------------
!
!
pemit_lw_fac(:) = 0.5*(zemit_lw_wl_a(:)+zemit_lw_wl_b(:)) * (1-b%XGR(:)) +  zemit_lw_win(:) * b%XGR(:)
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('FACADE_E_BUDGET',1,zhook_handle)
END SUBROUTINE facade_e_budget