sfx_oasis_send_ol.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE sfx_oasis_send_ol (F, I, S, U, W, &
                              hprogram,ki,ptimec,pstep_surf,ksize_omp)
!###########################################
!
!!****  *SFX_OASIS_SEND_OL* - Offline driver to send coupling fields
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
USE modd_off_surfex_n, ONLY : goto_model
!
USE modd_flake_n, ONLY : flake_t
USE modd_isba_n, ONLY : isba_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_surfex_omp, ONLY :  nindx1sfx, nindx2sfx, nblock, nblocktot, &
                             init_dim, reset_dim
!
USE modd_surf_par,   ONLY : xundef
!
USE modn_sfx_oasis,  ONLY : xtstep_cpl_land, &
                            xtstep_cpl_lake, &
                            xtstep_cpl_sea , &
                            lwater
!
USE modd_sfx_oasis,  ONLY : lcpl_land,lcpl_gw,       &
                            lcpl_flood,lcpl_calving, &
                            lcpl_lake,               &
                            lcpl_sea,lcpl_seaice
!
USE modi_get_sfx_land
USE modi_get_sfx_lake
USE modi_get_sfx_sea
!
USE modi_get_luout
USE modi_sfx_oasis_send
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
#ifdef AIX64
!$ USE OMP_LIB
#endif
!
IMPLICIT NONE
!
#ifndef AIX64
!$ INCLUDE 'omp_lib.h'
#endif
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(flake_t), INTENT(INOUT) :: f
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(seaflux_t), INTENT(INOUT) :: s
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(watflux_t), INTENT(INOUT) :: w
!
 CHARACTER(LEN=*),      INTENT(IN) :: hprogram
INTEGER,               INTENT(IN) :: ki            ! number of points
REAL,                  INTENT(IN) :: ptimec        ! Cumulated run time step (s)
REAL,                  INTENT(IN) :: pstep_surf    ! Model time step (s)
INTEGER, DIMENSION(:), INTENT(IN) :: ksize_omp
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI)   :: zland_runoff    ! Cumulated Surface runoff             (kg/m2)
REAL, DIMENSION(KI)   :: zland_drain     ! Cumulated Deep drainage              (kg/m2)
REAL, DIMENSION(KI)   :: zland_calving   ! Cumulated Calving flux               (kg/m2)
REAL, DIMENSION(KI)   :: zland_recharge  ! Cumulated Recharge to groundwater    (kg/m2)
REAL, DIMENSION(KI)   :: zland_watfld    ! Cumulated net freshwater rate        (kg/m2)
!
REAL, DIMENSION(KI)   :: zlake_evap  ! Cumulated Evaporation             (kg/m2)
REAL, DIMENSION(KI)   :: zlake_rain  ! Cumulated Rainfall rate           (kg/m2)
REAL, DIMENSION(KI)   :: zlake_snow  ! Cumulated Snowfall rate           (kg/m2)
REAL, DIMENSION(KI)   :: zlake_watf  ! Cumulated net freshwater rate     (kg/m2)
!
REAL, DIMENSION(KI)   :: zsea_fwsu  ! Cumulated zonal wind stress       (Pa.s)
REAL, DIMENSION(KI)   :: zsea_fwsv  ! Cumulated meridian wind stress    (Pa.s)
REAL, DIMENSION(KI)   :: zsea_heat  ! Cumulated Non solar net heat flux (J/m2)
REAL, DIMENSION(KI)   :: zsea_snet  ! Cumulated Solar net heat flux     (J/m2)
REAL, DIMENSION(KI)   :: zsea_wind  ! Cumulated 10m wind speed          (m)
REAL, DIMENSION(KI)   :: zsea_fwsm  ! Cumulated wind stress             (Pa.s)
REAL, DIMENSION(KI)   :: zsea_evap  ! Cumulated Evaporation             (kg/m2)
REAL, DIMENSION(KI)   :: zsea_rain  ! Cumulated Rainfall rate           (kg/m2)
REAL, DIMENSION(KI)   :: zsea_snow  ! Cumulated Snowfall rate           (kg/m2)
REAL, DIMENSION(KI)   :: zsea_watf  ! Cumulated net freshwater rate     (kg/m2)
!
REAL, DIMENSION(KI)   :: zseaice_heat ! Cumulated Sea-ice non solar net heat flux (J/m2)
REAL, DIMENSION(KI)   :: zseaice_snet ! Cumulated Sea-ice solar net heat flux     (J/m2)
REAL, DIMENSION(KI)   :: zseaice_evap ! Cumulated Sea-ice sublimation             (kg/m2)
!
INTEGER               :: idate  ! current coupling time step (s)
INTEGER               :: iluout
INTEGER               :: inkproma
!
LOGICAL               :: gsend_land
LOGICAL               :: gsend_lake
LOGICAL               :: gsend_sea
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_SEND_OL',0,zhook_handle)
!
!-------------------------------------------------------------------------------
!
!*       1.     Initialize proc by proc :
!               -------------------------
!
 CALL get_luout(hprogram,iluout)
