teb_morpho.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################################################################
      SUBROUTINE teb_morpho(HPROGRAM, PBLD,PWALL_O_HOR, PGARDEN, PBLD_HEIGHT, PROAD, &
                            proad_o_grnd, pgarden_o_grnd, pwall_o_grnd,              &
                            pcan_hw_ratio, psvf_road, psvf_garden, psvf_wall,        &
                            pz0_town, pwall_o_bld, ph_traffic, ple_traffic           )
!     ###########################################################################################################
!
!!****  *TEB_MORPHO* 
!!
!!    PURPOSE
!!    -------
!!**** routine to verify and compute the canyon/building morphology in TEB
!!
!!**  METHOD
!!    ------
!! the routine controls the canyon/building morphology
!!    - in the case of low building fraction (lower than 10^-4)
!!    - in the case of high building fraction (higher than 0.9999)
!!    - building height
!!    - in the case of low road fraction
!!    - in the case of low/hight wall surface ratio 
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!      G. Pigeon   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2011
!!      C. de Munck and A. lemonsu 05/2013 : - corrections in case of too high WALL_O_HOR (6.)
!!                                           - final check of parameters range added
!----------------------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modi_get_luout
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
 CHARACTER(LEN=6),     INTENT(IN)  :: hprogram    ! program calling surf. schemes
REAL, DIMENSION(:),   INTENT(INOUT)  :: pbld         ! Urban horizontal building density
REAL, DIMENSION(:),   INTENT(INOUT)  :: pwall_o_hor  ! Wall to horizontal surface ratio
REAL, DIMENSION(:),   INTENT(INOUT)  :: pgarden      ! Urban horizontal garden density
REAL, DIMENSION(:),   INTENT(INOUT)  :: pbld_height  ! Average building height [m]
REAL, DIMENSION(:),   INTENT(OUT)  :: proad  ! Urban horizontal road density
REAL, DIMENSION(:),   INTENT(OUT)  :: proad_o_grnd  ! Road relative surface over ground (road + garden)
REAL, DIMENSION(:),   INTENT(OUT)  :: pgarden_o_grnd  ! Garden relative surface over ground (road + garden)
REAL, DIMENSION(:),   INTENT(OUT)  :: pwall_o_grnd  ! Wall relative surface over ground (road + garden)
REAL, DIMENSION(:),   INTENT(OUT)  :: pcan_hw_ratio  ! Urban canyon Height-Width ratio
REAL, DIMENSION(:),   INTENT(OUT)  :: psvf_road  ! road sky view factor
REAL, DIMENSION(:),   INTENT(OUT)  :: psvf_garden  ! garden sky view factor
REAL, DIMENSION(:),   INTENT(OUT)  :: psvf_wall  ! wall sky view factor
REAL, DIMENSION(:),   INTENT(OUT)  :: pz0_town  ! Urban roughness length
REAL, DIMENSION(:),   INTENT(OUT)  :: pwall_o_bld  ! Wall relative surface over ground (road + garden)
REAL, DIMENSION(:),   INTENT(INOUT)  :: ph_traffic   ! sensible heat flux due to traffic
REAL, DIMENSION(:),   INTENT(INOUT)  :: ple_traffic  ! latent heat flux due to traffic
!
!*       0.2   Declarations of local variables
!
INTEGER :: jj
INTEGER :: iluout
!
REAL, DIMENSION(SIZE(PBLD)) :: zwall_o_bld   ! Initial wall to built surface ratio
REAL, DIMENSION(SIZE(PBLD)) :: zwall_o_hor   ! Initial wall to horizontal surface ratio
!
REAL, DIMENSION(2) :: zrange_bld        = (/ 0.0001  ,   0.9999 /) ! Range allowed for PBLD variation
REAL, DIMENSION(2) :: zrange_road       = (/ 0.0001  ,   0.9999 /) ! Range allowed for PROAD variation
REAL, DIMENSION(2) :: zrange_bld_height = (/ 3.      , 829.84   /) ! Range allowed for PBLD_HEIGHT variation
REAL, DIMENSION(2) :: zrange_wall_o_hor = (/ 0.00012 , 322.     /) ! Range allowed for PWALL_O_HOR variation
!
!
!*       1.   Get listing file for warnings
!
 CALL get_luout(hprogram, iluout)
!

zwall_o_bld(:) = 0.
zwall_o_hor(:) = 0.

