tebgrid.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE tebgrid( PSOILDEPTH, PD_G, PD_G1 )

!     ##########################################################################
!
!!****  *TEBGRID*  
!!
!!    PURPOSE
!!    -------
!
!     Calculates the soil grid configuration using a simple
!     geometric relation for all sub-surface layers.
!     This algorithm assumes the total soil depth > 0 m
!         
!     
!!**  METHOD
!!    ------
!
!     Direct calculation
!
!!    EXTERNAL
!!    --------
!
!     None
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    Noilhan and Planton (1989)
!!    Belair (1995)
!!    Boone (2000)
!!    Boone et al. (2000)
!!    Habets et al. (2003)
!!      
!!    AUTHOR
!!    ------
!!      A. Boone           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/04/03
!!      B. Decharme    12/10 uppermost soil layer set to 1cm
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL, DIMENSION(:),   INTENT(IN)  :: psoildepth  ! total soil depth            (m)
!                                   
REAL, DIMENSION(:,:), INTENT(OUT) :: pd_g        ! depth of base of soil layers (m)
REAL, OPTIONAL,       INTENT(IN)  :: pd_g1       ! depth of first layer
!
!
!*      0.2    declarations of local variables
!
INTEGER                           :: jj, jnlvl
!
!
REAL, PARAMETER                   :: zgridfactor = 3.0 ! soil depth factor
!                                                      ! of increase with depth
!                                                      ! for all *sub-surface* 
!                                                      ! layers. Note, uppermost
!                                                      ! layer fixed by other
!                                                      ! constraints.          (-)
!
REAL                              :: zd_g1 = 0.01      ! uppermost soil layer 
!                                                      ! thickness/depth       (m)
!                                                      ! Can not be too thin as 
!                                                      ! then definition of soil
!                                                      ! properties (i.e. phyiscal
!                                                      ! representation of) and 
!                                                      ! accuarcy of
!                                                      ! numerical solution come
!                                                      ! into question. If it is too
!                                                      ! thick, then resolution of
!                                                      ! diurnal cycle not as valid.
!                                                      ! Also chosen to comply with
!                                                      ! remotely sensed soil moisture.
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!        0.     Initialization
!               --------------
!
IF (lhook) CALL dr_hook('TEBGRID',0,zhook_handle)
jnlvl = SIZE(pd_g,2)
!
IF (present(pd_g1)) zd_g1 = pd_g1
!-------------------------------------------------------------------------------
!
!*       1.     Assign soil layer depths
!               ------------------------
!               using a geometric relation
!               for layers 2...N
!               This is GENERAL rule.
!               Note that the first soil layer
!               is FIXED except for VERY thin
!               soils (see #3 below).
!
pd_g(:,1)     = zd_g1
pd_g(:,jnlvl) = psoildepth(:)
!
DO jj=jnlvl-1,2,-1
   pd_g(:,jj) = pd_g(:,jj+1)/zgridfactor
ENDDO
!
!-------------------------------------------------------------------------------
!
!*       2.     When the soil is sufficiently thin
!               ------------------------------------------
!               We recalculate layer depths such
!               that all layer thicknesses are >= ZD_G1
!               We favor keeping a minimum grid thickness
!               OVER maintaining geometric relation
!               for increasingly thin soils. This means
!               that uppermost soil moisture is readily
!               comparable (i.e. for same layer thickness)
!               EVERYWHERE except for most thin soils (below).
!
DO jj=1,jnlvl
   pd_g(:,jj) = max(pd_g(:,jj), jj*zd_g1)
ENDDO
!
!-------------------------------------------------------------------------------
!
!*       3.     In the LIMIT For extremely thin soils
!               ------------------------------------------
!               This should be a RARE occurance, but 
!               accounted for none-the-less ...:
!               hold the ratio between all layer 
!               thicknesses constant. 
!           
DO jj=1,jnlvl
   WHERE(psoildepth(:) < jnlvl*zd_g1)
      pd_g(:,jj) = jj*psoildepth/jnlvl
   END WHERE
ENDDO
IF (lhook) CALL dr_hook('TEBGRID',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE tebgrid