z0v_from_lai.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#######################
MODULE modi_z0v_from_lai
!#######################
!
INTERFACE z0v_from_lai
!
    FUNCTION z0v_from_lai_0d(PLAI,PH_TREE,PVEGTYPE,OAGRI_TO_GRASS) RESULT(PZ0)
!
REAL,                 INTENT(IN) :: plai         ! Leaf area Index
REAL,                 INTENT(IN) :: ph_tree      ! height of trees
REAL,   DIMENSION(:), INTENT(IN) :: pvegtype     ! type of vegetation
LOGICAL,              INTENT(IN) :: oagri_to_grass
!
REAL                             :: pz0          ! vegetation roughness
!
END FUNCTION z0v_from_lai_0d
!
!
    FUNCTION z0v_from_lai_1d(PLAI,PH_TREE,PVEGTYPE,OAGRI_TO_GRASS) RESULT(PZ0)
!
REAL,   DIMENSION(:),   INTENT(IN) :: plai         ! Leaf area Index
REAL,   DIMENSION(:),   INTENT(IN) :: ph_tree      ! height of trees
REAL,   DIMENSION(:,:), INTENT(IN) :: pvegtype     ! type of vegetation
LOGICAL,                INTENT(IN) :: oagri_to_grass
!
REAL,   DIMENSION(SIZE(PLAI))      :: pz0          ! vegetation roughness
!
END FUNCTION z0v_from_lai_1d
!
!
    FUNCTION z0v_from_lai_2d(PLAI,PH_TREE,PVEGTYPE,OAGRI_TO_GRASS) RESULT(PZ0)
!
REAL,   DIMENSION(:,:),   INTENT(IN) :: plai         ! Leaf area Index
REAL,   DIMENSION(:,:),   INTENT(IN) :: ph_tree      ! height of trees
REAL,   DIMENSION(:,:,:), INTENT(IN) :: pvegtype     ! type of vegetation
LOGICAL,                  INTENT(IN) :: oagri_to_grass
!
REAL,   DIMENSION(SIZE(PLAI,1),SIZE(PLAI,2)) :: pz0  ! vegetation roughness
!
END FUNCTION z0v_from_lai_2d
!
    FUNCTION z0v_from_lai_patch(PLAI,PH_TREE,PVEGTYPE,OAGRI_TO_GRASS) RESULT(PZ0)
!
REAL,   DIMENSION(:),   INTENT(IN) :: plai         ! Leaf area Index
REAL,   DIMENSION(:),   INTENT(IN) :: ph_tree      ! height of trees
REAL,   DIMENSION(:),   INTENT(IN) :: pvegtype     ! type of vegetation
LOGICAL,                INTENT(IN) :: oagri_to_grass
!
REAL,   DIMENSION(SIZE(PLAI)) :: pz0  ! vegetation roughness
!
END FUNCTION z0v_from_lai_patch
!
END INTERFACE
!
END MODULE modi_z0v_from_lai
!

!   ###########################################################
    FUNCTION z0v_from_lai_0d(PLAI,PH_TREE,PVEGTYPE,OAGRI_TO_GRASS) RESULT(PZ0)
!   ###########################################################
!!
!!    PURPOSE
!!    -------
!
!     Calculates vegetation roughness from leaf
!    area index and type of vegetation
!    (most of types; forest and vineyards; grassland)
!              
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson and A. Boone          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    25/03/99
!!      P. Aumond   10/10/2009     Because drag force applied in atmospheric 
!!                                 model, Z0tree -> z0grass
!!      R. Alkama    05/2012   : Extantion from 12 to 19 vegtypes 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_par,       ONLY : xundef
USE modd_data_cover_par, ONLY : nvt_no, nvt_rock, nvt_snow, nvt_tebd,     & 
                                  nvt_bone, nvt_trbe, nvt_c3, nvt_c4,     &
                                  nvt_irr, nvt_gras, nvt_trog,nvt_park,   &
                                  nvt_trbd, nvt_tebe, nvt_tene, nvt_bobd, &
                                  nvt_bond, nvt_bogr, nvt_shrb  
USE modi_veg_height_from_lai
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL,                 INTENT(IN) :: plai         ! Leaf area Index
REAL,                 INTENT(IN) :: ph_tree      ! height of trees
REAL,   DIMENSION(:), INTENT(IN) :: pvegtype     ! type of vegetation
LOGICAL,              INTENT(IN) :: oagri_to_grass
!
REAL                             :: pz0          ! vegetation roughness
!
!*      0.2    declarations of local variables
!
REAL                            :: zallen_h    ! Allen formula for height
REAL                            :: zlai        ! LAI for vegetated areas
!
REAL, DIMENSION(SIZE(PVEGTYPE)) :: zh_veg          ! height for each type
REAL                            :: zavg_h      ! averaged height
REAL                            :: zzref       ! reference height        
!
INTEGER                         :: jtype       ! loop counter
REAL(KIND=JPRB) :: zhook_handle
!-----------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MODI_Z0V_FROM_LAI:Z0V_FROM_LAI_0D',0,zhook_handle)
!
zh_veg(:) = veg_height_from_lai(plai,ph_tree,pvegtype,oagri_to_grass)
!
zzref = 10.
zavg_h = 0.
DO jtype=1,SIZE(pvegtype)
  zavg_h = zavg_h + pvegtype(jtype) / (log(0.13*zh_veg(jtype)/zzref))**2
