ini_data_rootfrac.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE ini_data_rootfrac( PDG, PROOTDEPTH, PROOT_EXT, PROOT_LIN,  &
                                    PROOTFRAC, OGV                          )

!     ##########################################################################
!
!!****  *INI_DATA_ROOTFRAC*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the soil grid configuration using a reference grid
!     Also compute the root fraction
!         
!     
!!**  METHOD
!!    ------
!
!     Direct calculation
!
!!    EXTERNAL
!!    --------
!
!     None
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    Noilhan and Planton (1989)
!!    Belair (1995)
!!    Boone (2000)
!!    Boone et al. (2000)
!!    Habets et al. (2003)
!!    Decharme et al. (2011)
!!      
!!    AUTHOR
!!    ------
!!      A. Boone           * Meteo-France *
!!      new version :
!!      B. Decharme        * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original     12/04/03
!!      new version :10/08/2011
!!      P. Samuelsson  02/2012  MEB
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_par, ONLY : xundef, nundef
USE modd_isba_par, ONLY : noptimlayer, xoptimgrid
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL,    DIMENSION(:,:), INTENT(IN) :: PDG         ! depth of base of soil layers (m)
REAL,    DIMENSION(:),   INTENT(IN) :: PROOTDEPTH  ! effective root depth         (m)
REAL, DIMENSION(:), INTENT(IN)     :: PROOT_EXT
REAL, DIMENSION(:), INTENT(IN)     :: PROOT_LIN
LOGICAL, OPTIONAL, INTENT(IN)        :: OGV
!
REAL, DIMENSION(:,:), INTENT(OUT)  :: PROOTFRAC
!
!*      0.2    declarations of local variables
!
REAL               :: ZLOG1, ZLOG2
REAL               :: ZJACKSON ! Jackson (1996) formulation for cumulative root fraction
REAL               :: ZUNIF    ! linear formulation for cumulative root fraction
REAL               :: ZROOTFRGV ! Fraction of patch root depth given to
!                               ! grass root depth for understory ground vegetation.
!                               ! =1 for non-understory vegetation

!
INTEGER            :: INI,INL
INTEGER            :: JJ,JL
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!        0.     Initialization
!               --------------
!
IF (lhook) CALL dr_hook('INI_DATA_ROOTFRAC',0,zhook_handle)
!
ini    = SIZE(pdg,1)
inl    = SIZE(pdg,2)
!
zrootfrgv  = 1.0
IF (PRESENT(ogv)) THEN
  IF(ogv) zrootfrgv  = 0.5
ENDIF
!
prootfrac(:,:) = xundef
!
  DO jj=1,ini
    !
    IF ( prootdepth(jj)/=xundef .AND. prootdepth(jj)/=0.0 ) THEN 
      !
      DO jl=1,inl                
        zlog1    = 100. * log(proot_ext(jj)) * pdg(jj,jl)
        zlog2    = 100. * log(proot_ext(jj)) * zrootfrgv * prootdepth(jj)
        zjackson = min(1.0,(1.0-exp(zlog1))/(1.0-exp(zlog2)))
        zunif    = min(1.0,(pdg(jj,jl)/zrootfrgv/prootdepth(jj))) 
        prootfrac(jj,jl) =      proot_lin(jj)  * zunif    &
                                   + (1.0-proot_lin(jj)) * zjackson
      ENDDO
!       No vegetation case                                    
    ELSE
      prootfrac(jj,:) = 0.0
    ENDIF
    !
  ENDDO
  
!
IF (lhook) CALL dr_hook('INI_DATA_ROOTFRAC',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE ini_data_rootfrac