update_rad_water.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE update_rad_water(HALB,PSST,PZENITH,PTT,PEMIS,PDIR_ALB,PSCA_ALB, &
                            pdir_alb_atmos,psca_alb_atmos,pemis_atmos,ptrad)  
!     #######################################################################
!
!!****  *UPDATE_RAD_WATER * - update the radiative properties at time t+1 (see by the atmosphere) 
!                           in order to close the energy budget between surfex and the atmosphere
 
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    09/2009
!!      Modified    03/2011 : E. Bazile (MK10) albedo from Marat Khairoutdinov
!!      Modified    02/2014 : split from update_rad_seawat.F90
!!------------------------------------------------------------------
!
USE modd_water_par, ONLY : xemiswat, xemiswatice, &
                           xalbwat, xalbsca_wat,  &
                           xalbwatice
!
USE modn_sfx_oasis,  ONLY : lwater
USE modd_sfx_oasis,  ONLY : lcpl_sea
!
USE modi_albedo_ta96
USE modi_albedo_mk10
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=4),       INTENT(IN)   :: halb
!
REAL, DIMENSION(:),     INTENT(IN)   :: psst      ! Sea surface temperature
REAL, DIMENSION(:),     INTENT(IN)   :: pzenith   ! Zenithal angle at t+1
REAL,                   INTENT(IN)   :: ptt       ! Sea/ice transition temperature (different according to sea or inland water)
!
REAL, DIMENSION(:),     INTENT(INOUT):: pdir_alb  ! Direct albedo at t+1
REAL, DIMENSION(:),     INTENT(INOUT):: psca_alb  ! Diffuse albedo at t+1
REAL, DIMENSION(:),     INTENT(OUT)  :: pemis     ! emissivity (soil+vegetation) at t+1
!
REAL, DIMENSION(:,:),   INTENT(OUT)  :: pdir_alb_atmos ! Direct albedo at t+1 for the atmosphere
REAL, DIMENSION(:,:),   INTENT(OUT)  :: psca_alb_atmos ! Diffuse albedo at t+1 for the atmosphere
REAL, DIMENSION(:),     INTENT(OUT)  :: pemis_atmos    ! Emissivity at t+1 for the atmosphere
REAL, DIMENSION(:),     INTENT(OUT)  :: ptrad          ! radiative temp at t+1 for the atmosphere
!
!*      0.2    declarations of local variables
!
INTEGER :: jswb
REAL, DIMENSION(SIZE(PSST)) :: zalbedo
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('UPDATE_RAD_WATER',0,zhook_handle)
!
zalbedo(:) = 0.
IF (halb=='TA96') THEN
  zalbedo(:) = albedo_ta96(pzenith(:))
ELSEIF (halb=='MK10') THEN
  zalbedo(:) = albedo_mk10(pzenith(:))
ENDIF
!
IF(lcpl_sea.AND.lwater)THEN !Earth System Model
!
!Sea and/or ice albedo already given by oceanic model
!Except for Taylor et al (1996) formulation
!
  !
  WHERE (psst(:)>=ptt  )
    !* open water
    pemis(:) = xemiswat
  ELSEWHERE
    !* sea ice
    pemis(:) = xemiswatice
  END WHERE
  !
  IF (halb=='TA96' .OR. halb=='MK10') THEN
    !* Taylor et al 1996
    !* open water
    WHERE (psst(:)>=ptt) pdir_alb(:) = zalbedo(:)
    WHERE (psst(:)>=ptt) psca_alb(:) = xalbsca_wat
  ENDIF
  !
ELSE
  !
  IF (halb=='UNIF') THEN
  !* uniform albedo
    WHERE (psst(:)>=ptt  )
    !* open water
      pdir_alb(:) = xalbwat
      psca_alb(:) = xalbwat
      pemis(:) = xemiswat
    ELSEWHERE
    !* sea ice
      pdir_alb(:) = xalbwatice
      psca_alb(:) = xalbwatice
      pemis(:) = xemiswatice
    END WHERE
  !
  ELSE IF (halb=='TA96' .OR. halb=='MK10') THEN
    !* Taylor et al 1996
    WHERE (psst(:)>=ptt) pdir_alb(:) = zalbedo(:)
    !
    WHERE (psst(:)>=ptt)
    !* open water
      psca_alb(:) = xalbsca_wat
      pemis(:) = xemiswat
    ELSEWHERE
    !* sea ice
      pdir_alb(:) = xalbwatice
      psca_alb(:) = xalbwatice
      pemis(:) = xemiswatice
    END WHERE
    !
  ENDIF
  !
ENDIF
!
!-------------------------------------------------------------------------------------
!
DO jswb=1,SIZE(pdir_alb_atmos,2)
  pdir_alb_atmos(:,jswb) = pdir_alb(:)
  psca_alb_atmos(:,jswb) = psca_alb(:)
END DO
!
pemis_atmos(:) = pemis(:)
ptrad(:) = psst(:)
!
IF (lhook) CALL dr_hook('UPDATE_RAD_WATER',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE update_rad_water