diag_inline_watfluxn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_inline_watflux_n (DGO, D, DC, W, &
                                         PTSTEP, PTA, PQA, PPA, PPS, PRHOA, PZONA,  &
                                         PMERA, PHT, PHW, PCD, PCDN, PCH, PRI, PHU, &
                                         PZ0H, PQSAT, PSFTH, PSFTQ, PSFZON, PSFMER, &
                                         PDIR_SW, PSCA_SW, PLW, PDIR_ALB, PSCA_ALB, &
                                         PEMIS, PTRAD, PRAIN, PSNOW, PSFTH_ICE,     &
                                         PSFTQ_ICE                                  )  
!     ###############################################################################
!
!!****  *DIAG_INLINE_WATFLUX_n * - computes diagnostics during WATFLUX time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      B. Decharme 08/2009 : Diag for Earth System Model Coupling
!!      S. Riette   06/2009 CLS_2M becomes CLS_TQ, CLS_TQ and CLS_WIND have one
!!                          more argument (height of diagnostic)
!       B. decharme 04/2013 : Add EVAP and SUBL diag
!!------------------------------------------------------------------
!

!
!
!
USE modd_diag_n, ONLY : diag_t, diag_options_t
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_csts,           ONLY : xtt
USE modd_surf_par,       ONLY : xundef
USE modd_sfx_oasis,      ONLY : lcpl_sea, lcpl_seaice
!
USE modi_cls_tq
USE modi_cls_wind
USE modi_diag_surf_budget_water
USE modi_diag_surf_budgetc
USE modi_diag_cpl_esm_water
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_options_t), INTENT(INOUT) :: DGO
TYPE(diag_t), INTENT(INOUT) :: D
TYPE(diag_t), INTENT(INOUT) :: DC
TYPE(watflux_t), INTENT(INOUT) :: W
!
REAL,               INTENT(IN) :: PTSTEP ! atmospheric time-step                 (s)
REAL, DIMENSION(:), INTENT(IN) :: PTA    ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN) :: PQA    ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN) :: PPA    ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN) :: PPS    ! surface pressure
REAL, DIMENSION(:), INTENT(IN) :: PRHOA  ! air density
REAL, DIMENSION(:), INTENT(IN) :: PZONA  ! zonal wind
REAL, DIMENSION(:), INTENT(IN) :: PMERA  ! meridian wind
REAL, DIMENSION(:), INTENT(IN) :: PHT    ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN) :: PHW    ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN) :: PCD    ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN) :: PCDN   ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN) :: PCH    ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN) :: PRI    ! Richardson number
REAL, DIMENSION(:), INTENT(IN) :: PHU    ! near-surface humidity
REAL, DIMENSION(:), INTENT(IN) :: PZ0H   ! roughness length for heat
REAL, DIMENSION(:), INTENT(IN) :: PQSAT  ! humidity at saturation
REAL, DIMENSION(:), INTENT(IN) :: PSFZON ! zonal friction
REAL, DIMENSION(:), INTENT(IN) :: PSFMER ! meridian friction
REAL, DIMENSION(:), INTENT(IN) :: PSFTH  ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PSFTQ  ! water flux (kg/m2/s)
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_SW   ! direct  solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_SW   ! diffuse solar radiation (on horizontal surf.)
!                                           !                                       (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PLW       ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN) :: PTRAD     ! radiative temperature                 (K)
REAL, DIMENSION(:,:),INTENT(IN):: PDIR_ALB  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN):: PSCA_ALB  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN) :: PEMIS     ! emissivity                            (-)
!
REAL, DIMENSION(:), INTENT(IN) :: PRAIN     ! Rainfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: PSNOW     ! Snowfall (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN) :: PSFTH_ICE ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN) :: PSFTQ_ICE ! water flux (kg/m2/s)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PTA)) :: ZH
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_WATFLUX_N',0,zhook_handle)
!
! * Mean surface temperature need to couple with AGCM
!
d%XTS(:) = w%XTS(:)
!
IF (.NOT. w%LSBL) THEN
!
  IF (dgo%N2M==2) THEN
    zh(:)=2.          
    CALL cls_tq(pta, pqa, ppa, pps, pht, pcd, pch, pri, &
                w%XTS, phu, pz0h, zh, d%XT2M, d%XQ2M, d%XHU2M )  
    zh(:)=10.                
    CALL cls_wind(pzona, pmera, phw, pcd, pcdn, pri, zh, d%XZON10M, d%XMER10M )  
  END IF
!
  IF (dgo%N2M>=1) THEN
    !
    d%XT2M_MIN(:) = min(d%XT2M_MIN(:),d%XT2M(:))
    d%XT2M_MAX(:) = max(d%XT2M_MAX(:),d%XT2M(:))
    !
    d%XHU2M_MIN(:) = min(d%XHU2M_MIN(:),d%XHU2M(:))
    d%XHU2M_MAX(:) = max(d%XHU2M_MAX(:),d%XHU2M(:))
    !
    d%XWIND10M (:) = sqrt(d%XZON10M(:)**2+d%XMER10M(:)**2)
    d%XWIND10M_MAX(:) = max(d%XWIND10M_MAX(:),d%XWIND10M(:))
    !
    !* Richardson number
    d%XRI = pri
    !
  ENDIF
!
ELSE
  IF (dgo%N2M>=1) THEN
    d%XT2M    = xundef
    d%XQ2M    = xundef
    d%XHU2M   = xundef
    d%XZON10M = xundef
    d%XMER10M = xundef
    d%XRI     = pri
  ENDIF
ENDIF
!
IF (dgo%LSURF_BUDGET.OR.dgo%LSURF_BUDGETC) THEN
  !
  CALL  diag_surf_budget_water (d, xtt, w%XTS, prhoa, psfth, psftq, pdir_sw, psca_sw, plw,  &
                                pdir_alb, psca_alb, pemis, ptrad, psfzon, psfmer )  
  !
END IF
!
IF(dgo%LSURF_BUDGETC) CALL diag_surf_budgetc(d, dc, ptstep, .true.)  
!
IF (dgo%LCOEF) THEN
  !
  !* Transfer coefficients
  !
  d%XCD = pcd
  d%XCH = pch
  d%XCE = pch
  !
  !* Roughness lengths
  !
  d%XZ0  = w%XZ0
  d%XZ0H = pz0h
  !
ENDIF
!
IF (dgo%LSURF_VARS) THEN
  !
  !* Humidity at saturation
  !
  d%XQS = pqsat
  !
ENDIF
!
! Diag for Earth System Model coupling
!
IF (lcpl_sea) THEN
!
  CALL diag_cpl_esm_water(w, d, lcpl_seaice, ptstep, psftq, prain, psnow, plw, &
                          psfth_ice, psftq_ice, pdir_sw, psca_sw )  
! 
ENDIF
IF (lhook) CALL dr_hook('DIAG_INLINE_WATFLUX_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_watflux_n