convert_patch_isba.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE convert_patch_isba (DTCO, DTV, IO, KDEC, KDEC2, PCOVER, OCOVER,&
                                     OAGRIP, HSFTYPE, KPATCH, KK, PK, PEK, OFIX, OTIME, &
                                     OMEB, OIRR, OALB, OUPDATE_ALB, PSOILGRID, PWG1, PWSAT, PPERM )
!     ##############################################################
!
!!**** *CONVERT_PATCH_ISBA* 
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    16/11/10
!!      V. Masson    04/14 Garden and Greenroofs can only be initialized by ecoclimap 
!!                         in this routine (not from user specified parameters from
!!                         the nature tile, as the number of points is not the same)
!!    B. Decharme  04/2013  Add CDGAVG (method to average depth)
!!                          Soil depth = Root depth with ISBA-DF
!!                           except for bare soil pft (but limited to 1m)
!!                          With TR_ML (new radiative transfert) and modis
!!                           albedo, UV albedo not defined (conserv nrj when
!!                           coupled to atmosphere)
!!    P Samuelsson  10/2014  MEB
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_isba_n, ONLY : data_isba_t
USE modd_isba_options_n, ONLY : isba_options_t
!
USE modd_isba_n, ONLY : isba_p_t, isba_pe_t, isba_k_t
!
USE modd_data_cover_par, ONLY : nvegtype, nvt_no, nvt_rock, nvt_snow
!
USE modd_type_date_surf
!
!
USE modd_data_cover,     ONLY : xdata_lai, xdata_h_tree,                &
                                xdata_veg, xdata_z0, xdata_z0_o_z0h,    &
                                xdata_emis_eco, xdata_gamma, xdata_cv,  &
                                xdata_rgl, xdata_rsmin,                 &
                                xdata_albnir_veg, xdata_albvis_veg,     &
                                xdata_albuv_veg,                        &
                                xdata_alb_veg_nir, xdata_alb_veg_vis,   &
                                xdata_alb_soil_nir, xdata_alb_soil_vis, &
                                xdata_gmes, xdata_bslai, xdata_laimin,  &
                                xdata_sefold, xdata_gc, xdata_wrmax_cf, &
                                xdata_stress,                           &
                                xdata_dmax, xdata_f2i, xdata_re25,      &
                                xdata_ce_nitro, xdata_cf_nitro,         &
                                xdata_cna_nitro, xdata_dice,            &
                                xdata_gmes_st, xdata_bslai_st,          &
                                xdata_sefold_st, xdata_gc_st,           &
                                xdata_dmax_st, xdata_watsup,            &
                                xdata_gndlitter, xdata_z0litter, xdata_h_veg,  &
                                tdata_seed, tdata_reap,xdata_irrig,     &
                                xdata_root_depth, xdata_ground_depth,   &
                                xdata_root_extinction, xdata_root_lin
!   
!
USE modd_treedrag,       ONLY : ltreedrag
!
USE modi_av_pgd_param
USE modi_av_pgd_1p
USE modi_soil_albedo
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(data_isba_t), INTENT(INOUT) :: DTV
TYPE(isba_options_t), INTENT(INOUT) :: IO
!
INTEGER,                INTENT(IN)    :: KDEC
INTEGER,                INTENT(IN)    :: KDEC2
REAL, DIMENSION(:,:),   INTENT(IN)    :: PCOVER
LOGICAL, DIMENSION(:),  INTENT(IN)    :: OCOVER
LOGICAL,                INTENT(IN)    :: OAGRIP
 CHARACTER(LEN=*),       INTENT(IN)    :: HSFTYPE ! nature / garden
INTEGER, INTENT(IN) :: KPATCH
!
TYPE(isba_k_t), INTENT(INOUT) :: KK
TYPE(isba_p_t), INTENT(INOUT) :: PK
TYPE(isba_pe_t), INTENT(INOUT) :: PEK
!
LOGICAL, INTENT(IN) :: OFIX
LOGICAL, INTENT(IN) :: OTIME
LOGICAL, INTENT(IN) :: OMEB
LOGICAL, INTENT(IN) :: OIRR
LOGICAL, INTENT(IN) :: OALB
LOGICAL, INTENT(IN) :: OUPDATE_ALB
!
REAL, DIMENSION(:),   OPTIONAL, INTENT(IN)   :: PWG1
REAL, DIMENSION(:,:),   OPTIONAL, INTENT(IN)   :: PWSAT
REAL, DIMENSION(:),   OPTIONAL, INTENT(IN)   :: PPERM
!
REAL, DIMENSION(:)  ,   OPTIONAL, INTENT(IN)    :: PSOILGRID
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
REAL, DIMENSION(:), ALLOCATABLE :: ZWORKI
 CHARACTER(LEN=3)  :: YTREE, YNAT, YLAI, YVEG, YBAR, YDIF