!
idate = int(ptimec-pstep_surf)
!
gsend_land=(lcpl_land.AND.mod(ptimec,xtstep_cpl_land)==0.0)
gsend_lake=(lcpl_lake.AND.mod(ptimec,xtstep_cpl_lake)==0.0)
gsend_sea =(lcpl_sea .AND.mod(ptimec,xtstep_cpl_sea )==0.0)
!
!-------------------------------------------------------------------------------
!
IF(.NOT.(gsend_land.OR.gsend_lake.OR.gsend_sea))THEN
  IF (lhook) CALL dr_hook('SFX_OASIS_SEND_OL',1,zhook_handle)
  RETURN
ENDIF
!
!-------------------------------------------------------------------------------
!
IF(gsend_land)THEN
  zland_runoff(:) = xundef
  zland_drain(:) = xundef
  zland_calving(:) = xundef
  zland_recharge(:) = xundef
  zland_watfld(:) = xundef  
ENDIF
!
IF(gsend_lake)THEN
  zlake_evap(:) = xundef
  zlake_rain(:) = xundef
  zlake_snow(:) = xundef
  zsea_watf(:) = xundef  
ENDIF
!
IF(gsend_sea)THEN
  zsea_fwsu(:) = xundef
  zsea_fwsv(:) = xundef
  zsea_heat(:) = xundef
  zsea_snet(:) = xundef
  zsea_wind(:) = xundef
  zsea_fwsm(:) = xundef
  zsea_evap(:) = xundef
  zsea_rain(:) = xundef
  zsea_snow(:) = xundef
  zsea_watf(:) = xundef
  !
  zseaice_heat(:) = xundef
  zseaice_snet(:) = xundef
  zseaice_evap(:) = xundef
ENDIF
!
!-------------------------------------------------------------------------------
!
!$OMP PARALLEL PRIVATE(INKPROMA)
!
!$ NBLOCK = OMP_GET_THREAD_NUM()
!
IF (nblock==nblocktot) THEN
   CALL init_dim(ksize_omp,0,inkproma,nindx1sfx,nindx2sfx)
ELSE
   CALL init_dim(ksize_omp,nblock,inkproma,nindx1sfx,nindx2sfx)
ENDIF
!
IF (nblock==0) THEN
   CALL goto_model(nblocktot)
ELSE
   CALL goto_model(nblock)
ENDIF
!
!*       2.     get local fields :
!               ------------------
!
IF(gsend_land)THEN
!
! * Get river output fields
!
  CALL get_sfx_land(i, u, &
                    lcpl_gw,lcpl_flood,lcpl_calving,                           &
                    zland_runoff(nindx1sfx:nindx2sfx),zland_drain(nindx1sfx:nindx2sfx),&
                    zland_calving(nindx1sfx:nindx2sfx),zland_recharge(nindx1sfx:nindx2sfx),&
                    zland_watfld(nindx1sfx:nindx2sfx))
!
ENDIF
!
IF(gsend_lake)THEN
!
! * Get output fields
!
  CALL get_sfx_lake(f, u, &
                    zlake_evap(nindx1sfx:nindx2sfx),zlake_rain(nindx1sfx:nindx2sfx), &
                    zlake_snow(nindx1sfx:nindx2sfx),zlake_watf(nindx1sfx:nindx2sfx) )
!
ENDIF
!
IF(gsend_sea)THEN
!
! * Get sea output fields
!
  CALL get_sfx_sea(s, u, w, &
                   lcpl_seaice,lwater,                                                                                    &
                   zsea_fwsu(nindx1sfx:nindx2sfx),zsea_fwsv(nindx1sfx:nindx2sfx),zsea_heat(nindx1sfx:nindx2sfx),&
                   zsea_snet(nindx1sfx:nindx2sfx),zsea_wind(nindx1sfx:nindx2sfx),zsea_fwsm(nindx1sfx:nindx2sfx),&
                   zsea_evap(nindx1sfx:nindx2sfx),zsea_rain(nindx1sfx:nindx2sfx),zsea_snow(nindx1sfx:nindx2sfx),&
                   zsea_watf(nindx1sfx:nindx2sfx),                                                                    &
                   zseaice_heat(nindx1sfx:nindx2sfx),zseaice_snet(nindx1sfx:nindx2sfx),zseaice_evap(nindx1sfx:nindx2sfx) )
!
ENDIF
!
 CALL reset_dim(ki,inkproma,nindx1sfx,nindx2sfx)
!
!$OMP END PARALLEL
!    
!-------------------------------------------------------------------------------
!
!*       3.     Send fields to OASIS proc by proc:
!               ----------------------------------
!
!
 CALL sfx_oasis_send(iluout,ki,idate,gsend_land,gsend_lake,gsend_sea,      &
                    zland_runoff,zland_drain,zland_calving,zland_recharge,&
                    zland_watfld,                                         &
                    zlake_evap,zlake_rain,zlake_snow,zlake_watf,          &
                    zsea_fwsu,zsea_fwsv,zsea_heat,zsea_snet,zsea_wind,    &
                    zsea_fwsm,zsea_evap,zsea_rain,zsea_snow,zsea_watf,    &
                    zseaice_heat,zseaice_snet,zseaice_evap                )                     
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_SEND_OL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE sfx_oasis_send_ol