window_e_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
SUBROUTINE window_e_budget(B, PEMIS_WIN, PLW_W_TO_WIN, PLW_R_TO_WIN, PLW_G_TO_WIN, &
                           PLW_NR_TO_WIN, PLW_S_TO_WIN, PRAD_RF_WIN, PRAD_WL_WIN,  &
                           PABS_SW_WIN, PLW_RAD, PAC_WL, PRADHT_IN, PTS_FL, PRHOA, &
                           PDN_RD, PT_CANYON, PTS_WL, PTS_RD, PTSN_RD, PTS_GD,     &
                           PRAD_WIN_FL, PRAD_WIN_MA, PCONV_WIN_BLD, PEMIT_LW_WIN,  &
                           PABS_LW_WIN, PLOAD_IN_WIN)
!###################################################################################################################################
!
!!****  *WINDOW_E_BUDGET*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evoultion of window temperature
!         
!     
!!**  METHOD
!     ------
!
! window is supposed double pane with no thermal capacity
! a steady state energy balance is applied to both layers that exchanges U_WIN(T1 - T2)
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      B. Bueno           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    04/2011 
!!      G. Pigeon   10/11/2011 exteranlized window balance from wall_layer_e_budget to window_e_budget and use fluxes from layers for
!                              which the balance has been computed before (roof and wall) and returns the fluxes to the compartments
!                              computed afterwards (floor, mass, bld)
!!      G. Pigeon      09/2012 new indoor conv. coef
!!      G. Pigeon      10/2012 separate abs from outdoor on both side of window
!!                            + add loads for indoor face of the window
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_bem_n, ONLY : bem_t
!
USE modd_csts,ONLY : xcpd, xstefan
USE mode_conv_doe
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
TYPE(bem_t), INTENT(INOUT) :: B
!
REAL, DIMENSION(:), INTENT(IN)    :: PEMIS_WIN    ! window emissivity
REAL, DIMENSION(:), INTENT(IN)    :: PLW_W_TO_WIN ! Radiative heat trasfer coeff window-wall outdoor
                                                  ! [W K-1 m-2] 
REAL, DIMENSION(:), INTENT(IN)    :: PLW_R_TO_WIN ! Radiative heat trasfer coeff window-road 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PLW_G_TO_WIN ! Radiative heat trasfer coeff window-garden
REAL, DIMENSION(:), INTENT(IN)    :: PLW_NR_TO_WIN! Radiative heat trasfer coeff window-snow
REAL, DIMENSION(:), INTENT(IN)    :: PLW_S_TO_WIN ! Radiative heat trasfer coeff window-sky 
                                                  ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PRAD_RF_WIN  ! rad. fluxes from roof to win [W m-2(roof)]
REAL, DIMENSION(:), INTENT(IN)    :: PRAD_WL_WIN  ! rad. fluxes from wall to win [W m-2(roof)]
REAL, DIMENSION(:), INTENT(IN)    :: PABS_SW_WIN  ! window absorbed shortwave radiation [W m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PLW_RAD      ! atmospheric infrared radiation
REAL, DIMENSION(:), INTENT(IN)    :: PAC_WL     ! aerodynamical conductance between wall and canyon
REAL, DIMENSION(:),   INTENT(IN)  :: PRADHT_IN     ! Indoor radiant heat transfer coefficient
                                                    ! [W K-1 m-2]
REAL, DIMENSION(:), INTENT(IN)    :: PTS_FL    ! floor layers temperatures [K]
REAL, DIMENSION(:), INTENT(IN)    :: PRHOA        ! rho
REAL, DIMENSION(:), INTENT(IN)    :: PDN_RD     ! snow-covered fraction on roads
REAL, DIMENSION(:), INTENT(IN)    :: PT_CANYON    ! air canyon temperature
REAL, DIMENSION(:), INTENT(IN)    :: PTS_WL     ! wall outdoor surface temperature
REAL, DIMENSION(:), INTENT(IN)    :: PTS_RD     ! road surface temperature
REAL, DIMENSION(:), INTENT(IN)    :: PTSN_RD  ! road snow temperature
REAL, DIMENSION(:), INTENT(IN)    :: PTS_GD   ! green area surface temperature
REAL, DIMENSION(:), INTENT(OUT)   :: PRAD_WIN_FL ! rad. fluxes from window to floor [W m-2(window)]
REAL, DIMENSION(:), INTENT(OUT)   :: PRAD_WIN_MA  ! rad. fluxes from window to mass [W m-2(window)]
REAL, DIMENSION(:), INTENT(OUT)   :: PCONV_WIN_BLD  ! conv. fluxes from window to bld [W m-2(window)]
REAL, DIMENSION(:), INTENT(OUT)   :: PEMIT_LW_WIN  ! Longwave radiation emitted by the window [W m-2(window)]
REAL, DIMENSION(:), INTENT(OUT)   :: PABS_LW_WIN   ! Longwave radiation absorbed by the window [W m-2(window)]
REAL, DIMENSION(:), INTENT(IN)    :: PLOAD_IN_WIN  ! solar + internal heat gain 
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PT_CANYON)) :: ZT_SKY         ! sky temperature [K]
REAL, DIMENSION(SIZE(PT_CANYON)) :: ZA12           ! 
REAL, DIMENSION(SIZE(PT_CANYON)) :: ZB2            ! auxiliar variables for window temperature
REAL, DIMENSION(SIZE(PT_CANYON)) :: ZB1            ! calculations
REAL, DIMENSION(SIZE(PT_CANYON)) :: ZA21           !
REAL, DIMENSION(SIZE(PT_CANYON)) :: ZCHTC_IN_WIN   ! indoor convective heat transfer coef. window [W m-2 K-1]
INTEGER :: JJ

