update_esm_isban.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE update_esm_isba_n (I, &
                                    ki,ksw,pzenith,psw_bands,pdir_alb,& 
                                   psca_alb,pemis,ptsrad,ptsurf      )
!     ################################################################
!
!!****  *UPDATE_ESM_ISBA_n* - update ISBA radiative and physical properties in Earth System Model 
!!                            after the call to OASIS coupler in order 
!!                            to close the energy budget between radiative scheme and surfex
!!
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    09/2009
!!      B. Decharme 06/2013 new coupling variables
!!      P. Samuelsson 10/2014 MEB
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE modd_isba_n, ONLY : isba_t
!
USE modd_type_snow
USE modd_surf_par, ONLY : xundef
!
USE modi_average_rad
USE modi_average_tsurf
USE modi_update_rad_isba_n
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(isba_t), INTENT(INOUT) :: i
!
INTEGER,                            INTENT(IN)  :: ki        ! number of points
INTEGER,                            INTENT(IN)  :: ksw       ! number of short-wave spectral bands
!
REAL,             DIMENSION(KI),    INTENT(IN)  :: pzenith   ! solar zenithal angle
REAL,             DIMENSION(KSW),   INTENT(IN)  :: psw_bands ! short-wave spectral bands
!
REAL,             DIMENSION(KI,KSW),INTENT(OUT) :: pdir_alb  ! direct albedo for each band
REAL,             DIMENSION(KI,KSW),INTENT(OUT) :: psca_alb  ! diffuse albedo for each band
REAL,             DIMENSION(KI),    INTENT(OUT) :: pemis     ! emissivity
REAL,             DIMENSION(KI),    INTENT(OUT) :: ptsrad    ! radiative temperature
REAL,             DIMENSION(KI),    INTENT(OUT) :: ptsurf    ! surface effective temperature         (K)
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI,KSW,I%NPATCH) :: zdir_alb_patch
REAL, DIMENSION(KI,KSW,I%NPATCH) :: zsca_alb_patch
REAL, DIMENSION(KI,I%NPATCH)     :: zemis_patch
REAL, DIMENSION(KI,I%NPATCH)     :: ztsrad_patch
REAL, DIMENSION(KI,I%NPATCH)     :: ztsurf_patch
REAL, DIMENSION(KI,I%NPATCH)     :: zemis          ! emissivity with flood
!
LOGICAL :: lexplicit_snow ! snow scheme key
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!*       1.     Defaults
!               --------
!
IF (lhook) CALL dr_hook('UPDATE_ESM_ISBA_N',0,zhook_handle)
!
zdir_alb_patch(:,:,:) = 0.0
zsca_alb_patch(:,:,:) = 0.0
zemis_patch(:,:  ) = 0.0
zemis(:,:  ) = i%XEMIS(:,:)
!
lexplicit_snow = (i%TSNOW%SCHEME=='3-L'.OR.i%TSNOW%SCHEME=='CRO')
!
ztsrad_patch(:,:) = i%XTG(:,1,:)
ztsurf_patch(:,:) = i%XTG(:,1,:)
!
!
!*       2.     Update nature albedo and emissivity
!               -----------------------------------
!
 CALL update_rad_isba_n(i, &
                        i%LFLOOD,i%TSNOW%SCHEME,pzenith,psw_bands,i%XVEG,i%XLAI,i%XZ0, &
                         i%LMEB_PATCH,i%XLAIGV,i%XGNDLITTER,i%XZ0LITTER,i%XH_VEG,      &
                         i%XALBNIR,i%XALBVIS,i%XALBUV,i%XEMIS,                       &
                         zdir_alb_patch,zsca_alb_patch,zemis_patch           )
!
!*       3.     radiative surface temperature
!               -----------------------------
!
IF(lexplicit_snow.AND.i%LFLOOD)THEN
  WHERE(i%XPSN(:,:)<1.0.AND.i%XEMIS(:,:)/=xundef)
       zemis(:,:) = ((1.-i%XFF(:,:)-i%XPSN(:,:))*i%XEMIS(:,:) + i%XFF(:,:)*i%XEMISF(:,:)) / (1.-i%XPSN(:,:))
  ENDWHERE
ENDIF
!
IF(lexplicit_snow)THEN
  WHERE(i%XEMIS(:,:)/=xundef.AND.zemis_patch(:,:)/=0.)
       ztsrad_patch(:,:) = ( ( (1.-i%XPSN(:,:))*zemis(:,:)*i%XTG   (:,1,:)**4     &
                             +     i%XPSN(:,:) *i%TSNOW%EMIS(:,:)*i%TSNOW%TS(:,:)**4 )   &
                           / zemis_patch(:,:) )**0.25         
  ENDWHERE
ENDIF        
!
!
!*       4.     averaged fields
!               ---------------
!
 CALL average_rad(i%XPATCH,                                                     &
                   zdir_alb_patch, zsca_alb_patch, zemis_patch, ztsrad_patch, &
                   pdir_alb,       psca_alb,       i%XEMIS_NAT,   i%XTSRAD_NAT    )  
!
pemis = i%XEMIS_NAT
ptsrad = i%XTSRAD_NAT
!
!* averaged effective temperature
!
IF(lexplicit_snow)THEN
  ztsurf_patch(:,:) = i%XTG(:,1,:)*(1.-i%XPSN(:,:)) + i%TSNOW%TS(:,:)*i%XPSN(:,:)
ENDIF
!
 CALL average_tsurf(i%XPATCH, ztsurf_patch, ptsurf)
!
IF (lhook) CALL dr_hook('UPDATE_ESM_ISBA_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE update_esm_isba_n