solar_panel.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE solar_panel(PTSTEP, PTSUN, PRESIDENTIAL,                  &
                               pemit_lw_roof, pemit_lwdn_panel, plw_rad, &
                               pabs_sw_panel, pta, pn_floor, pfrac_panel,&
                               pemis_panel, palb_panel, peff_panel,      &
                               pabs_lw_panel, ph_panel, prn_panel,       &
                               pther_prodc_day,                          &
                               pther_prod_panel, pphot_prod_panel,       &
                               pprod_panel,                              &
                               pther_prod_bld,   pphot_prod_bld,         &
                               pprod_bld                                 )
!   ##########################################################################
!
!!****  *SOLAR_PANEL*  
!!
!!    PURPOSE
!!    -------
!
! Computes the energy budget of the solar panels.
!         
!     
!!**  METHOD
!     ------
!
!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      V. Masson           * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    08/2013
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surf_par, ONLY : xundef
USE modd_csts,     ONLY : xstefan
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
REAL,               INTENT(IN)  :: ptstep          ! time step  (s)
REAL, DIMENSION(:), INTENT(IN)  :: ptsun           ! solar time (s since solar midnight)
REAL, DIMENSION(:), INTENT(IN)  :: presidential    ! Buildings Residential use fraction        (-)
REAL, DIMENSION(:), INTENT(IN)  :: pemit_lw_roof   ! Upwards   LW flux from roof               (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: pemit_lwdn_panel! Downwards LW flux from panel              (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: plw_rad         ! Incoming Longwave radiation               (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: pabs_sw_panel   ! Absorbed solar energy by the solar panel  (W/m2)
REAL, DIMENSION(:), INTENT(IN)  :: pta             ! Air temperature                           (K)
REAL, DIMENSION(:), INTENT(IN)  :: pn_floor        ! number of floors                          (-)
REAL, DIMENSION(:), INTENT(IN)  :: pfrac_panel     ! fraction   of solar panel on roofs        (-)
REAL, DIMENSION(:), INTENT(IN)  :: pemis_panel     ! emissivity of solar panel                 (-)
REAL, DIMENSION(:), INTENT(IN)  :: palb_panel      ! albedo     of solar panel                 (-)
REAL, DIMENSION(:), INTENT(IN)  :: peff_panel      ! efficiency of solar panel                 (-)
REAL, DIMENSION(:), INTENT(OUT) :: pabs_lw_panel   ! Absorbed LW enerby by solar panel         (W/m2)
REAL, DIMENSION(:), INTENT(OUT) :: ph_panel        ! Sensible heat released by the solar panel (W/m2)
REAL, DIMENSION(:), INTENT(OUT) :: prn_panel       ! Net radiation     of the solar panel      (W/m2)
REAL, DIMENSION(:), INTENT(INOUT)::pther_prodc_day ! Present day integrated thermal production of energy    (J/m2 panel)
REAL, DIMENSION(:), INTENT(OUT) :: pther_prod_panel! Thermal      Energy production of the solar panel      (W/m2 panel)
REAL, DIMENSION(:), INTENT(OUT) :: pphot_prod_panel! Photovoltaic Energy production of the solar panel      (W/m2 panel)
REAL, DIMENSION(:), INTENT(OUT) :: pprod_panel     ! Averaged     Energy production of the solar panel      (W/m2 panel)
REAL, DIMENSION(:), INTENT(OUT) :: pther_prod_bld  ! Thermal      Energy production of the solar panel      (W/m2 bld)
REAL, DIMENSION(:), INTENT(OUT) :: pphot_prod_bld  ! Photovoltaic Energy production of the solar panel      (W/m2 bld)
REAL, DIMENSION(:), INTENT(OUT) :: pprod_bld       ! Averaged     Energy production of the solar panel      (W/m2 bld)
!
REAL(KIND=JPRB) :: zhook_handle
!
!*      0.2    declarations of parameters
!
! coefficient to take into account irradiance to estimate surface temperature of panel
REAL, PARAMETER :: xkt    = 0.05   ! (Km2/W)
!
! coefficient to take into account optimum orientation of the solar panel
REAL, PARAMETER :: xft    = 1.10   ! (-)
!
! optimum panel temperature for photovoltaic production
REAL, PARAMETER :: xt_opt = 298.15 ! (K)
!
! coefficient to take into account decrease of production for warm temperatures
REAL, PARAMETER :: xt_loss= 0.005  ! (K-1)
!
! difference of temperature between cold and hot water
REAL, PARAMETER :: xwater_dt = 45. ! (K)
!
! density of m2 of panel per m2 of floor necessary for hot water production
REAL, PARAMETER :: xther_floor= 1./30. ! (-)
!
! Annual thermal production for an increase of 1K of the water temperature
REAL, PARAMETER :: xther_rate= 0.5 * 1.16*32. ! (kWh/year/m2 panel)
!
!! Maximum irradiance above which there is no more heating necessary (target temperature reached quickly)
!REAL, PARAMETER :: XTHER_IRR = 500.           ! (W/m2)
! Efficiency for thermal panels
REAL, PARAMETER :: xther_eff = 0.60           ! (-)
!
!
!
!
!*      0.3    declarations of local variables
!
REAL                       :: zther_daily_target ! daily target for thermal production         (J/m2)
REAL, DIMENSION(SIZE(PTA)) :: zirradiance ! incoming solar radiation normal to the solar panel (W/m2)
REAL, DIMENSION(SIZE(PTA)) :: zts_panel   ! Surface temperature of the upwards face of the solar panel (K)
REAL, DIMENSION(SIZE(PTA)) :: zlwu_panel  ! Upwards longwave radiation from the solar panel (W/m2)
REAL, DIMENSION(SIZE(PTA)) :: zther_frac  ! Fraction of thermal      panels per m2 of roof  (m2 panel/m2 bld)
REAL, DIMENSION(SIZE(PTA)) :: zphot_frac  ! Fraction of photovoltaic panels per m2 of roof  (m2 panel/m2 bld)
REAL, DIMENSION(SIZE(PTA)) :: zther_prodc_day ! guess of daily production by thermal panels (J/m2)
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('SOLAR_PANEL',0,zhook_handle)
!-------------------------------------------------------------------------------
!
!*      0.4    Default values for output variables
!              -----------------------------------
!
pabs_lw_panel   = xundef ! Absorbed LW enerby by solar panel         (W/m2)
ph_panel        = xundef ! Sensible heat released by the solar panel (W/m2)
prn_panel       = xundef ! Net radiation     of the solar panel      (W/m2)
pther_prod_panel= xundef ! Thermal      Energy production of the solar panel      (W/m2)
pphot_prod_panel= xundef ! Photovoltaic Energy production of the solar panel      (W/m2)
pprod_panel     = xundef ! Averaged     Energy production of the solar panel      (W/m2)
pther_prod_bld  = 0.     ! Thermal      Energy production of the solar panel      (W/m2)
pphot_prod_bld  = 0.     ! Photovoltaic Energy production of the solar panel      (W/m2)
pprod_bld       = 0.     ! Averaged     Energy production of the solar panel      (W/m2)
!
!-------------------------------------------------------------------------------
!
!*      1.     Initializations
!              ---------------
!
!*      1.1    Checks hour for daily thermal production reset
!              ----------------------------------------------
!
!* energy reset between midnight and 1AM.
WHERE (ptsun(:)>=0. .AND. ptsun(:)<=3600.)  pther_prodc_day(:) = 0.
!
!
!*      1.2    Daily target production for thermal panels
!              ------------------------------------------
!
zther_daily_target = (2.*xther_rate) * xwater_dt * (1000. / 365. * 3600. ) ! (J/m2)
! the factor 2 is to remove the assumption of cloudy days in the annual mean production
!
!-------------------------------------------------------------------------------
!* Note that computations are done only where solar panels are present
WHERE (pfrac_panel(:)>0.)
!-------------------------------------------------------------------------------
!
!*      2.     Irradiance on panel
!              -------------------
!
  zirradiance(:) = xft * pabs_sw_panel(:) / (1.-palb_panel(:) ) 
!
!-------------------------------------------------------------------------------
!
!*      3.     Solar panel temperature
!              -----------------------
!
  zts_panel(:) = pta(:) + xkt * zirradiance(:)
!
!-------------------------------------------------------------------------------
!
!*      4.     Upwards solar panel LW radiation
!              --------------------------------
!
  zlwu_panel(:) =       pemis_panel(:)  * xstefan * zts_panel(:)**4 &
                    + (1.-pemis_panel(:)) * plw_rad(:)
!
!-------------------------------------------------------------------------------
!
!*      5.     Solar panel LW budget
!              ---------------------
!
  pabs_lw_panel(:)= plw_rad(:) + pemit_lw_roof(:) - pemit_lwdn_panel(:) - zlwu_panel(:)
!
!-------------------------------------------------------------------------------
!
!*      6.     Solar panel Net radiation
!              -------------------------
!
  prn_panel(:)    = pabs_sw_panel(:) + pabs_lw_panel(:)
!
!-------------------------------------------------------------------------------
!
!*      7.     Fraction of panel surface types
!              -------------------------------
!
!*      7.1    Panel dedicated to thermal production of hot water 
!              --------------------------------------------------
!
  zther_frac(:) = min( xther_floor * pn_floor(:) * presidential(:), pfrac_panel(:) )   ! (m2 thermal       panel / m2 roof)
!
!*      7.2    Photovoltaic panel
!              ------------------
!
  zphot_frac(:) =  pfrac_panel(:) - zther_frac(:)                      ! (m2 photovoltaic panel / m2 roof)
!
!-------------------------------------------------------------------------------
!
!*      8.     Thermal Production of hot water (W/m2 thermal panel)
!              -------------------------------
!
!*      8.1    Instantaneous production
!              ------------------------
!
  pther_prod_panel(:)= xther_eff * zirradiance(:)                       ! (W/m2)
!  PTHER_PROD_PANEL(:) = XTHER_RATE * XWATER_DT * (1000. / 24. / 365.)
!
!*      8.2    Integrated daily production
!              ---------------------------
!
  zther_prodc_day(:) = pther_prodc_day(:) + ptstep * pther_prod_panel(:) ! (J/m2)
!
!*      8.3    Daily production limited by daily target
!              ----------------------------------------
!
  zther_prodc_day(:) = min( zther_prodc_day(:) , zther_daily_target )
!
!*      8.4     Instantaneous production taking into account target limit if reached
!               --------------------------------------------------------------------
!
  pther_prod_panel(:)= ( zther_prodc_day(:) - pther_prodc_day(:) ) / ptstep
!
!*      8.5    Updates daily production
!              ------------------------
!
  pther_prodc_day(:) = zther_prodc_day(:)

!-------------------------------------------------------------------------------
!
!*      9.     Photovoltaic Production  (W/m2 photovoltaic panel)
!              -----------------------
!
  pphot_prod_panel(:) = peff_panel(:) * zirradiance(:) * min(1.,1.-xt_loss*(zts_panel(:)-xt_opt))
!
!-------------------------------------------------------------------------------
!
!*     10.     Averaged Production  (W/m2 panel)
!              -------------------
!
  pprod_panel(:) =  pther_prod_panel(:) * (zther_frac(:) / pfrac_panel(:)) &
                  + pphot_prod_panel(:) * (zphot_frac(:) / pfrac_panel(:))
!
!-------------------------------------------------------------------------------
!
!*     11.     Sensible heat flux  (W/m2 panel)
!              ------------------
!
  ph_panel(:) = prn_panel(:) - pprod_panel(:)
!
!-------------------------------------------------------------------------------
!
!*     12.     Productions per building (W/m2 bld)
!              ------------------------
!
  pther_prod_bld(:) = pther_prod_panel(:) * zther_frac(:)
  pphot_prod_bld(:) = pphot_prod_panel(:) * zphot_frac(:)
  pprod_bld(:) = pther_prod_bld(:) + pphot_prod_panel(:)
!
!-------------------------------------------------------------------------------
END WHERE
!-------------------------------------------------------------------------------
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('SOLAR_PANEL',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE solar_panel