sst_update.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE sst_update (DTS, S, &
                           psst,ttime)
!   ###############################################################
!!****  *SST_UPDATE*
!!
!!    PURPOSE
!!    -------
!
!     performs the time evolution of sst
!              
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      P. Le Moigne          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    09/2007
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE modd_data_seaflux_n, ONLY : data_seaflux_t
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_type_date_surf
USE modi_temporal_dists
USE modi_temporal_lts
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_seaflux_t), INTENT(INOUT) :: dts
TYPE(seaflux_t), INTENT(INOUT) :: s
!
TYPE(date_time),      INTENT(IN)    :: ttime   ! UTC time
REAL,   DIMENSION(:), INTENT(INOUT) :: psst    ! sst
!
!*      0.2    declarations of local variables
!
INTEGER                                  :: jxp
REAL, DIMENSION(SIZE(PSST))              :: zsst, zsst0
REAL                                     :: zsdtjx
REAL                                     :: zdt, zalpha
REAL(KIND=JPRB) :: zhook_handle
!-----------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SST_UPDATE',0,zhook_handle)
!
IF (.NOT.s%LTZTIME_DONE) THEN
   s%LTZTIME_DONE = .true.
   s%JSX = 1
   s%TZTIME%TDATE%YEAR  = ttime%TDATE%YEAR
   s%TZTIME%TDATE%MONTH = ttime%TDATE%MONTH
   s%TZTIME%TDATE%DAY   = ttime%TDATE%DAY
   s%TZTIME%TIME        = ttime%TIME
ENDIF
!
zsst0(:) = s%XSST_INI(:)
!
IF ( temporal_lts( ttime, dts%TDATA_SST(1) ) ) THEN
  !
  CALL temporal_dists( dts%TDATA_SST(1)%TDATE%YEAR,dts%TDATA_SST(1)%TDATE%MONTH, &
                        dts%TDATA_SST(1)%TDATE%DAY ,dts%TDATA_SST(1)%TIME,        &
                        s%TZTIME%TDATE%YEAR   ,s%TZTIME%TDATE%MONTH,          &
                        s%TZTIME%TDATE%DAY    ,s%TZTIME%TIME,                 &
                        zsdtjx                                            )  
  !
  CALL temporal_dists( ttime%TDATE%YEAR   ,ttime%TDATE%MONTH,           &
                        ttime%TDATE%DAY    ,ttime%TIME,                  &
                        s%TZTIME%TDATE%YEAR  ,s%TZTIME%TDATE%MONTH,          &
                        s%TZTIME%TDATE%DAY   ,s%TZTIME%TIME,                 &
                        zdt                                              )  
  !
  zalpha = zdt / zsdtjx
  !
  zsst(:)= zsst0(:)+(dts%XDATA_SST(:,1)-zsst0(:))*zalpha
  !
ELSE IF ( .NOT. temporal_lts( ttime, dts%TDATA_SST(dts%NTIME) ) ) THEN
  !
  zsst(:) = dts%XDATA_SST(:,dts%NTIME)
  !
ELSE
  !
  DO
    jxp = s%JSX + 1
    IF ( temporal_lts( ttime, dts%TDATA_SST(jxp)) ) EXIT
    s%JSX = s%JSX + 1
  ENDDO
  !  
  CALL temporal_dists( dts%TDATA_SST(jxp)%TDATE%YEAR,dts%TDATA_SST(jxp)%TDATE%MONTH,   &
                        dts%TDATA_SST(jxp)%TDATE%DAY ,dts%TDATA_SST(jxp)%TIME,          &
                        dts%TDATA_SST(s%JSX)%TDATE%YEAR ,dts%TDATA_SST(s%JSX)%TDATE%MONTH,  &
                        dts%TDATA_SST(s%JSX)%TDATE%DAY  ,dts%TDATA_SST(s%JSX)%TIME,         &
                        zsdtjx                                            )  
  !
  CALL temporal_dists( ttime%TDATE%YEAR   ,ttime%TDATE%MONTH,                  &
                        ttime%TDATE%DAY    ,ttime%TIME,                         &
                        dts%TDATA_SST(s%JSX)%TDATE%YEAR,dts%TDATA_SST(s%JSX)%TDATE%MONTH,   &
                        dts%TDATA_SST(s%JSX)%TDATE%DAY ,dts%TDATA_SST(s%JSX)%TIME,          &
                        zdt                                             )  
  !
  zalpha = zdt / zsdtjx

  !
  zsst(:)= dts%XDATA_SST(:,s%JSX)+(dts%XDATA_SST(:,jxp)-dts%XDATA_SST(:,s%JSX))*zalpha
  !                
END IF
!
psst(:) = zsst(:)
!
IF (lhook) CALL dr_hook('SST_UPDATE',1,zhook_handle)
!-----------------------------------------------------------------
!
END SUBROUTINE sst_update