!*      Preliminaries
!       -------------
zchtc_in_win = chtc_vert_doe(b%XT_WIN2, b%XTI_BLD)
DO jj=1,SIZE(zchtc_in_win)
   zchtc_in_win(jj) = max(1., zchtc_in_win(jj))
ENDDO

!*      1.    Sky temperature
!             ---------------
zt_sky(:) = (plw_rad(:)/xstefan)**0.25
!  
za12(:) = zchtc_in_win(:)   &
         + pradht_in(:) * b%XF_WIN_MASS (:)  &
         + pradht_in(:) * b%XF_WIN_FLOOR(:) &
         + b%XUGG_WIN(:)
!
zb1(:)  = zchtc_in_win(:) * b%XTI_BLD (:)             &
         + pradht_in(:) * b%XF_WIN_MASS(:) * b%XT_MASS(:,1)             &
         + b%XF_WIN_WALL (:) * prad_wl_win(:) &
         + b%XF_WIN_FLOOR(:) * prad_rf_win(:) &
         + pradht_in(:) * b%XF_WIN_FLOOR(:)* pts_fl(:) &
         + pload_in_win(:) + pabs_sw_win(:) /2.
!
za21(:) = - pac_wl(:) * prhoa(:)*xcpd   &
          - plw_s_to_win(:)                  &
          - plw_w_to_win(:)                  &
          - plw_r_to_win(:) *(1.-pdn_rd(:))&
          - plw_g_to_win(:)                  &
          - plw_nr_to_win(:) * pdn_rd(:)    &
          - b%XUGG_WIN(:)
!
zb2(:)  = - pac_wl(:) * prhoa(:)*xcpd*pt_canyon(:)   &
          - plw_s_to_win(:) * zt_sky(:)                     &
          - plw_w_to_win(:) * pts_wl(:)                   &
          - plw_r_to_win(:) *(1.-pdn_rd(:)) * pts_rd(:) &
          - plw_nr_to_win(:) * pdn_rd(:) * ptsn_rd(:) &
          - pabs_sw_win(:) /2.
!
IF (SIZE(pts_gd)>0) THEN
  zb2(:) = zb2(:) - plw_g_to_win(:) * pts_gd(:)
ENDIF
!
! compute outdoor temperature
b%XT_WIN1(:) = ( zb2(:) - zb1(:)*b%XUGG_WIN(:)/za12(:) ) / &
                  ( za21(:) + b%XUGG_WIN(:)**2/za12(:) )
!
! compute indoor temperature
b%XT_WIN2(:) = (zb1(:) + b%XUGG_WIN(:)*b%XT_WIN1(:) ) / za12(:)
!
! outdoor infrared radiation absorded by the window
pabs_lw_win(:)    = plw_s_to_win(:) * (zt_sky(:) - b%XT_WIN1(:)) + &
  (1.-pdn_rd(:)) *  plw_r_to_win(:) * (pts_rd(:) - b%XT_WIN1(:)) + &
                    plw_w_to_win(:) * (pts_wl(:) - b%XT_WIN1(:)) + &
        pdn_rd(:) * plw_nr_to_win(:) * (ptsn_rd(:) - b%XT_WIN1(:))
!
IF (SIZE(pts_gd)>0) THEN
  pabs_lw_win(:) = pabs_lw_win(:) +  plw_g_to_win(:) * (pts_gd(:) - b%XT_WIN1(:))      
ENDIF
!
! outdoor infrared radiation emited by the window
pemit_lw_win(:) = xstefan * b%XT_WIN1(:)**4 + (1 - pemis_win(:))/pemis_win(:) * pabs_lw_win(:)
!
prad_win_fl(:)  = pradht_in(:)    * (b%XT_WIN2(:) - pts_fl(:))
prad_win_ma(:)  = pradht_in(:)    * (b%XT_WIN2(:) - b%XT_MASS(:,1))
pconv_win_bld(:)  = zchtc_in_win(:) * (b%XT_WIN2(:) - b%XTI_BLD(:))
!
END SUBROUTINE window_e_budget