sso_beljaars04.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################################
SUBROUTINE sso_beljaars04 (USS, &
                           ki,klvl,pz,psso_stdev,pu,pforc_u,pdforc_udu)
!     ###############################################################################
!
!!****  *SSO_BELJAARS04_n * - prepares forcing for canopy air model
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2006
!!---------------------------------------------------------------
!
!
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
INTEGER,                  INTENT(IN)    :: ki        ! number of points
INTEGER,                  INTENT(IN)    :: klvl      ! number of levels in canopy
REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pz        ! heights of canopy levels              (m)
REAL, DIMENSION(KI),      INTENT(IN)    :: psso_stdev! Subgrid scale orography standard dev. (m)

REAL, DIMENSION(KI,KLVL), INTENT(IN)    :: pu        ! wind for each canopy layer            (m/s)
!
REAL, DIMENSION(KI,KLVL), INTENT(INOUT)   :: pforc_u   ! tendency of wind due to canopy drag   (m/s2)
REAL, DIMENSION(KI,KLVL), INTENT(INOUT)   :: pdforc_udu! formal derivative of the tendency of
!                                                    ! wind due to canopy drag               (1/s)
!
!*      0.2    declarations of local variables
!
!
!* BERJLAARS et al 2004  constants
!
REAL, PARAMETER :: c_alpha   = 12.
REAL, PARAMETER :: c_beta    = 1.
REAL, PARAMETER :: c_cmd     = 0.005
REAL, PARAMETER :: c_cor     = 0.6
REAL, PARAMETER :: c_ih      = 0.00102    !   (m-1)
REAL, PARAMETER :: c_kflt    = 0.00035    !   (m-1)
REAL, PARAMETER :: c_k1      = 0.003      !   (m-1)
REAL, PARAMETER :: c_n1      = -1.9
REAL, PARAMETER :: c_n2      = -2.8
REAL            :: c_avar                 ! = C_K1**(C_N1-C_N2) / (C_IH * C_KFLT**C_N1)  
!                                         ! (unit: m^{1+C_N2}  =  m^-1.8)
!
INTEGER                  :: jl            ! loop counter on canopy heights
REAL, DIMENSION(KI,KLVL) :: zsso_drag     ! drag due to subgrid-scale orogaphy
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!-------------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('SSO_BELJAARS04',0,zhook_handle)
!
!*      2.     Computations of wind tendency due to orographic drag
!              ----------------------------------------------------
!
 c_avar    = c_k1**(c_n1-c_n2) / (c_ih * c_kflt**c_n1)   ! (unit: m^{1+C_N2}  =  m^-1.8)
!
!
!*      2.1    Drag coefficient in  drag force by subscale orography 
!              -----------------------------------------------------
!
! unit : m-1    (m^-1.8 . m ^2 . m^-1.2) 
!
zsso_drag = 0.
DO jl=1,klvl
  zsso_drag(:,jl) = uss%XCOEFBE * c_alpha * c_beta * c_cor * c_cmd * 2.109 * exp( -(pz(:,jl)/1500.)**1.5) &
    * c_avar * psso_stdev(:)**2 * pz(:,jl)**(-1.2)
END DO
!
!
!*      2.2    Impact on each SBL layer
!              ------------------------
!
! Ext = - Cdrag(z)  * u- * u-       (unit :  m s-2)   subscale orgraphy drag
!
pforc_u(:,:)    = pforc_u(:,:)    -       zsso_drag(:,:) * pu(:,:)**2
!
pdforc_udu(:,:) = pdforc_udu(:,:) -  2. * zsso_drag(:,:) * pu(:,:)
!
IF (lhook) CALL dr_hook('SSO_BELJAARS04',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE sso_beljaars04