z0rel_1d.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ######################################################################
      SUBROUTINE z0rel_1d(PAOSIP,PAOSIM,PAOSJP,PAOSJM,            &
                          pho2ip,pho2im,pho2jp,pho2jm,            &
                          pz0rel,omask                            )
!     ######################################################################
!
!!*SUBSCALE_Z0EFF  computes an effective roughness lenght deduced
!!                 from the subgrid-scale orography.
!!
!!
!!    METHOD
!!    ------
!!    See M.Georgelin and al. July 1994, Monthly Weather Review.
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    M. Georgelin      Laboratoire d'Aerologie
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    18/12/95
!!                22/12/97 (V Masson) call with dummy arguments
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_surf_par, ONLY : xundef
USE modd_csts,     ONLY : xkarman
USE modd_isba_par, ONLY : xcdz0eff
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
REAL, DIMENSION(:), INTENT(IN)  :: paosip  ! A/S for increasing x
REAL, DIMENSION(:), INTENT(IN)  :: paosim  ! A/S for decreasing x
REAL, DIMENSION(:), INTENT(IN)  :: paosjp  ! A/S for increasing y
REAL, DIMENSION(:), INTENT(IN)  :: paosjm  ! A/S for decreasing y
REAL, DIMENSION(:), INTENT(IN)  :: pho2ip  ! h/2 for increasing x
REAL, DIMENSION(:), INTENT(IN)  :: pho2im  ! h/2 for decreasing x
REAL, DIMENSION(:), INTENT(IN)  :: pho2jp  ! h/2 for increasing y
REAL, DIMENSION(:), INTENT(IN)  :: pho2jm  ! h/2 for decreasing y
!
REAL, DIMENSION(:), INTENT(OUT) :: pz0rel  ! roughness length
!                                                      ! of SSO only
LOGICAL, DIMENSION(:), INTENT(IN) :: omask ! mask where computations
                                                       ! are done
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL,    DIMENSION(SIZE(PAOSIP)) :: zloc
!
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
IF (lhook) CALL dr_hook('Z0REL_1D',0,zhook_handle)
!
pz0rel=xundef
!
zloc(:) = 0.
!
WHERE (omask(:))
  zloc(:) = 0.25 * xcdz0eff/(2.*xkarman**2)                  &
                   * (paosip(:)+paosim(:)+paosjp(:)+paosjm(:))        
  WHERE ( zloc(:) > 0. )
    pz0rel(:) = 0.25 * (pho2ip(:)+pho2im(:)+pho2jp(:)+pho2jm(:)) &
                     * exp(-sqrt(1./zloc(:)))
    pz0rel(:) = max(pz0rel(:),1e-10)
  ELSEWHERE
    pz0rel(:) = 0.
  END WHERE
END WHERE
!
IF (lhook) CALL dr_hook('Z0REL_1D',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE z0rel_1d