END DO
zavg_h = max(zavg_h,0.00001)

zavg_h = zzref / 0.13 * exp(-1./sqrt(zavg_h))
!
pz0  = max(0.001, 0.13*zavg_h)
IF (lhook) CALL dr_hook('MODI_Z0V_FROM_LAI:Z0V_FROM_LAI_0D',1,zhook_handle)
!
!-----------------------------------------------------------------
!
END FUNCTION z0v_from_lai_0d
!
!   ###########################################################
    FUNCTION z0v_from_lai_1d(PLAI,PH_TREE,PVEGTYPE,OAGRI_TO_GRASS) RESULT(PZ0)
!   ###########################################################
!!
!!    PURPOSE
!!    -------
!
!     Calculates vegetation roughness from leaf
!    area index and type of vegetation
!    (most of types; forest and vineyards; grassland)
!              
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson and A. Boone          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    25/03/99
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_par,       ONLY : xundef
USE modd_data_cover_par, ONLY : nvt_no, nvt_rock, nvt_snow, nvt_tebd,     & 
                                  nvt_bone, nvt_trbe, nvt_c3, nvt_c4,     &
                                  nvt_irr, nvt_gras, nvt_trog,nvt_park,   &
                                  nvt_trbd, nvt_tebe, nvt_tene, nvt_bobd, &
                                  nvt_bond, nvt_bogr, nvt_shrb  
USE modi_veg_height_from_lai
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL,   DIMENSION(:),   INTENT(IN) :: plai         ! Leaf area Index
REAL,   DIMENSION(:),   INTENT(IN) :: ph_tree      ! height of trees
REAL,   DIMENSION(:,:), INTENT(IN) :: pvegtype     ! type of vegetation
LOGICAL,                INTENT(IN) :: oagri_to_grass
!
REAL,   DIMENSION(SIZE(PLAI))      :: pz0          ! vegetation roughness
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PLAI))                  :: zallen_h    ! Allen formula for height
REAL, DIMENSION(SIZE(PLAI))                  :: zlai        ! LAI for vegetated areas
!
REAL, DIMENSION(SIZE(PLAI),SIZE(PVEGTYPE,2)) :: zh_veg          ! height for each type
REAL, DIMENSION(SIZE(PLAI))                  :: zavg_h      ! averaged height
REAL                                         :: zzref       ! reference height        
!
INTEGER                                      :: jtype       ! loop counter
REAL(KIND=JPRB) :: zhook_handle
!-----------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MODI_Z0V_FROM_LAI:Z0V_FROM_LAI_1D',0,zhook_handle)
zh_veg(:,:) = veg_height_from_lai(plai,ph_tree,pvegtype,oagri_to_grass)
!
zzref = 10.
zavg_h(:) = 0.
DO jtype=1,SIZE(pvegtype,2)
  zavg_h(:) = zavg_h(:) + pvegtype(:,jtype) / (log(0.13*zh_veg(:,jtype)/zzref))**2
END DO

zavg_h = max(zavg_h,0.00001)

zavg_h(:) = zzref / 0.13 * exp(-1./sqrt(zavg_h(:)))
!
pz0(:) = max(0.001, 0.13*zavg_h(:))
IF (lhook) CALL dr_hook('MODI_Z0V_FROM_LAI:Z0V_FROM_LAI_1D',1,zhook_handle)
!-----------------------------------------------------------------
!
END FUNCTION z0v_from_lai_1d
!
!   ###########################################################
    FUNCTION z0v_from_lai_2d(PLAI,PH_TREE,PVEGTYPE,OAGRI_TO_GRASS) RESULT(PZ0)
!   ###########################################################
!!
!!    PURPOSE
!!    -------
!
!     Calculates vegetation roughness from leaf
!    area index and type of vegetation
!    (most of types; forest and vineyards; grassland)
!              
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson and A. Boone          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    25/03/99
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_data_cover_par, ONLY : nvt_no, nvt_rock, nvt_snow, nvt_tebd,     & 
                                  nvt_bone, nvt_trbe, nvt_c3, nvt_c4,     &
                                  nvt_irr, nvt_gras, nvt_trog,nvt_park,   &
                                  nvt_trbd, nvt_tebe, nvt_tene, nvt_bobd, &
                                  nvt_bond, nvt_bogr, nvt_shrb  
