sfx_oasis_recv_ol.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE sfx_oasis_recv_ol (F, I, S, U, W, &
                             hprogram,ki,ksw,ptimec,ptstep_surf,   &
                             ksize_omp,pzenith,psw_bands,          &
                             ptsrad,pdir_alb,psca_alb,pemis,ptsurf )
!#############################################
!
!!****  *SFX_OASIS_RECV_OL* - Offline driver that receive coupling fields from oasis
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modn_sfx_oasis,  ONLY : xtstep_cpl_land, &
                            xtstep_cpl_sea,  &
                            lwater
!
USE modd_sfx_oasis,  ONLY : lcpl_land,         &
                            lcpl_gw,lcpl_flood,&
                            lcpl_sea,          &
                            lcpl_seaice
!                    
USE modd_off_surfex_n, ONLY : goto_model
!
USE modd_flake_n, ONLY : flake_t
USE modd_isba_n, ONLY : isba_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_watflux_n, ONLY : watflux_t
!
USE modd_surf_par,   ONLY : xundef
!
USE modd_surfex_omp, ONLY :  nindx1sfx, nindx2sfx, nblock, nblocktot, &
                             init_dim, reset_dim
!
USE modi_get_luout
USE modi_sfx_oasis_recv
USE modi_put_sfx_land
USE modi_put_sfx_sea
USE modi_update_esm_surf_atm_n
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
#ifdef AIX64
!$ USE OMP_LIB
#endif
!
IMPLICIT NONE
!
#ifndef AIX64
!$ INCLUDE 'omp_lib.h'
#endif
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(flake_t), INTENT(INOUT) :: f
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(seaflux_t), INTENT(INOUT) :: s
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(watflux_t), INTENT(INOUT) :: w
!
 CHARACTER(LEN=6),       INTENT(IN)  :: hprogram    ! program calling surf. schemes
!
INTEGER,                INTENT(IN)  :: ki          ! number of points on this proc
INTEGER,                INTENT(IN)  :: ksw         ! number of short-wave spectral bands
REAL,                   INTENT(IN)  :: ptimec      ! Cumulated run time step (s)
REAL,                   INTENT(IN)  :: ptstep_surf ! Surfex time step
INTEGER, DIMENSION(:),  INTENT(IN)  :: ksize_omp
!
REAL, DIMENSION(KI),    INTENT(IN)  :: pzenith   ! zenithal angle       (radian from the vertical)
REAL, DIMENSION(KSW),   INTENT(IN)  :: psw_bands ! mean wavelength of each shortwave band (m)
!
REAL, DIMENSION(KI),    INTENT(OUT) :: ptsrad    ! radiative temperature                 (K)
REAL, DIMENSION(KI,KSW),INTENT(OUT) :: pdir_alb  ! direct albedo for each spectral band  (-)
REAL, DIMENSION(KI,KSW),INTENT(OUT) :: psca_alb  ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(KI),    INTENT(OUT) :: pemis     ! emissivity                            (-)
REAL, DIMENSION(KI),    INTENT(OUT) :: ptsurf    ! surface effective temperature         (K)
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(KI) :: zland_wtd     ! Land water table depth (m)
REAL, DIMENSION(KI) :: zland_fwtd    ! Land grid-cell fraction of water table rise (-)
REAL, DIMENSION(KI) :: zland_fflood  ! Land Floodplains fraction (-)
REAL, DIMENSION(KI) :: zland_piflood ! Land Potential flood infiltration(kg/m2/s)
REAL, DIMENSION(KI) :: zsea_sst      ! Sea surface temperature (K)
REAL, DIMENSION(KI) :: zsea_ucu      ! Sea u-current stress (Pa)
REAL, DIMENSION(KI) :: zsea_vcu      ! Sea v-current stress (Pa)
REAL, DIMENSION(KI) :: zseaice_sit   ! Sea-ice Temperature (K)
REAL, DIMENSION(KI) :: zseaice_cvr   ! Sea-ice cover (-)
REAL, DIMENSION(KI) :: zseaice_alb   ! Sea-ice albedo (-)
!
REAL                :: ztime_cpl
!
LOGICAL             :: grecv_land
LOGICAL             :: grecv_flood
LOGICAL             :: grecv_sea
!
INTEGER             :: inkproma, iluout
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_RECV_OL',0,zhook_handle)
!
!-------------------------------------------------------------------------------
!
!*       1.     init coupling fields:
!               ----------------------------------
!
ztime_cpl = ptimec-ptstep_surf
!
grecv_land=(lcpl_land.AND.mod(ztime_cpl,xtstep_cpl_land)==0.0)
grecv_sea =(lcpl_sea .AND.mod(ztime_cpl,xtstep_cpl_sea )==0.0)
!
IF(.NOT.(grecv_land.OR.grecv_sea))THEN
  IF (lhook) CALL dr_hook('SFX_OASIS_RECV_OL',1,zhook_handle)
  RETURN