!
INTEGER               :: JLAYER    ! loop counter on layers
INTEGER               :: JVEG  ! loop counter on vegtypes
!
LOGICAL               :: GDATA     ! Flag where initialization can be done
!                                  ! either with ecoclimap of data fields specified
!                                  ! by user on the natural points (GDTA=T)
!                                  ! For fields in town, only ecoclimap option
!                                  ! is treated in this routine (GDATA=F)
INTEGER               :: JJ        ! loop counter
!
INTEGER               :: ISIZE_LMEB_PATCH  ! Number of patches with MEB=true
!
REAL, ALLOCATABLE, DIMENSION(:) :: ZH_VEG
!
!
!*    0.3    Declaration of namelists
!            ------------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('CONVERT_PATCH_ISBA',0,zhook_handle)
!
IF (ASSOCIATED(dtco%XDATA_WEIGHT)) DEALLOCATE(dtco%XDATA_WEIGHT)
!
IF (hsftype=='NAT') THEN
  ynat='NAT'
  ytree='TRE'
  ylai='LAI'
  yveg='VEG'
  ybar='BAR'
  ydif='DVG'
  gdata=.true.
  isize_lmeb_patch = count(io%LMEB_PATCH(:))
ELSEIF (hsftype=='GRD') THEN
  ynat='GRD'
  ytree='GRT'
  ylai='GRL'
  yveg='GRV'
  ybar='GRB'
  ydif='GDV'
  gdata=.false.
  isize_lmeb_patch = 0
ENDIF
!
IF (ofix) THEN
  !
  !* soil layers and root fraction
!  -----------------------------
  !
  !   compute soil layers (and root fraction if DIF)
  !
  CALL set_grid_param(SIZE(pk%XDG,1),SIZE(pk%XDG,2))
