zoom_pgd_surf_atm.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################
      SUBROUTINE zoom_pgd_surf_atm (YSC, &
                                    hprogram,hinifile,hinifiletype,hfile,hfiletype)
!     ###########################################################

!!
!!    PURPOSE
!!    -------
!!   This program prepares the physiographic data fields.
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson                   Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original     13/10/03
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
USE modd_surfex_n, ONLY : surfex_t
!
USE modi_ini_csts
USE modi_read_nam_write_cover_tex
USE modi_pgd_grid
USE modi_open_aux_io_surf
USE modi_close_aux_io_surf
USE modi_read_surf
USE modi_zoom_pgd_cover
USE modi_zoom_pgd_orography
USE modi_init_read_data_cover
USE modi_ini_data_cover
USE modi_surf_version
USE modi_zoom_pgd_inland_water
USE modi_zoom_pgd_nature
USE modi_zoom_pgd_sea
USE modi_zoom_pgd_town
USE modi_read_cover_garden
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
!
TYPE(surfex_t), INTENT(INOUT) :: ysc
!
 CHARACTER(LEN=6),     INTENT(IN)  :: hprogram    ! program calling
 CHARACTER(LEN=28),    INTENT(IN)  :: hinifile    ! input atmospheric file name
 CHARACTER(LEN=6),     INTENT(IN)  :: hinifiletype! input atmospheric file type
 CHARACTER(LEN=28),    INTENT(IN)  :: hfile       ! output atmospheric file name
 CHARACTER(LEN=6),     INTENT(IN)  :: hfiletype   ! output atmospheric file type
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER :: iresp
REAL(KIND=JPRB) :: zhook_handle
!------------------------------------------------------------------------------
!
!*    1.      Set default constant values 
!             ---------------------------
!
IF (lhook) CALL dr_hook('ZOOM_PGD_SURF_ATM',0,zhook_handle)
 CALL surf_version
!
 CALL ini_csts
!
 CALL read_nam_write_cover_tex(hprogram)
!
!-------------------------------------------------------------------------------
!
!*    2.      Initialisation of output grid and schemes
!             -----------------------------------------
!
 CALL pgd_grid(&
               ysc%UG, ysc%U, &
               hprogram,hfile,hfiletype,.true.,ysc%UG%CGRID,ysc%UG%NGRID_PAR,ysc%UG%XGRID_PAR)
!
 CALL open_aux_io_surf(&
                       hinifile,hinifiletype,'FULL  ')
 CALL read_surf(&
                hinifiletype,'SEA',   ysc%U%CSEA,   iresp)
 CALL read_surf(&
                hinifiletype,'NATURE',ysc%U%CNATURE,iresp)
 CALL read_surf(&
                hinifiletype,'WATER', ysc%U%CWATER, iresp)
 CALL read_surf(&
                hinifiletype,'TOWN',  ysc%U%CTOWN,  iresp)
 CALL read_cover_garden(&
                        hinifiletype,ysc%U%LGARDEN)
 CALL init_read_data_cover(hprogram)
 CALL ini_data_cover(ysc%DTCO, ysc%U)
 CALL close_aux_io_surf(hinifile,hinifiletype)
!
!-------------------------------------------------------------------------------
!
!*    3.      surface cover
!             -------------
!
 CALL zoom_pgd_cover(ysc%DTCO, ysc%UG, ysc%U, &
                     hprogram,hinifile,hinifiletype,ysc%U%LECOCLIMAP)
!
!-------------------------------------------------------------------------------
!
!*    4.      Orography
!             ---------
!
 CALL zoom_pgd_orography(ysc%DTCO, &
                         ysc%UG, ysc%U, ysc%USS, &
                         hprogram,ysc%U%XSEA,ysc%U%XWATER,hinifile,hinifiletype)
!
!_______________________________________________________________________________
!
!*    5.      Additionnal fields for nature scheme
!             ------------------------------------
!
IF (ysc%U%NDIM_NATURE>0)                                 &
  CALL zoom_pgd_nature(ysc%IM%CHI, ysc%DTCO, ysc%IM%DTI, ysc%IM%IG, &
                        ysc%IM%I, ysc%UG, ysc%U, ysc%USS, &
                       hprogram,hinifile,hinifiletype,hfile,hfiletype,ysc%U%LECOCLIMAP)  
!_______________________________________________________________________________
!
!*    6.      Additionnal fields for town scheme
!             ----------------------------------
!
IF (ysc%U%NDIM_TOWN>0)                                 &
  CALL zoom_pgd_town(ysc%TM%B, ysc%TM%DGCT, ysc%TM%DGMT, ysc%TM%T, ysc%GDM%TGD, &
                     ysc%GDM%TGDPE, ysc%GRM%TGR, ysc%GRM%TGRPE, &
                     ysc%TM%BOP, ysc%TM%BDD, ysc%TM%DTB, ysc%DTCO, ysc%TM%DTT, ysc%UG, ysc%U, &
                     ysc%GDM%TGDO, ysc%GDM%TGDP, ysc%TM%TG, ysc%TM%TOP, ysc%GDM%TVG, &
                     hprogram,hinifile,hinifiletype,hfile,hfiletype,ysc%U%LECOCLIMAP,ysc%U%LGARDEN)  
!_______________________________________________________________________________
!
!*    7.      Additionnal fields for inland water scheme
!             ------------------------------------------
!
IF (ysc%U%NDIM_WATER>0)                                 &
  CALL zoom_pgd_inland_water(ysc%DTCO, ysc%FM%FG, ysc%FM%F, ysc%UG, ysc%U, ysc%USS, ysc%WM%WG, ysc%WM%W, &
                             hprogram,hinifile,hinifiletype,hfile,hfiletype,ysc%U%LECOCLIMAP)  
!_______________________________________________________________________________
!
!*    8.      Additionnal fields for sea scheme
!             ---------------------------------
!
IF (ysc%U%NDIM_SEA>0)                                 &
  CALL zoom_pgd_sea(ysc%DTCO, ysc%SM%DTS, ysc%SM%SG, ysc%SM%S, ysc%UG, ysc%U, &
                    hprogram,hinifile,hinifiletype,hfile,hfiletype)  
!
!_______________________________________________________________________________
!
!*    9.      Dummy fields
!             ------------
!
ysc%DUU%NDUMMY_NBR = 0
!_______________________________________________________________________________
!
!*   10.      Chemical Emission fields
!             ------------------------
!
ysc%CHU%LCH_EMIS = .false.
IF (lhook) CALL dr_hook('ZOOM_PGD_SURF_ATM',1,zhook_handle)
!_______________________________________________________________________________
!
END SUBROUTINE zoom_pgd_surf_atm