utci_teb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!   ##########################################################################
SUBROUTINE utci_teb(PT_CAN, PQ_CAN, PTI_BLD, PQI_BLD, PU10, PPS,         &
                    pref_sw_grnd, pref_sw_fac, psca_sw, pdir_sw, pzenith,&
                    pemit_lw_fac, pemit_lw_grnd, plw_rad, ptrad_in,      &
                    pbld, pbld_height, pwall_o_hor,                      &
                    putci_in, putci_outsun, putci_outshade,              &
                    ptrad_sun, ptrad_shade )
!   ##########################################################################
!
!!****  *UTCI_TEB*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the Universal Thermal and Climate Index Equivalent temperature
!     for 3 persons in the urban environment
!         
!     
!!**  METHOD
!     ------
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!! a supplement
!!    MODD_CST
!!
!!    REFERENCE
!!    ---------
!!   www.utci.org
!!      
!!    AUTHOR
!!    ------
!!
!!      G. Pigeon           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original  03/2011
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts, ONLY : xtt
USE modi_utci_approx
USE modi_trad_body
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
REAL, DIMENSION(:), INTENT(IN)  :: pt_can !Air canyon temperature (K) 
REAL, DIMENSION(:), INTENT(IN)  :: pq_can !Canyon specific humidity (kg/kg)
REAL, DIMENSION(:), INTENT(IN)  :: pti_bld !Indoor air temperature (K) 
REAL, DIMENSION(:), INTENT(IN)  :: pqi_bld !Indoor specific humidity (kg/kg) 
REAL, DIMENSION(:), INTENT(IN)  :: pu10 !Canyon wind speed at 10m (m/s)
REAL, DIMENSION(:), INTENT(IN)  :: pps !Atmospheric Pressure (Pa)
REAL, DIMENSION(:), INTENT(IN)  :: pref_sw_grnd !Solar radiation reflected by ground [road + garden] (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: pref_sw_fac !Solar radiation reflected by facade [wall + glazing] (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: psca_sw !Diffuse solar radiation (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: pdir_sw !Direct solar radiation (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: pzenith !solar zenithal angle (rad from vert.)
REAL, DIMENSION(:), INTENT(IN)  :: pemit_lw_fac !Longwave radiation emitted by the facade [wall + glazing] (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: pemit_lw_grnd !Longwave radiation emitted by the ground [road + garden] (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: plw_rad !Atmospheric longwave radiation (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: ptrad_in !Indoor radiant temperature (K)
REAL, DIMENSION(:), INTENT(IN)  :: pbld !Building surface fraction
REAL, DIMENSION(:), INTENT(IN)  :: pbld_height !Building surface fraction
REAL, DIMENSION(:), INTENT(IN)  :: pwall_o_hor !Building surface fraction
REAL, DIMENSION(:), INTENT(OUT) :: putci_in !UTCI for indoor person (C)
REAL, DIMENSION(:), INTENT(OUT) :: putci_outsun !UTCI for outdoor person at sun (C)
REAL, DIMENSION(:), INTENT(OUT) :: putci_outshade !UTCI for outdoor person in shade (C)
REAL, DIMENSION(:), INTENT(OUT) :: ptrad_sun !Mean radiant temperature at sun (C)
REAL, DIMENSION(:), INTENT(OUT) :: ptrad_shade !Mean radiant temperature in shade (C)
!
!*      0.2    declarations of local variables
REAL, DIMENSION(SIZE(PTI_BLD)) :: zehpa !water vapour pressure (hPa)
REAL, DIMENSION(SIZE(PTI_BLD)) :: zuin !indoor air wind speed (m/s)
REAL, DIMENSION(SIZE(PTI_BLD)) :: zdir_sw !direct solar radiation
REAL, DIMENSION(SIZE(PTI_BLD)) :: zzenith !zenithal angle
!
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('UTCI_TEB',0,zhook_handle)
! 1-calculation of UTCI_IN
zehpa = pqi_bld * pps /(0.622 + 0.378 * pqi_bld) / 100.
zuin = 0.5
putci_in = utci_approx(pti_bld - xtt, zehpa, ptrad_in - xtt, zuin)
!
! 2-calculation of UTCI_OUTSUN
zehpa = pq_can * pps / (0.622 + 0.378 * pq_can) /100.
ptrad_sun = trad_body(psca_sw, pref_sw_fac, pref_sw_grnd,  &
                      pemit_lw_fac, pemit_lw_grnd, plw_rad,&
                      pbld, pbld_height, pwall_o_hor, pdir_sw, pzenith )
putci_outsun = utci_approx(pt_can - xtt, zehpa, ptrad_sun - xtt, pu10)
!
! 3-calculation of UTCI_OUTSHADE
zdir_sw=0.
zzenith=0.
!!PTRAD_SHADE = TRAD_BODY(PSCA_SW,PREF_SW_FAC, PREF_SW_GRND, &
!!                      PEMIT_LW_FAC, PEMIT_LW_GRND, PLW_RAD,&
!!                      PBLD, PBLD_HEIGHT, PWALL_O_HOR, ZDIR_SW, ZZENITH)
ptrad_shade = trad_body(psca_sw,pref_sw_fac, pref_sw_grnd, &
                      pemit_lw_fac, pemit_lw_grnd, plw_rad,&
                      pbld, pbld_height, pwall_o_hor)
putci_outshade = utci_approx(pt_can - xtt, zehpa, ptrad_shade - xtt, pu10)
IF (lhook) CALL dr_hook('UTCI_TEB',1,zhook_handle)
END SUBROUTINE utci_teb