veg.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE veg( PSW_RAD, PTA, PQA, PPS, PRGL, PLAI, PRSMIN,              &
                  pgamma, pf2, prs                                         )  
!     ####################################################################
!
!!****  *VEG*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the surface stomatal resistance Rs
!         
!     
!!**  METHOD
!!    ------
!
!     First calculates the F coefficients (i.e., f, F1, F2, F3, and F4).
!     
!     Then, we have
!
!     Rs = Rsmin / ( F1 F2 F3 F4 LAI )
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!    none
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!    Noilhan and Planton (1989)
!!    Belair (1995)
!!      
!!    AUTHOR
!!    ------
!!
!!      S. Belair           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original      13/03/95 
!!     (P.Jabouille)  13/11/96    mininum value for ZF1
!!     (V. Masson)    28/08/98    add PF2 for Calvet (1998) CO2 computations
!!     (V. Masson)    01/03/03    puts PF2 in a separate routine
!!     (A. Boone)     21/1&/11    Rs_max in MODD_ISBA_PAR
!!     (B. Decharme)     07/15    Add numerical adjustement for F2 soilstress function
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_isba_par, ONLY : xrs_max, xdenom_min
USE mode_thermos
!
!
USE yomhook       ,ONLY : lhook,   dr_hook
USE parkind1      ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL, DIMENSION(:), INTENT(IN)   :: psw_rad, pta, pqa, pps
!                                     PSW_RAD = incoming solar radiation
!                                     PTA   = near-surface air temperature
!                                     PQA   = near-surface air specific humidity
!                                     PPS   = surface pressure
!
REAL, DIMENSION(:), INTENT(IN)   :: prgl, plai, prsmin, pgamma
!                                     PRGL   = coefficient in the Rs formulation
!                                     PLAI   = leaf area index
!                                     PRSMIN = minimum surface resistance
!                                     PGAMMA = coef. in the Rs calculation
!
REAL, DIMENSION(:), INTENT(IN)   :: pf2      ! water stress coefficient
REAL, DIMENSION(:), INTENT(OUT)  :: prs      ! ground stomatal resistance
!
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PSW_RAD)) :: zf, zf1, zf2, zf3, zf4
!                                           temporary factors necessary to 
!                                           calculate the surface stomatao resistance
!
REAL, DIMENSION(SIZE(PSW_RAD)) :: zqsat
!                                 ZQSAT = specific humidity at saturation
!
!
!*      0.3    declarations of local parameters:
!
REAL, PARAMETER                :: zfactr_min  = 1.e-3  ! minimum value for some parameters
!                                                      ! to prevent from being too small 
REAL, PARAMETER                :: zrs_min     = 1.e-4  ! minimum canopy resistance (s m-1)
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('VEG',0,zhook_handle)
!
!*       1.     THE 'ZF1' FACTOR
!               ---------------
!                                      This factor measures the influence
!                                      of the photosynthetically active radiation
!
zf(:)  = 0.55*2.*psw_rad(:) / (prgl(:)+ xdenom_min ) / ( plai(:)+  xdenom_min )
!
zf1(:) = ( zf(:) + prsmin(:)/xrs_max) /( 1. + zf(:) )
zf1(:) = max( zf1(:), xdenom_min  )
!
!-------------------------------------------------------------------------------
!
!*       2.     THE 'ZF2' FACTOR
!               ----------------
!
!               This factor takes into account the effect
!               of the water stress on the surface
!               resistance (see soilstress.F90)
!
! - For intermediate soils it ranges (F2_min =< F2 <= 1):
!   where F2_min is a small numerical threshold
!
zf2(:) = max(xdenom_min,pf2(:))
!
!-------------------------------------------------------------------------------
!
!*       3.     THE 'ZF3' FACTOR
!               ----------------
!                                      This factor represents the effect of
!                                      vapor pressure deficit of the atmosphere.
!                                      For very humid air, the stomatal resistance
!                                      is a small, whereas it increases as the
!                                      air is drier. 
!
!
zqsat(:) = qsat(pta(:),pps(:))
!
zf3(:)   = max( 1. - pgamma(:)*( zqsat(:) - pqa(:) )*1000. , zfactr_min )
!
!-------------------------------------------------------------------------------
!
!*       4.     THE 'ZF4' FACTOR
!               ----------------
!                                       This factor introduces an air temperature
!                                       dependance on the surface stomatal resistance
!
zf4(:) = max( 1.0 - 0.0016*(298.15-pta(:))**2, zfactr_min )
!
!-------------------------------------------------------------------------------
!
!*       5.     THE SURFACE STOMATAL RESISTANCE
!               -------------------------------
!
! use Jarvis-resistance (in standard ISBA version):
! otherwise use Jacobs/ISBA-Ags method (see routine COTWORES)
!
prs(:) = prsmin(:) / ( plai(:)+ xdenom_min )          &
            / zf1(:) / zf2(:) /zf3(:) / zf4(:)  
!
prs(:) = min( prs(:), xrs_max)
prs(:) = max( prs(:), zrs_min)
!
IF (lhook) CALL dr_hook('VEG',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE veg