!
!        D ICE
!        -----
!
  IF (io%CISBA/='DIF') THEN
    IF (gdata .AND. any(dtv%LDATA_DICE)) THEN
      CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                        pk%XD_ICE,dtv%XPAR_VEGTYPE,dtv%XPAR_DICE,ynat,'ARI',pk%NR_P,io%NPATCH,kpatch)
    ELSE
      CALL av_pgd_1p(dtco, pk%XD_ICE,pcover,xdata_dice(:,:),ynat,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
    ENDIF
  ENDIF
!
  IF (gdata .AND. any(dtv%LDATA_Z0_O_Z0H)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pk%XZ0_O_Z0H,dtv%XPAR_VEGTYPE,dtv%XPAR_Z0_O_Z0H,ynat,'ARI',pk%NR_P,io%NPATCH,kpatch)
  ELSE
    CALL av_pgd_1p(dtco, pk%XZ0_O_Z0H,pcover,xdata_z0_o_z0h,ynat,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ENDIF
!
  IF (io%CPHOTO/='NON'.OR.ltreedrag) THEN
    IF (gdata .AND. any(dtv%LDATA_H_TREE)) THEN
      CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pk%XH_TREE,dtv%XPAR_VEGTYPE,dtv%XPAR_H_TREE,ytree,'ARI',pk%NR_P,io%NPATCH,kpatch)
    ELSE
      CALL av_pgd_1p(dtco, pk%XH_TREE,pcover,xdata_h_tree(:,:),ytree,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
    ENDIF
  ENDIF
!
  IF (io%CPHOTO/='NON') THEN
    !
    IF (SIZE(pk%XRE25)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_RE25)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pk%XRE25,dtv%XPAR_VEGTYPE,dtv%XPAR_RE25,ynat,'ARI',pk%NR_P,io%NPATCH,kpatch)      
      ELSE
        CALL av_pgd_1p(dtco, pk%XRE25,pcover,xdata_re25,ynat,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
    !
    IF (SIZE(pk%XDMAX)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_DMAX)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pk%XDMAX,dtv%XPAR_VEGTYPE,dtv%XPAR_DMAX,ytree,'ARI',pk%NR_P,io%NPATCH,kpatch)
      ELSE
        CALL av_pgd_1p(dtco, pk%XDMAX,pcover,xdata_dmax_st,ytree,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
    !
  ENDIF
!
ENDIF
!
IF (otime) THEN
!
 IF (.NOT.oupdate_alb) THEN
!   VEG
!   ----
  IF (gdata .AND. any(dtv%LDATA_VEG)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, pek%XVEG,dtv%XPAR_VEGTYPE,dtv%XPAR_VEG(:,kdec2,:),&
            ynat,'ARI',pk%NR_P,io%NPATCH,kpatch)
  ELSE
    CALL av_pgd_1p(dtco, pek%XVEG,pcover,xdata_veg(:,kdec,:),ynat,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ENDIF
!
!   LAI
!   ----
  IF (gdata .AND. any(dtv%LDATA_LAI)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XLAI,dtv%XPAR_VEGTYPE,dtv%XPAR_LAI(:,kdec2,:),yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XLAI,pcover,xdata_lai(:,kdec,:),yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ENDIF
!
!           EMIS
!           ----
!emis needs VEG by vegtypes is changed at this step
  IF (gdata .AND. any(dtv%LDATA_EMIS)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XEMIS ,dtv%XPAR_VEGTYPE,dtv%XPAR_EMIS(:,kdec2,:),ynat,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch)
  ELSE
    CALL av_pgd_1p(dtco, pek%XEMIS ,pcover ,xdata_emis_eco(:,kdec,:),ynat,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ENDIF
!
!    Z0V
!    ----
  IF (gdata .AND. any(dtv%LDATA_Z0)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XZ0,dtv%XPAR_VEGTYPE,dtv%XPAR_Z0(:,kdec2,:),ynat,'CDN',&
                      pk%NR_P,io%NPATCH,kpatch)
  ELSE
    CALL av_pgd_1p(dtco, pek%XZ0 ,pcover ,xdata_z0(:,kdec,:),ynat,'CDN',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ENDIF
!
 ENDIF

  IF (gdata .AND. any(dtv%LDATA_ALBNIR_VEG)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XALBNIR_VEG,dtv%XPAR_VEGTYPE,dtv%XPAR_ALBNIR_VEG(:,kdec2,:),yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSEIF (io%CALBEDO=='CM13') THEN
    CALL av_pgd_1p(dtco, pek%XALBNIR_VEG,pcover,xdata_alb_veg_nir(:,kdec,:),yveg,'ARI', ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)    
  ELSE
    CALL av_pgd_1p(dtco, pek%XALBNIR_VEG,pcover,xdata_albnir_veg,yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
  ENDIF
!
  IF (gdata .AND. any(dtv%LDATA_ALBVIS_VEG)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XALBVIS_VEG,dtv%XPAR_VEGTYPE,dtv%XPAR_ALBVIS_VEG(:,kdec2,:),yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSEIF (io%CALBEDO=='CM13') THEN
    CALL av_pgd_1p(dtco, pek%XALBVIS_VEG,pcover,xdata_alb_veg_vis(:,kdec,:),yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)      
  ELSE
    CALL av_pgd_1p(dtco, pek%XALBVIS_VEG,pcover,xdata_albvis_veg,yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
  ENDIF
!
  IF ((io%CALBEDO=='CM13'.OR.io%LTR_ML)) THEN
    pek%XALBUV_VEG(:)=pek%XALBVIS_VEG(:)
  ELSEIF (gdata .AND. any(dtv%LDATA_ALBUV_VEG)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XALBUV_VEG,dtv%XPAR_VEGTYPE,dtv%XPAR_ALBUV_VEG(:,kdec2,:),yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XALBUV_VEG,pcover,xdata_albuv_veg,yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
  ENDIF
!
 IF (.NOT.oupdate_alb) THEN
!        Other parameters
!        ----------------
  IF( SIZE(pek%XRSMIN)>0) THEN
    IF (gdata .AND. any(dtv%LDATA_RSMIN)) THEN
      CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XRSMIN,dtv%XPAR_VEGTYPE,dtv%XPAR_RSMIN,ylai,'INV',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
    ELSE
      CALL av_pgd_1p(dtco, pek%XRSMIN,pcover,xdata_rsmin,ylai,'INV',&
              ocover,pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
    ENDIF
  ENDIF
!
  IF (gdata .AND. any(dtv%LDATA_GAMMA)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XGAMMA,dtv%XPAR_VEGTYPE,dtv%XPAR_GAMMA,yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XGAMMA,pcover,xdata_gamma,yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
  ENDIF
!
  IF (gdata .AND. any(dtv%LDATA_WRMAX_CF)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XWRMAX_CF,dtv%XPAR_VEGTYPE,dtv%XPAR_WRMAX_CF,yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XWRMAX_CF,pcover,xdata_wrmax_cf,yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
  ENDIF
!
  IF (gdata .AND. any(dtv%LDATA_RGL)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XRGL,dtv%XPAR_VEGTYPE,dtv%XPAR_RGL,yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XRGL,pcover,xdata_rgl,yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
  ENDIF
!
  IF (gdata .AND. any(dtv%LDATA_CV)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XCV,dtv%XPAR_VEGTYPE,dtv%XPAR_CV,yveg,'INV',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XCV,pcover,xdata_cv,yveg,'INV',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
  ENDIF
!
  IF (isize_lmeb_patch>0 .OR. io%CPHOTO/='NON') THEN

    IF( SIZE(pek%XBSLAI)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_BSLAI)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XBSLAI,dtv%XPAR_VEGTYPE,dtv%XPAR_BSLAI,yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
      ELSE
        CALL av_pgd_1p(dtco, pek%XBSLAI,pcover,xdata_bslai_st,yveg,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
  ENDIF
!
  IF (io%CPHOTO/='NON') THEN
  !
    IF (SIZE(pek%XLAIMIN)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_LAIMIN)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XLAIMIN,dtv%XPAR_VEGTYPE,dtv%XPAR_LAIMIN,yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
      ELSE
        CALL av_pgd_1p(dtco, pek%XLAIMIN,pcover,xdata_laimin,yveg,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF    
  !
    IF (SIZE(pek%XSEFOLD)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_SEFOLD)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XSEFOLD,dtv%XPAR_VEGTYPE,dtv%XPAR_SEFOLD,yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
      ELSE
        CALL av_pgd_1p(dtco, pek%XSEFOLD,pcover,xdata_sefold_st,yveg,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
    !
    IF ( SIZE(pek%XGMES)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_GMES)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XGMES,dtv%XPAR_VEGTYPE,dtv%XPAR_GMES,yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
      ELSE
        CALL av_pgd_1p(dtco, pek%XGMES,pcover,xdata_gmes_st,yveg,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
    !
    IF ( SIZE(pek%XGC)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_GC)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                          pek%XGC,dtv%XPAR_VEGTYPE,dtv%XPAR_GC,yveg,'ARI',&
                          pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
      ELSE
        CALL av_pgd_1p(dtco, pek%XGC,pcover,xdata_gc_st,yveg,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
    !
    IF (SIZE(pek%XF2I)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_F2I)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                    pek%XF2I,dtv%XPAR_VEGTYPE,dtv%XPAR_F2I,yveg,'ARI',&
                    pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
      ELSE
        CALL av_pgd_1p(dtco, pek%XF2I,pcover,xdata_f2i,yveg,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
    !
    IF (io%CPHOTO=='NIT' .OR. io%CPHOTO=='NCB') THEN
      !
      IF (SIZE(pek%XCE_NITRO)>0) THEN
        IF (gdata .AND. any(dtv%LDATA_CE_NITRO)) THEN
          CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                    pek%XCE_NITRO,dtv%XPAR_VEGTYPE,dtv%XPAR_CE_NITRO,yveg,'ARI',&
                    pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
        ELSE
          CALL av_pgd_1p(dtco, pek%XCE_NITRO,pcover,xdata_ce_nitro,yveg,'ARI',ocover,&
                  pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
        ENDIF
      ENDIF
      !
      IF (SIZE(pek%XCF_NITRO)>0) THEN
        IF (gdata .AND. any(dtv%LDATA_CF_NITRO)) THEN
          CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                    pek%XCF_NITRO,dtv%XPAR_VEGTYPE,dtv%XPAR_CF_NITRO,yveg,'ARI',&
                    pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
        ELSE
          CALL av_pgd_1p(dtco, pek%XCF_NITRO,pcover,xdata_cf_nitro,yveg,'ARI',ocover,&
                  pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
        ENDIF
      ENDIF
      !
      IF (SIZE(pek%XCNA_NITRO)>0) THEN
        IF (gdata .AND. any(dtv%LDATA_CNA_NITRO)) THEN
          CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                    pek%XCNA_NITRO,dtv%XPAR_VEGTYPE,dtv%XPAR_CNA_NITRO,yveg,'ARI',&
                    pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
        ELSE
          CALL av_pgd_1p(dtco, pek%XCNA_NITRO,pcover,xdata_cna_nitro,yveg,'ARI',ocover,&
                  pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
        ENDIF
      ENDIF
      !
    ENDIF
    !
  ENDIF
!
!       STRESS
!       --------
  IF (SIZE(pek%LSTRESS)>0) THEN
    CALL set_stress
  ENDIF
!
 ENDIF
!
ENDIF
!
IF (omeb .AND. .NOT.oupdate_alb) THEN
  !
!   GNDLITTER
!   ---------
  IF (gdata .AND. any(dtv%LDATA_GNDLITTER)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, pek%XGNDLITTER,dtv%XPAR_VEGTYPE,&
                        dtv%XPAR_GNDLITTER(:,kdec2,:),ynat,'ARI',pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XGNDLITTER,pcover,xdata_gndlitter(:,kdec,:),ynat,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ENDIF
!
!        H_VEG
!        -----
  IF (gdata .AND. any(dtv%LDATA_H_VEG)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XH_VEG,dtv%XPAR_VEGTYPE,dtv%XPAR_H_VEG(:,kdec2,:),yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XH_VEG,pcover,xdata_h_veg(:,kdec,:),yveg,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ENDIF
! In case of MEB, force 0<PH_VEG<XUNDEF for those patches where LMEB_PATCH=.T.
  IF(io%LMEB_PATCH(kpatch))THEN
    ALLOCATE(zh_veg(SIZE(pek%XH_VEG)))
    zh_veg=pek%XH_VEG(:)
    WHERE(zh_veg>1000.) zh_veg=0.
    zh_veg=max(zh_veg,1.0e-3)
    pek%XH_VEG(:)=zh_veg
    DEALLOCATE(zh_veg)
  ENDIF
!
!    Z0LITTER
!    --------
  IF (gdata .AND. any(dtv%LDATA_Z0LITTER)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XZ0LITTER,dtv%XPAR_VEGTYPE,dtv%XPAR_Z0LITTER(:,kdec2,:),ynat,'CDN',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL av_pgd_1p(dtco, pek%XZ0LITTER ,pcover ,xdata_z0litter(:,kdec,:),ynat,'CDN',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ENDIF
!
ENDIF
!
IF (oirr .AND. .NOT.oupdate_alb) THEN
!
  IF ((io%CPHOTO == 'NIT' .OR. io%CPHOTO=='NCB') .AND. oagrip)  THEN
  !
  ! date of seeding
  ! ---------------
  !
     ALLOCATE(zworki(SIZE(pek%TSEED,1)))
     !
     IF(SIZE(pek%TSEED)>0) THEN
       IF (gdata .AND. any(dtv%LDATA_SEED_M) .AND. any(dtv%LDATA_SEED_D)) THEN
          CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                            zworki,dtv%XPAR_VEGTYPE,dtv%XPAR_SEED_M(:,:),yveg,'MAJ',&
                            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
          pek%TSEED(:)%TDATE%MONTH = nint(zworki(:))
          CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                            zworki,dtv%XPAR_VEGTYPE,dtv%XPAR_SEED_D(:,:),yveg,'MAJ',&
                            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
          pek%TSEED(:)%TDATE%DAY = nint(zworki(:))        
       ELSE            
         CALL av_pgd_1p (pek%TSEED,pcover,tdata_seed(:,:),yveg,'MAJ',ocover,&
                         pk%NR_P,io%NPATCH, kpatch, kdecade=kdec)
       ENDIF
     ENDIF
  !
  ! date of reaping
  ! ---------------
  !
    IF (SIZE(pek%TREAP)>0) THEN
       IF (gdata .AND. any(dtv%LDATA_REAP_M) .AND. any(dtv%LDATA_REAP_D)) THEN
          CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                            zworki,dtv%XPAR_VEGTYPE,dtv%XPAR_REAP_M(:,:),yveg,'MAJ',&
                            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
          pek%TREAP(:)%TDATE%MONTH = nint(zworki(:))
          CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                            zworki,dtv%XPAR_VEGTYPE,dtv%XPAR_REAP_D(:,:),yveg,'MAJ',&
                            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
          pek%TREAP(:)%TDATE%DAY = nint(zworki(:))          
       ELSE               
         CALL av_pgd_1p (pek%TREAP ,pcover,tdata_reap(:,:),yveg,'MAJ',ocover,&
                         pk%NR_P,io%NPATCH, kpatch, kdecade=kdec) 
       ENDIF 
    ENDIF
    !
    DEALLOCATE(zworki)
    !
    IF (SIZE(pek%XIRRIG)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_IRRIG)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XIRRIG,dtv%XPAR_VEGTYPE,dtv%XPAR_IRRIG(:,kdec2,:),yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
      ELSE
        CALL av_pgd_1p(dtco, pek%XIRRIG,pcover,xdata_irrig,yveg,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
!
    IF (SIZE(pek%XWATSUP)>0) THEN
      IF (gdata .AND. any(dtv%LDATA_WATSUP)) THEN
        CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XWATSUP,dtv%XPAR_VEGTYPE,dtv%XPAR_WATSUP(:,kdec2,:),yveg,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
      ELSE
        CALL av_pgd_1p(dtco, pek%XWATSUP,pcover,xdata_watsup,yveg,'ARI',ocover,&
                pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)  
      ENDIF
    ENDIF
    !
  ENDIF
!
ENDIF
!
IF (oalb) THEN
!
  IF (gdata .AND. any(dtv%LDATA_ALBNIR_SOIL)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XALBNIR_SOIL,dtv%XPAR_VEGTYPE,dtv%XPAR_ALBNIR_SOIL(:,kdec2,:),ybar,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSEIF (io%CALBEDO=='CM13') THEN
    CALL av_pgd_1p(dtco, pek%XALBNIR_SOIL,pcover,xdata_alb_soil_nir(:,kdec,:),ybar,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ELSE
    CALL soil_albedo (io%CALBEDO, pwsat(:,1), pwg1, kk, pek, "NIR" )  
  ENDIF
!
  IF (gdata .AND. any(dtv%LDATA_ALBVIS_SOIL)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XALBVIS_SOIL,dtv%XPAR_VEGTYPE,dtv%XPAR_ALBVIS_SOIL(:,kdec2,:),ybar,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSEIF (io%CALBEDO=='CM13') THEN
    CALL av_pgd_1p(dtco, pek%XALBVIS_SOIL,pcover,xdata_alb_soil_vis(:,kdec,:),ybar,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
  ELSE
    CALL soil_albedo (io%CALBEDO, pwsat(:,1), pwg1, kk, pek, "VIS" )
  ENDIF
!

  IF (io%CALBEDO=='CM13'.OR.io%LTR_ML) THEN
    pek%XALBUV_SOIL(:)=pek%XALBVIS_SOIL(:)
  ELSEIF (gdata .AND. any(dtv%LDATA_ALBUV_SOIL)) THEN
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pek%XALBUV_SOIL,dtv%XPAR_VEGTYPE,dtv%XPAR_ALBUV_SOIL(:,kdec2,:),ynat,'ARI',&
                      pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
  ELSE
    CALL soil_albedo (io%CALBEDO, pwsat(:,1), pwg1, kk, pek, "UV"  )  
  ENDIF
!
ENDIF
!
IF (ASSOCIATED(dtco%XDATA_WEIGHT)) DEALLOCATE(dtco%XDATA_WEIGHT)
!
IF (lhook) CALL dr_hook('CONVERT_PATCH_ISBA',1,zhook_handle)
!
!-------------------------------------------------------------------------------
CONTAINS
!-------------------------------------------------------------------------------
!
SUBROUTINE set_stress
!
IMPLICIT NONE
!
REAL, DIMENSION(PK%NSIZE_P)   :: ZWORK
REAL, DIMENSION(SIZE(DTV%LPAR_STRESS,1),NVEGTYPE) :: ZSTRESS
INTEGER :: JI
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('CONVERT_PATCH_ISBA:SET_STRESS',0,zhook_handle)
!
IF (gdata .AND. any(dtv%LDATA_STRESS)) THEN
  zstress(:,:)=0.
  DO jveg=1,nvegtype
    DO ji = 1,pk%NSIZE_P
      IF (dtv%LPAR_STRESS(ji,jveg)) zstress(pk%NR_P(ji),jveg) = 1.
    ENDDO
  ENDDO
  CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      zwork,dtv%XPAR_VEGTYPE,zstress,yveg,'ARI',pk%NR_P,io%NPATCH,kpatch,kdecade=kdec2)
ELSE
  CALL av_pgd_1p(dtco, zwork,pcover,xdata_stress(:,:),yveg,'ARI',ocover,pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
ENDIF
!
WHERE (zwork(:)<0.5)
  pek%LSTRESS(:) = .false.
ELSEWHERE
  pek%LSTRESS(:) = .true.
END WHERE
!
IF (lhook) CALL dr_hook('CONVERT_PATCH_ISBA:SET_STRESS',1,zhook_handle)
END SUBROUTINE set_stress
!
!-------------------------------------------------------------------------------
SUBROUTINE set_grid_param(KNI,KGROUND)
!
USE modd_pgdwork, ONLY : xprec
!
USE modd_surf_par, ONLY : xundef, nundef
USE modd_isba_par, ONLY : xpermfrac
!
USE modd_reprod_oper, ONLY : cdgavg, cdgdif
!
USE modi_ini_data_rootfrac
USE modi_ini_data_soil
USE modi_permafrost_depth
USE modi_abor1_sfx
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: KNI
INTEGER, INTENT(IN) :: KGROUND
!
REAL,    DIMENSION (SIZE(XDATA_GROUND_DEPTH,1),NVEGTYPE) :: ZDATA_GROUND_DEPTH
!
REAL,    DIMENSION (KNI)         :: ZDTOT, ZDG2, ZROOT_EXT, ZROOT_LIN
!
INTEGER :: JJ, JL
!
! flags taking general surface type flag into account
LOGICAL :: GDATA_DG, GDATA_GROUND_DEPTH, GDATA_ROOT_DEPTH, GDATA_ROOTFRAC, &
           GNOECO, GMEB
!-------------------------------------------------------------------------!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('CONVERT_PATCH_ISBA:SET_GRID_PARAM',0,zhook_handle)
!
IF(io%CISBA=='DIF')THEN
  IF(.NOT.ofix) CALL abor1_sfx('CONVERT_PATCH_ISBA: SET_GRID_PARAM: KWG_LAYER, PDROOT and PGD2 must be present with DIF')
 
ENDIF
!
gmeb = (omeb .AND. (isize_lmeb_patch>0))
!
zdtot(:) = xundef
zdg2(:) = xundef
!
pk%NWG_LAYER(:) = nundef
pk%XROOTFRAC(:,:) = xundef
!
zdata_ground_depth(:,:) = xdata_ground_depth(:,:)
!
gdata_dg           = gdata .AND. any(dtv%LDATA_DG)
gdata_ground_depth = gdata .AND. any(dtv%LDATA_GROUND_DEPTH)
gdata_root_depth   = gdata .AND. any(dtv%LDATA_ROOT_DEPTH)
gdata_rootfrac     = gdata .AND. any(dtv%LDATA_ROOTFRAC)
!
!####################################################################################
!
!CDGAVG : old for reprod = 'ARI' Arithmetic average for all depth 
!         recommended    = 'INV' Harmonic average for all depth (default)
!
!CDGDIF : old for reprod = 'SOIL' d3 soil depth from ecoclimap for isba-df
!         recommended    = 'ROOT' d2 soil depth from ecoclimap for isba-df (default)
!
!####################################################################################
!n
!DG IN NAMELIST => GROUND_DEPTH KNOWN, ROOT_DEPTH UNKNOWN 
IF (gdata_dg) THEN
  !
  DO jlayer=1,kground
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pk%XDG(:,jlayer),dtv%XPAR_VEGTYPE,dtv%XPAR_DG(:,jlayer,:),ynat,cdgavg,&
                      pk%NR_P,io%NPATCH,kpatch)
  ENDDO
  !
ENDIF
!
IF(.NOT.gdata_ground_depth.AND.io%CISBA=='DIF'.AND.cdgdif=='ROOT')THEN
  !
  DO jveg=1,nvegtype
    IF(jveg==nvt_no)THEN
      WHERE(xdata_ground_depth(:,jveg)/=xundef)
        zdata_ground_depth(:,jveg) = min(1.0,xdata_ground_depth(:,jveg))
      ENDWHERE
    ELSEIF(jveg/=nvt_rock.AND.jveg/=nvt_snow)THEN
      zdata_ground_depth(:,jveg) = max(1.0,xdata_root_depth(:,jveg))
    ELSE
      zdata_ground_depth(:,jveg) = xdata_root_depth(:,jveg)
    ENDIF
  ENDDO
  !
ENDIF
!
!CALCULATION OF GROUND_DEPTH IN ZDTOT : ECOCLMAP OR LDATA_GROUND_DEPTH
IF (io%CISBA/='2-L') THEN 
  !
  IF (gdata_ground_depth .AND. (io%CISBA=='DIF' .OR. .NOT.gdata_dg)) THEN
    !GROUND DEPTH IN NAMELIST
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      zdtot(:),dtv%XPAR_VEGTYPE,dtv%XPAR_GROUND_DEPTH(:,:),ynat,cdgavg,&
                      pk%NR_P,io%NPATCH,kpatch)
    !Error Due to machine precision
    WHERE(zdtot(:)/=xundef) zdtot(:)=nint(zdtot(:)*xprec)/xprec
    !CONSISTENCY CHECK
    IF (gdata_dg) zdtot(:) = min(zdtot(:),pk%XDG(:,kground))
  ELSEIF (gdata_dg) THEN
    !GROUND DEPTH FROM NAMELIST DG
    zdtot(:) = pk%XDG(:,kground)
  ELSE
    !GROUND DEPTH FROM ECOCLMAP
    CALL av_pgd_1p(dtco, zdtot(:),pcover,zdata_ground_depth(:,:),ynat,cdgavg,ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
    IF(io%CISBA=='DIF'.AND.cdgdif=='ROOT')zdg2(:)=zdtot(:)
  ENDIF
  !
ENDIF
!
!CALCULATION OF GROUND_DEPTH : Permafrost depth put to 12m
IF(io%CISBA=='DIF'.AND.io%LPERM) CALL permafrost_depth(pk%NSIZE_P,kpatch,pperm,zdtot)
!
!IN BOTH CASES, ROOT_DEPTH IS NEEDED: PUT IN DG2
IF (io%CISBA=='DIF' .OR. .NOT.gdata_dg) THEN
  !
  gnoeco=(gdata_root_depth .AND. .NOT.gdata_rootfrac)
  IF (gnoeco) THEN
    !ROOT_DEPTH IN NAMELIST
    CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      zdg2(:),dtv%XPAR_VEGTYPE,dtv%XPAR_ROOT_DEPTH(:,:),ynat,cdgavg,&
            pk%NR_P,io%NPATCH,kpatch)
    !Error Due to machine precision
    WHERE(zdg2(:)/=xundef) zdg2(:)=nint(zdg2(:)*xprec)/xprec  
    !CONSISTENCY CHECKS
    IF (any(dtv%LDATA_DG)) zdg2(:) = min(zdg2(:),pk%XDG(:,kground))
    zdtot(:) = max(zdg2(:),zdtot(:))
    IF (io%CISBA=='DIF') THEN
      CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pk%XDROOT(:),dtv%XPAR_VEGTYPE,dtv%XPAR_ROOT_DEPTH(:,:),ydif,cdgavg,&
            pk%NR_P,io%NPATCH,kpatch)
     !error due to machine precision
      WHERE(pk%XDROOT(:)/=xundef)
          pk%XDROOT(:)=nint(pk%XDROOT(:)*xprec)/xprec
      ENDWHERE 
       IF(cdgdif=='ROOT')THEN
         WHERE(pk%XDROOT(:).NE.xundef) zdtot(:) = max(pk%XDROOT(:),zdtot(:))
         WHERE(pk%XDROOT(:).NE.xundef) zdg2(:) = max(pk%XDROOT(:),zdg2(:))
       ELSE
         CALL av_pgd_1p(dtco, zdg2(:),pcover,xdata_root_depth(:,:),ynat,cdgavg,ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
       ENDIF      
     !consistency checks
      IF (gdata_dg) WHERE (pk%XDROOT(:).NE.xundef) pk%XDROOT(:) = min(pk%XDROOT(:),pk%XDG(:,kground))   
    ENDIF
  ELSE 
    !ROOT_DEPTH FROM ECOCLMAP
    IF (io%CISBA=='DIF')THEN
       CALL av_pgd_1p(dtco, pk%XDROOT(:),pcover,xdata_root_depth(:,:),ydif,cdgavg,ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
       IF(cdgdif=='ROOT')THEN
         WHERE(pk%XDROOT(:).NE.xundef) zdtot(:) = max(pk%XDROOT(:),zdtot(:))
         WHERE(pk%XDROOT(:).NE.xundef) zdg2(:) = max(pk%XDROOT(:),zdg2(:))
       ELSE
         CALL av_pgd_1p(dtco, zdg2(:),pcover,xdata_root_depth(:,:),ynat,cdgavg,ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
       ENDIF
    ELSE
       CALL av_pgd_1p(dtco, zdg2(:),pcover,xdata_root_depth(:,:),ynat,cdgavg,ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
    ENDIF
    IF ( gdata_ground_depth .OR. gdata_dg ) THEN
      zdg2(:) = min(zdg2(:),zdtot(:))
      IF (io%CISBA=='DIF') WHERE (pk%XDROOT(:).NE.xundef) pk%XDROOT(:) = min(pk%XDROOT(:),zdtot(:))
    ENDIF
  ENDIF
  !
  !CALCULATION OF DG IF NOT IN NAMELIST
  IF (.NOT.gdata_dg) THEN
    !
    IF (io%CISBA=='DIF') THEN
      IF( maxval(zdtot,zdtot/=xundef)>psoilgrid(kground) ) THEN
        CALL abor1_sfx('CONVERT_PATCH_ISBA: not enough soil layer with optimized grid')
      ENDIF
    ENDIF
    !
    WHERE(zdg2(:)==xundef.AND.zdtot(:)/=xundef) zdg2(:)=0.0 !No vegetation
    !
    !IF CISBA=DIF CALCULATES ALSO KWG_LAYER WITH USE OF SOILGRID $
    CALL ini_data_soil(io%CISBA, pk%XDG,prootdepth=zdg2, psoildepth=zdtot,&
                       psoilgrid=psoilgrid, kwg_layer=pk%NWG_LAYER )
    IF (io%CISBA=='DIF'.AND.cdgdif=='ROOT')THEN
          DO jj=1,kni
             IF(io%LPERM.AND.pk%NWG_LAYER(jj)/=nundef)THEN
               IF(pperm(jj)<xpermfrac) zdg2(jj)=pk%XDG(jj,pk%NWG_LAYER(jj))
             ELSEIF(pk%NWG_LAYER(jj)/=nundef)THEN
               zdg2(jj)=pk%XDG(jj,pk%NWG_LAYER(jj))
             ELSE
               zdg2(jj)=xundef
             ENDIF
          ENDDO
    ENDIF
               
    !
  ELSEIF ( io%CISBA=='DIF') THEN
    !
    !CALCULATION OF KWG_LAYER IF DG IN NAMELIST
    IF(gdata_ground_depth)THEN
        DO jj=1,kni
          DO jl=1,kground
            IF( pk%XDG(jj,jl) <= zdtot(jj) .AND. zdtot(jj) < xundef ) &
                pk%NWG_LAYER(jj) = jl
          ENDDO
        ENDDO              
    ELSE
      pk%NWG_LAYER(:) = kground
    ENDIF
    !
  ENDIF
  !
  ! DROOT AND DG2 LMITED BY KWG_LAYER
  IF (io%CISBA=='DIF' .AND. .NOT.any(dtv%LDATA_ROOTFRAC)) THEN
    !
      DO jj=1,kni
        IF(pk%NWG_LAYER(jj)/=nundef) THEN
          jl = pk%NWG_LAYER(jj)
          zdg2(jj)=min(zdg2(jj),pk%XDG(jj,jl))
          IF (pk%XDROOT(jj)/=xundef) pk%XDROOT(jj)=min(pk%XDROOT(jj),pk%XDG(jj,jl))    
        ENDIF
      ENDDO
    !
  ENDIF
  !
ENDIF
!
!CALCULATION OF ROOTFRAC
IF (io%CISBA=='DIF') THEN
  !
  IF (gdata_rootfrac) THEN
    !
    !ROOTFRAC IN NAMELIST
    DO jl=1,kground
      CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      pk%XROOTFRAC(:,jl),dtv%XPAR_VEGTYPE,dtv%XPAR_ROOTFRAC(:,jl,:),ynat,'ARI',&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
    ENDDO
    !    
    zdg2(:)=0.0
    pk%XDROOT(:)=0.0    
      DO jj=1,kni
        !
        !DROOT DEPENDS ON ROOTFRAC
        DO jl=kground,1,-1
          IF( pk%XROOTFRAC(jj,jl)>=1.0 )THEN
            zdg2(jj) = pk%XDG(jj,jl)
            pk%XDROOT(jj) = pk%XDG(jj,jl)
          ELSEIF (jl<kground.AND.pk%XROOTFRAC(jj,jl)>0.0) THEN
            IF (pk%NWG_LAYER(jj)<=jl) pk%NWG_LAYER(jj) = jl+1
            EXIT
          ENDIF
        ENDDO
        !
        IF(pk%XDROOT(jj)==0.0.AND.zdg2(jj)==0.0)THEN
          jl=pk%NWG_LAYER(jj)
          zdg2(jj)=min(0.6,pk%XDG(jj,jl))
        ENDIF
        !
      ENDDO
    !
  ELSE
    !
    !DEPENDS ON DROOT
    IF (gdata .AND. any(dtv%LDATA_ROOT_LIN)) THEN
      CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                      zroot_lin(:),dtv%XPAR_VEGTYPE,dtv%XPAR_ROOT_LIN(:,:),ydif,'ARI',&
            pk%NR_P,io%NPATCH,kpatch)
    ELSE
      CALL av_pgd_1p(dtco, zroot_lin(:),pcover,xdata_root_lin(:,:),ydif,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
    ENDIF
    !
    IF (gdata .AND. any(dtv%LDATA_ROOT_EXTINCTION)) THEN
      CALL av_pgd_param(dtv%XPAR_LAI, dtv%XPAR_VEG, &
                    zroot_ext(:),dtv%XPAR_VEGTYPE,dtv%XPAR_ROOT_EXTINCTION(:,:),ydif,'ARI',&
            pk%NR_P,io%NPATCH,kpatch)
    ELSE
      CALL av_pgd_1p(dtco, zroot_ext(:),pcover,xdata_root_extinction(:,:),ydif,'ARI',ocover,&
            pk%NR_P,io%NPATCH,kpatch,kdecade=kdec)
    ENDIF
    !
    CALL ini_data_rootfrac(pk%XDG,pk%XDROOT,zroot_ext,zroot_lin,pk%XROOTFRAC)
  ENDIF
  !
  WHERE(pk%XROOTFRAC(:,:)/=xundef) pk%XROOTFRAC(:,:)=nint(pk%XROOTFRAC(:,:)*xprec)/xprec
  !
  pk%XDG2(:) = zdg2(:)
  !
ENDIF
!
IF (lhook) CALL dr_hook('CONVERT_PATCH_ISBA:SET_GRID_PARAM',1,zhook_handle)
!
END SUBROUTINE set_grid_param
!-------------------------------------------------------------------------------
END SUBROUTINE convert_patch_isba