USE modd_surf_par,       ONLY : xundef
USE modi_veg_height_from_lai
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL,   DIMENSION(:,:),   INTENT(IN) :: plai         ! Leaf area Index
REAL,   DIMENSION(:,:),   INTENT(IN) :: ph_tree      ! height of trees
REAL,   DIMENSION(:,:,:), INTENT(IN) :: pvegtype     ! type of vegetation
LOGICAL,                  INTENT(IN) :: oagri_to_grass
!
REAL,   DIMENSION(SIZE(PLAI,1),SIZE(PLAI,2)) :: pz0  ! vegetation roughness
!
!*      0.2    declarations of local variables
!

REAL, DIMENSION(SIZE(PLAI,1),SIZE(PLAI,2))                  :: zallen_h ! Allen formula for height
REAL, DIMENSION(SIZE(PLAI,1),SIZE(PLAI,2))                  :: zlai     ! LAI for vegetated areas
!
REAL, DIMENSION(SIZE(PLAI,1),SIZE(PLAI,2),SIZE(PVEGTYPE,3)) :: zh_veg       ! height for each type
REAL, DIMENSION(SIZE(PLAI,1),SIZE(PLAI,2))                  :: zavg_h   ! averaged height
REAL                                                        :: zzref    ! reference height        
!
INTEGER                                                     :: jtype    ! loop counter
REAL(KIND=JPRB) :: zhook_handle
!-----------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MODI_Z0V_FROM_LAI:Z0V_FROM_LAI_2D',0,zhook_handle)
zh_veg(:,:,:) = veg_height_from_lai(plai,ph_tree,pvegtype,oagri_to_grass)
!
zzref = 10.
zavg_h(:,:) = 0.
DO jtype=1,SIZE(pvegtype,3)
  zavg_h(:,:) = zavg_h(:,:) + pvegtype(:,:,jtype) / (log(0.13*zh_veg(:,:,jtype)/zzref))**2
END DO
zavg_h(:,:) = max(zavg_h(:,:),0.00001)
zavg_h(:,:) = zzref / 0.13 * exp(-1./sqrt(zavg_h(:,:)))
!
pz0(:,:) = max(0.001, 0.13*zavg_h(:,:))
!
WHERE (plai(:,:) == xundef)
  pz0(:,:) = xundef
END WHERE
IF (lhook) CALL dr_hook('MODI_Z0V_FROM_LAI:Z0V_FROM_LAI_2D',1,zhook_handle)
!-----------------------------------------------------------------
!
END FUNCTION z0v_from_lai_2d
!
!
!
!   ###########################################################
    FUNCTION z0v_from_lai_patch(PLAI,PH_TREE,PVEGTYPE,OAGRI_TO_GRASS) RESULT(PZ0)
!   ###########################################################
!!
!!    PURPOSE
!!    -------
!
!     Calculates vegetation roughness from leaf
!    area index and type of vegetation for each patch
!    (most of types; forest and vineyards; grassland)
!              
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!        F.Solmon
!!      V. Masson and A. Boone          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    25/03/99
!!      
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_data_cover_par, ONLY : nvt_no, nvt_rock, nvt_snow, nvt_tebd,     & 
                                  nvt_bone, nvt_trbe, nvt_c3, nvt_c4,     &
                                  nvt_irr, nvt_gras, nvt_trog,nvt_park,   &
                                  nvt_trbd, nvt_tebe, nvt_tene, nvt_bobd, &
                                  nvt_bond, nvt_bogr, nvt_shrb
USE modd_surf_par,       ONLY : xundef
USE modi_veg_height_from_lai
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL,   DIMENSION(:),   INTENT(IN) :: plai         ! Leaf area Index
REAL,   DIMENSION(:),   INTENT(IN) :: ph_tree      ! height of trees
REAL,   DIMENSION(:),   INTENT(IN) :: pvegtype     ! type of vegetation
LOGICAL,                INTENT(IN) :: oagri_to_grass
!
REAL,   DIMENSION(SIZE(PLAI))      :: pz0          ! vegetation roughness
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PLAI)) :: zallen_h    ! Allen formula for height
!
REAL, DIMENSION(SIZE(PLAI)) :: zh_veg          ! height for each type
REAL(KIND=JPRB) :: zhook_handle
!-----------------------------------------------------------------
!
IF (lhook) CALL dr_hook('MODI_Z0V_FROM_LAI:Z0V_FROM_LAI_PATCH',0,zhook_handle)
zh_veg(:) = veg_height_from_lai(plai,ph_tree,pvegtype,oagri_to_grass)
!
pz0(:) = max(0.001, 0.13*zh_veg(:)) ! rugosite pour chaque vegtype
!-----------------------------------------------------------------
!
WHERE (plai(:) == xundef)
  pz0(:) = xundef
END WHERE
IF (lhook) CALL dr_hook('MODI_Z0V_FROM_LAI:Z0V_FROM_LAI_PATCH',1,zhook_handle)
!
!
END FUNCTION z0v_from_lai_patch
!