surf_solar_slopes.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########################################################################
SUBROUTINE surf_solar_slopes (PCOSZEN,PSINZEN,PAZIMSOL,PSLOPANG, PSLOPAZI, &
                              psurf_triangle,pdirsrfswd,pdirswdt           )
!#########################################################################
!
!!****  * SURF_SOLAR_SLOPES * - computes the modifications to the downwards
!!                           direct solar flux at the surface, due to
!!                           orientation and shape of this surface.
!!
!!    PURPOSE
!!    -------
!!
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson      * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    15/01/02
!!      V. Masson   01/03/03 add multiple wavelengths
!!
!!                03/14  : M Lafaysse, modifs for optimization and parallelization
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_slope_effect, ONLY:nnxloc,nnyloc
!
IMPLICIT NONE
!
!*       0.1   DECLARATIONS OF DUMMY ARGUMENTS :
!

REAL, DIMENSION(:,:),     INTENT(IN) :: pcoszen ! COS(zenithal solar angle)
REAL, DIMENSION(:,:),     INTENT(IN) :: psinzen ! SIN(zenithal solar angle)
REAL, DIMENSION(:,:),     INTENT(IN) :: pazimsol! azimuthal solar angle

REAL, DIMENSION(:,:,:),     INTENT(IN) :: pslopazi   ! azimuthal slope angle of triangles
REAL, DIMENSION(:,:,:),     INTENT(IN) :: pslopang   ! vertical slope angle of triangles
REAL, DIMENSION(:,:,:),     INTENT(IN) :: psurf_triangle ! surface of triangles
!
REAL, DIMENSION(:,:,:),   INTENT(IN) :: pdirsrfswd!Downward SuRF. DIRect SW Flux
REAL, DIMENSION(:,:,:,:), INTENT(OUT):: pdirswdt ! shortwave flux received by 
!                                                ! each subgrid triangle
!
!
!*       0.2   DECLARATIONS OF LOCAL VARIABLES
!
REAL,    PARAMETER :: xpi=4.*atan(1.)  ! Pi
INTEGER, PARAMETER :: jphext = 1 ! number of points around the physical domain
!
INTEGER :: iib, iie, ijb, ije
INTEGER :: ji, jj, jb
INTEGER :: jt
!
REAL                   :: zdzsdx   ! slope in X and Y direction
REAL                   :: zdzsdy   ! of a triangle surface
REAL                   :: zslopazi ! azimuthal slope angle
REAL                   :: zslopang ! vertical slope angle
!
!-------------------------------------------------------------------------------
!
iib= 1+jphext
iie=nnxloc-jphext
ijb=1+jphext
ije=nnyloc-jphext
!
pdirswdt(:,:,:,:)=0.
!
!-------------------------------------------------------------------------------
!
!*       1.    LOOP ON GRID MESHES
!              -------------------
!
!* discretization of the grid mesh in four triangles
!
DO jt=1,4
!
  DO jj=ijb,ije
    DO ji=iib,iie
!
!* If zenithal angle greater than Pi/2, sun is down.
!
      IF (pcoszen(ji,jj)<0.) cycle
!
!-------------------------------------------------------------------------------
!
!*       2.    MODIFICATION OF RADIATION DUE TO LOCAL SLOPE
!              --------------------------------------------
!* modification of radiation received by 1 square meter of surface 
! (of the triangle) because of its orientation relative to the sun
!

! Modif Matthieu Lafaysse :
! threshold 0.001 on zenithal angle cosinus to avoid numerical problems at sunset and sunrise

      pdirswdt(ji,jj,jt,:) = max( 0.0 , pdirsrfswd(ji,jj,:) * ( &
         cos(pslopang(ji,jj,jt))                                          &
       + sin(pslopang(ji,jj,jt)) * psinzen(ji,jj) / max(pcoszen(ji,jj),0.001)     &
         *  cos(pazimsol(ji,jj)-pslopazi(ji,jj,jt))))
!
!* normalizes received radiation by the surface of the triangle to obtain
!  radiation representative of an horizontal surface.
!
        pdirswdt(ji,jj,jt,:) = pdirswdt(ji,jj,jt,:) * psurf_triangle(ji,jj,jt)
!
!         DO JB=1,SIZE(PDIRSWDT(JI,JJ,JT,:))
!           IF (PDIRSWDT(JI,JJ,JT,JB)>15000) THEN
!             PRINT*,"warning >10000"
!             PRINT*,ASIN(PSINZEN(JI,JJ)),ACOS(PCOSZEN(JI,JJ)),ZSLOPANG,ZSLOPAZI,PAZIMSOL(JI,JJ),&
!             PDIRSRFSWD(JI,JJ,JB),PDIRSWDT(JI,JJ,JT,JB)
!           END IF
!         END DO
    END DO
  END DO
END DO
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE surf_solar_slopes