DO jj=1,SIZE(pbld)
   !
   !*    2.   Control building height no lower than 3.m and no higher than 829.84m
   !          reference: http://en.wikipedia.org/wiki/List_of_tallest_buildings_and_structures_in_the_world (2011)
   !          and control Z0_TOWN
   !
   IF (pbld_height(jj) < zrange_bld_height(1) ) THEN
      pbld_height(jj) = zrange_bld_height(1)
   ENDIF
   IF (pbld_height(jj) > zrange_bld_height(2)) &
           CALL abor1_sfx('TEB_MORPHO: PBLD_HEIGHT higher than 829.84, highest building in the world, should be lower')
   !
   IF (pz0_town(jj) > pbld_height(jj)) THEN
      CALL abor1_sfx('TEB_MORPHO: PZ0_TOWN higher than PBLD_HEIGHT, should be lower')
   ENDIF
   !
   !*    3.   Control no and almost no building in the cell
   !          authorize building up to 10m and W_O_H 0.001
   !
   IF (pbld(jj) < zrange_bld(1) ) THEN
      pbld(jj) = zrange_bld(1)
      pgarden(jj) = min(pgarden(jj), 1.-2.*pbld(jj))
   ENDIF
   !
   !*    4.   Control only building in the cell: could occur for high resolution 
   !          theoretically W_O_H could be 0. -> impose that at least the wall surface is equal to the mesh perimeter x building 
   !          height for a mesh size of 100 x 100m; the waste heat is released at the roof level
   !
   IF (pbld(jj) > zrange_bld(2)) THEN
      pbld(jj) = zrange_bld(2)
      IF (pgarden(jj) > 0.) THEN
         pgarden(jj) = 0. 
      ENDIF
   ENDIF
   !
   !*    5.   Control wall surface low respective to building density and building height: pb of the input
   !          Evaluation of the minimum woh is done for mesh size of 1000. m
   !          wall surface of the building evaluated considering 1 square building
   !
   IF (pwall_o_hor(jj) < 4. * sqrt(pbld(jj))*pbld_height(jj)/1000.) THEN
      pwall_o_hor(jj) = 4. * sqrt(pbld(jj))*pbld_height(jj)/1000. 
   ENDIF
   !
   !*    6.   Control facade surface vs building height, case of too high WALL_O_HOR
   !
   pwall_o_bld(jj) = pwall_o_hor(jj)/pbld(jj)
   !
   IF (pwall_o_bld(jj) > (0.4 * pbld_height(jj))) THEN ! <=> side_of_building < 10 m
      !     
      zwall_o_hor(jj) = pwall_o_hor(jj)
      zwall_o_bld(jj) = pwall_o_bld(jj)
      !
      pwall_o_hor(jj) = 0.4 * pbld(jj) * pbld_height(jj) ! correction WOHOR v2.1
      pwall_o_bld(jj) = pwall_o_hor(jj) / pbld(jj) ! correction WOHOR v2.1

   ENDIF
   !
   !*    7.   Verify road
   !
   proad(jj) = 1.-(pgarden(jj)+pbld(jj))
   IF (proad(jj) <= zrange_road(1) ) THEN
      proad(jj) = zrange_road(1)
      pgarden(jj) = max(pgarden(jj) - zrange_road(1), 0.)
      IF (ph_traffic(jj) > 0. .OR. ple_traffic(jj) > 0.) THEN
         ph_traffic(jj)  = 0.
         ple_traffic(jj) = 0.
      ENDIF
   ENDIF
   !
   !*    8.   Final check of parameters range
   !
   IF ( pbld(jj) < zrange_bld(1) .OR. pbld(jj) > zrange_bld(2) ) THEN
        WRITE(iluout,*) 'WARNING : PBLD is still out of range after final corrections &
        &for grid mesh',jj,' : ',pbld(jj)
   ENDIF
   !
   IF ( pbld_height(jj) < zrange_bld_height(1) .OR. pbld_height(jj) > zrange_bld_height(2) ) THEN
        WRITE(iluout,*) 'WARNING : PBLD_HEIGHT is still out of range after final corrections &
        &for grid mesh',jj,' : ',pbld_height(jj)
   ENDIF
   !
   IF ( pwall_o_hor(jj) < zrange_wall_o_hor(1) .OR. pwall_o_hor(jj) > zrange_wall_o_hor(2) ) THEN
        WRITE(iluout,*) 'WARNING : PWALL_O_HOR is still out of range after final corrections &
        &for grid mesh',jj,' : ',pwall_o_hor(jj)
   ENDIF
   !
   IF ( pwall_o_bld(jj) - (0.4 * pbld_height(jj)) > 10e-16 ) THEN
        WRITE(iluout,*) 'WARNING : PWALL_O_BLD is still too high after final corrections &
        &for grid mesh',jj,' : ',pwall_o_bld(jj)
   ENDIF
   !
ENDDO
!
!
!*    9.   Compute morphometric parameters 
!
pcan_hw_ratio(:)    = 0.5 * pwall_o_hor(:) / (1.-pbld(:))
!
!* relative surface fraction
!
proad_o_grnd(:)   = proad(:)       / (proad(:) + pgarden(:))
pgarden_o_grnd(:) = pgarden(:)     / (proad(:) + pgarden(:))
pwall_o_grnd(:)   = pwall_o_hor(:) / (proad(:) + pgarden(:))
!
!* Sky-view-factors:
!
psvf_road(:) = (sqrt(pcan_hw_ratio(:)**2+1.) - pcan_hw_ratio(:))
psvf_garden(:) = psvf_road(:)
psvf_wall(:) =  0.5*(pcan_hw_ratio(:)+1.-sqrt(pcan_hw_ratio(:)**2+1.))/pcan_hw_ratio(:)
!
END SUBROUTINE teb_morpho