ENDIF
!
 CALL get_luout(hprogram,iluout)
!
IF(grecv_land)THEN
  zland_wtd(:) = xundef
  zland_fwtd(:) = xundef
  zland_fflood(:) = xundef
  zland_piflood(:) = xundef
ENDIF
!
IF(grecv_sea)THEN
  zsea_sst(:) = xundef
  zsea_ucu(:) = xundef
  zsea_vcu(:) = xundef
  zseaice_sit(:) = xundef
  zseaice_cvr(:) = xundef
  zseaice_alb(:) = xundef
ENDIF
!
!*       2.     Receive fields to other models proc by proc:
!               --------------------------------------------
!
 CALL sfx_oasis_recv(hprogram,ki,ksw,ztime_cpl,         &
                    grecv_land, grecv_sea,             &
                    zland_wtd(:),zland_fwtd(:), &
                    zland_fflood(:),zland_piflood(:), &
                    zsea_sst(:),zsea_ucu(:), &
                    zsea_vcu(:),zseaice_sit(:), &
                    zseaice_cvr(:),zseaice_alb(:)  )
!
!*       3.     Put definitions for exchange of coupling fields :
!               -------------------------------------------------
!
!$OMP PARALLEL PRIVATE(INKPROMA)
!
!$ NBLOCK = OMP_GET_THREAD_NUM()
!
IF (nblock==nblocktot) THEN
   CALL init_dim(ksize_omp,0,inkproma,nindx1sfx,nindx2sfx)
ELSE
   CALL init_dim(ksize_omp,nblock,inkproma,nindx1sfx,nindx2sfx)
ENDIF
!
IF (nblock==0) THEN
   CALL goto_model(nblocktot)
ELSE
   CALL goto_model(nblock)
ENDIF
!
!-------------------------------------------------------------------------------
! Put variable over land tile
!-------------------------------------------------------------------------------
!
IF(grecv_land)THEN
  CALL put_sfx_land(i, u,                                                                 &
                    iluout,lcpl_gw,lcpl_flood,                                            &
                    zland_wtd(nindx1sfx:nindx2sfx),zland_fwtd(nindx1sfx:nindx2sfx), &
                    zland_fflood(nindx1sfx:nindx2sfx),zland_piflood(nindx1sfx:nindx2sfx)  )        
ENDIF
!
!-------------------------------------------------------------------------------
! Put variable over sea and/or water tile
!-------------------------------------------------------------------------------
!
IF(grecv_sea)THEN
  CALL put_sfx_sea(s, u, w,                                                           &
                   iluout,lcpl_seaice,lwater,                                         &
                   zsea_sst(nindx1sfx:nindx2sfx),zsea_ucu(nindx1sfx:nindx2sfx), &
                   zsea_vcu(nindx1sfx:nindx2sfx),zseaice_sit(nindx1sfx:nindx2sfx), &
                   zseaice_cvr(nindx1sfx:nindx2sfx),zseaice_alb(nindx1sfx:nindx2sfx)  )
ENDIF
!
!-------------------------------------------------------------------------------
! Update radiative properties at time t+1 for radiative scheme
!-------------------------------------------------------------------------------
!
grecv_flood=(grecv_land.AND.lcpl_flood)
!
IF(grecv_sea.OR.grecv_flood)THEN     
  CALL update_esm_surf_atm_n(f, i, s, u, w, &
                             hprogram, inkproma, ksw, pzenith(nindx1sfx:nindx2sfx), psw_bands, &
                             ptsrad(nindx1sfx:nindx2sfx), pdir_alb(nindx1sfx:nindx2sfx,:),     &
                             psca_alb(nindx1sfx:nindx2sfx,:), pemis(nindx1sfx:nindx2sfx),      &
                             ptsurf(nindx1sfx:nindx2sfx)                                       )                    
ENDIF
!
 CALL reset_dim(ki,inkproma,nindx1sfx,nindx2sfx)
!
!$OMP END PARALLEL
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_RECV_OL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE sfx_oasis_recv_ol