diag_inline_tebn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
       SUBROUTINE diag_inline_teb_n (DGO, D, SB, T, &
                                     OCANOPY, PTA, PTS, PQA, PPA, PPS, PRHOA,                &
                                     PZONA, PMERA, PWIND, PHT, PHW,                          &
                                     PCD, PCDN, PRI, PCH, PZ0,                               &
                                     PTRAD, PEMIS, PDIR_ALB, PSCA_ALB,                       &
                                     PLW, PDIR_SW, PSCA_SW,                                  &
                                     PSFTH, PSFTQ, PSFZON, PSFMER, PSFCO2,                   &
                                     PRN, PH, PLE, PGFLUX                                    )  
!     ###############################################################################!
!!****  *DIAG_INLINE_TEB_n * - Computes diagnostics during TEB time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette   06/2009 CLS_WIND has one more argument (height of diagnostic)
!!      S. Riette   01/2010 Use of interpol_sbl to compute 10m wind diagnostic
!       B. decharme 04/2013 : Add EVAP and SUBL diag
!!------------------------------------------------------------------
!

!
!
!
USE modd_diag_n, ONLY : diag_t, diag_options_t
USE modd_canopy_n, ONLY : canopy_t
USE modd_teb_n, ONLY : teb_t
!
USE modd_surf_par,   ONLY : xundef
!
USE modi_cls_wind
USE modi_diag_surf_budget_teb
USE modi_interpol_sbl
!
USE mode_thermos
USE mode_coupling_canopy
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_options_t), INTENT(INOUT) :: DGO
TYPE(diag_t), INTENT(INOUT) :: D
TYPE(canopy_t), INTENT(INOUT) :: SB
TYPE(teb_t), INTENT(INOUT) :: T
!
LOGICAL,            INTENT(IN)       :: OCANOPY  ! Flag for canopy
REAL, DIMENSION(:), INTENT(IN)       :: PTA      ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN)       :: PTS      ! surface temperature
REAL, DIMENSION(:), INTENT(IN)       :: PQA      ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN)       :: PPA      ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN)       :: PPS      ! surface pressure
REAL, DIMENSION(:), INTENT(IN)       :: PRHOA    ! air density
REAL, DIMENSION(:), INTENT(IN)       :: PZONA    ! zonal wind
REAL, DIMENSION(:), INTENT(IN)       :: PMERA    ! meridian wind
REAL, DIMENSION(:), INTENT(IN)       :: PWIND    ! wind
REAL, DIMENSION(:), INTENT(IN)       :: PHT      ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN)       :: PHW      ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN)       :: PCD      ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN)       :: PCDN     ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN)       :: PSFZON   ! zonal friction
REAL, DIMENSION(:), INTENT(IN)       :: PSFMER   ! meridian friction
REAL, DIMENSION(:), INTENT(IN)       :: PSFCO2   ! CO2 flux   (m/s*kg_CO2/kg_air)
REAL, DIMENSION(:), INTENT(IN)       :: PSFTH    ! heat flux  (W/m2)
REAL, DIMENSION(:), INTENT(IN)       :: PSFTQ    ! water flux (kg/m2/s)
REAL, DIMENSION(:), INTENT(IN)       :: PRI      ! Richardson number
REAL, DIMENSION(:), INTENT(IN)       :: PCH      ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN)       :: PZ0      ! roughness length for momentum
REAL, DIMENSION(:), INTENT(IN)       :: PRN      ! net radiation
REAL, DIMENSION(:), INTENT(IN)       :: PH       ! sensible heat flux
REAL, DIMENSION(:), INTENT(IN)       :: PLE      ! latent heat flux
REAL, DIMENSION(:), INTENT(IN)       :: PGFLUX   ! storage flux
REAL, DIMENSION(:,:),INTENT(IN)      :: PDIR_SW  ! direct  solar radiation (on horizontal surf.)
!                                                !                                      (W/m2)
REAL, DIMENSION(:,:),INTENT(IN)      :: PSCA_SW  ! diffuse solar radiation (on horizontal surf.)
!                                                !                                      (W/m2)
REAL, DIMENSION(:), INTENT(IN)       :: PLW      ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN)       :: PTRAD    ! radiative temperature                 (K)
REAL, DIMENSION(:,:),INTENT(IN)      :: PDIR_ALB ! direct albedo for each spectral band  (-)
REAL, DIMENSION(:,:),INTENT(IN)      :: PSCA_ALB ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:), INTENT(IN)       :: PEMIS    ! emissivity                            (-)
!
!*      0.2    declarations of local variables
!
REAL                                 :: ZZ0_O_Z0H
REAL, DIMENSION(SIZE(PTA))           :: ZH  
REAL, DIMENSION(SIZE(PTA))  :: ZU10
REAL, DIMENSION(SIZE(PTA))  :: ZWIND10M_MAX
REAL, DIMENSION(SIZE(PTA))  :: ZT2M_MIN
REAL, DIMENSION(SIZE(PTA))  :: ZT2M_MAX
REAL, DIMENSION(SIZE(PTA))  :: ZHU2M_MIN
REAL, DIMENSION(SIZE(PTA))  :: ZHU2M_MAX
INTEGER                              :: JJ    ! loop counter

REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_TEB_N',0,zhook_handle)
!
! * Mean surface temperature need to couple with AGCM
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Here it is the radiative temperature that is wrong !
!It should be the arithmetic mean of the surface temperature
!of each independant energy budget, if there is. See ISBA for more detail.
!
d%XTS(:) = pts(:)
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
zz0_o_z0h = 200.
!
!* 2m and 10m variables interpolated from canopy if used
!
IF (ocanopy) THEN
  zt2m_min(:) = xundef
  zt2m_max(:) = xundef
  zhu2m_min(:) = xundef
  zhu2m_max(:) = xundef
  zwind10m_max(:) = xundef
  IF (dgo%N2M>0) CALL init_2m_10m( sb, d, pzona, pmera, pwind, prhoa )
ELSE
!* 2m and 10m variables using CLS laws
  IF (dgo%N2M==2) THEN
    zh(:)=10.
    CALL cls_wind(pzona, pmera, phw, pcd, pcdn, pri, zh, d%XZON10M, d%XMER10M    )  
    d%XT2M  = t%XT_CANYON
    d%XQ2M  = t%XQ_CANYON
    d%XRI   = pri
    d%XHU2M = min(t%XQ_CANYON /qsat(t%XT_CANYON,ppa),1.)
  END IF
  !
  IF (dgo%N2M>=1) THEN
    !
    d%XT2M_MIN(:) = min(d%XT2M_MIN(:),d%XT2M(:))
    d%XT2M_MAX(:) = max(d%XT2M_MAX(:),d%XT2M(:))
    !
    d%XHU2M_MIN(:) = min(d%XHU2M_MIN(:),d%XHU2M(:))
    d%XHU2M_MAX(:) = max(d%XHU2M_MAX(:),d%XHU2M(:))
    !
    d%XWIND10M    (:) = sqrt(d%XZON10M**2+d%XMER10M**2)
    d%XWIND10M_MAX(:) = max(d%XWIND10M_MAX(:),d%XWIND10M(:))
    !
  END IF
ENDIF
!
IF (dgo%LSURF_BUDGET) THEN
   !
   CALL diag_surf_budget_teb(d, pdir_sw, psca_sw, pdir_alb, psca_alb, plw, pemis, ptrad   )  
   !                             
   d%XRN    = prn
   d%XH     = ph
   d%XLE    = ple
   d%XGFLUX = pgflux
   d%XFMU   = psfzon
   d%XFMV   = psfmer
   d%XSFCO2 = psfco2
   !
END IF
!
IF (dgo%LCOEF) THEN
  d%XCD    = pcd
  d%XCH    = pch
  d%XCE    = pch
  d%XZ0    = pz0
  d%XZ0H   = pz0 / zz0_o_z0h
END IF
!
IF (dgo%LSURF_VARS) THEN
  d%XQS    = t%XQ_CANYON
END IF
IF (lhook) CALL dr_hook('DIAG_INLINE_TEB_N',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_teb_n