urban_hydro.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE urban_hydro(PWS_ROOF_MAX,PWS_ROAD_MAX, PWS_ROOF, PWS_ROAD,  &
                             prr, pirrig_road, ptstep, pbld, ple_roof,     &
                             ple_road, prunoff_strlroof, prunoff_road      )
!   ##########################################################################
!
!!****  *URBAN_HYDRO*  
!!
!!    PURPOSE
!!    -------
!
!     Computes the evolution of prognostic water reservoirs
!     of urbanized areas.
!         
!     
!!**  METHOD
!     ------
!
!
!   The roof reservoir runoff goes directly into the road reservoir.
!
!   Runoff occurs for road reservoir (too much water), as well as drainage
!   (evacuation system, typical time scale: 1 day)
!
!
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    MODD_CST
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    23/01/98 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_csts,ONLY : xlvtt
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL, DIMENSION(:), INTENT(IN) :: pws_roof_max    ! maximum deepness of roof water reservoir
REAL, DIMENSION(:), INTENT(IN) :: pws_road_max    ! maximum deepness of road water reservoir

REAL, DIMENSION(:), INTENT(INOUT) :: pws_roof     ! roof water reservoir
REAL, DIMENSION(:), INTENT(INOUT) :: pws_road     ! road water reservoir
REAL, DIMENSION(:), INTENT(IN)    :: prr          ! rain rate
REAL, DIMENSION(:), INTENT(IN)    :: pirrig_road  ! watering rate for roads
REAL,               INTENT(IN)    :: ptstep       ! time step
REAL, DIMENSION(:), INTENT(IN)    :: pbld         ! fraction of buildings
REAL, DIMENSION(:), INTENT(IN)    :: ple_roof     ! latent heat flux over roof
REAL, DIMENSION(:), INTENT(IN)    :: ple_road     ! latent heat flux over road
!
REAL, DIMENSION(:), INTENT(OUT)   :: prunoff_strlroof ! runoff (kg/m2/s)
REAL, DIMENSION(:), INTENT(OUT)   :: prunoff_road ! runoff (kg/m2/s)
REAL(KIND=JPRB) :: zhook_handle
!
!*      0.2    declarations of local variables
!
!
!-------------------------------------------------------------------------------
!
!*      1.     Roof reservoir evolution
!              ------------------------
!
!
!                                           evolution of the water reservoir
!                                           (if we don't consider the runoff)
!                                           PRR in kg/m2/s therefore PWS in mm
!
IF (lhook) CALL dr_hook('URBAN_HYDRO',0,zhook_handle)
pws_roof(:) =  pws_roof(:)                                   &
               - ptstep * ( ple_roof(:) / xlvtt - prr(:) )  
!
!                                           Ws_town must be positive
!
pws_roof(:) = max(0., pws_roof(:))
!
!                                           if Ws_town > Ws_town_max,
!                                           there is runoff
!
prunoff_strlroof(:) = max(0., (pws_roof(:) - pws_roof_max(:)) / ptstep )
!
pws_roof(:) = min(pws_roof(:), pws_roof_max(:))
!
!-------------------------------------------------------------------------------
!
!*      2.     Road reservoir evolution
!              ------------------------
!
!
!                                           evolution of the water reservoir
!                                           (if we don't consider the runoff)
!                                           PRR in kg/m2/s therefore PWS in mm
!
pws_road(:) =  pws_road(:)                                 &
               - ptstep * ( ple_road(:) / xlvtt -  prr(:) - pirrig_road(:) )  
!
!                                           Ws_town must be positive
!
pws_road(:) = max(0., pws_road(:))
!
!                                           if Ws_town > Ws_town_max,
!                                           there is runoff
!
prunoff_road(:) = max(0., (pws_road(:) - pws_road_max(:)) / ptstep )
!
pws_road(:) = min(pws_road(:), pws_road_max(:))
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('URBAN_HYDRO',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE urban_hydro