sfx_oasis_prep.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE sfx_oasis_prep (I, UG, U, &
                           hprogram)
!###################################################
!
!!****  *SFX_OASIS_PREP* - Prepare grid areas and mask file for SFX-OASIS coupling
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE modd_isba_n, ONLY : isba_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par,       ONLY : xundef
!
!
!
!
USE modn_sfx_oasis
USE modd_sfx_oasis
!
USE modi_get_luout
USE modi_abor1_sfx
USE modi_get_mesh_corner
USE modi_unpack_same_rank
USE modi_sfx_oasis_check
!
#ifdef CPLOASIS
USE mod_oasis
#endif
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),        INTENT(IN) :: hprogram    ! program calling surf. schemes
!
!
!*       0.2   Declarations of local parameter
!              -------------------------------
!
INTEGER,           PARAMETER  :: inc = 4    ! Number of grid-cell corners
!
 CHARACTER(LEN=4),  PARAMETER  :: ysfx_land = 'slan'
 CHARACTER(LEN=4),  PARAMETER  :: ysfx_qsb  = 'sdra'
 CHARACTER(LEN=4),  PARAMETER  :: ysfx_gw   = 'sgw '
 CHARACTER(LEN=4),  PARAMETER  :: ysfx_sea  = 'ssea'
 CHARACTER(LEN=4),  PARAMETER  :: ysfx_lake = 'slak'
!
!*       0.3   Declarations of local variables
!              -------------------------------
!
REAL,    DIMENSION(U%NDIM_FULL)       :: zgw        ! groundwater mask
REAL,    DIMENSION(U%NDIM_FULL)       :: zmask_land ! land-sea mask for rrm coupling
REAL,    DIMENSION(U%NDIM_FULL)       :: zmask_lake ! lake mask for ogcm coupling
REAL,    DIMENSION(U%NDIM_FULL)       :: zmask_sea  ! sea-land mask for ogcm coupling
!
REAL,    DIMENSION(U%NDIM_FULL,1)     :: zlon
REAL,    DIMENSION(U%NDIM_FULL,1)     :: zlat
REAL,    DIMENSION(U%NDIM_FULL,1)     :: zarea
INTEGER, DIMENSION(U%NDIM_FULL,1)     :: imask
!
REAL,    DIMENSION(U%NDIM_FULL,1,INC) :: zcorner_lon
REAL,    DIMENSION(U%NDIM_FULL,1,INC) :: zcorner_lat
!
INTEGER, DIMENSION(2)          :: ivar_shape  ! indexes for the coupling field local dimension
!
INTEGER                        :: ipart_id ! Local partition ID
INTEGER                        :: ierr     ! Error info
!
INTEGER                        :: iluout, iflag
!
INTEGER                        :: ji, jc
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_PREP',0,zhook_handle)
!
!-------------------------------------------------------------------------------
#ifdef CPLOASIS
!-------------------------------------------------------------------------------
!
!
!*       0.     Initialize :
!               ------------
!
 CALL get_luout(hprogram,iluout)
!
 CALL sfx_oasis_check(i, u, &
                     iluout)
!
!-------------------------------------------------------------------------------
!
!*       2.     Get grid definition :
!               ---------------------
!
 CALL get_mesh_corner(ug, &
                     iluout,zcorner_lat(:,1,:),zcorner_lon(:,1,:))
!
zlon(:,1)=ug%XLON(:)
zlat(:,1)=ug%XLAT(:)
!
IF(lcpl_gw.AND.i%LGW)THEN
  CALL unpack_same_rank(u%NR_NATURE(:),i%XGW(:),zgw(:))
  WHERE(zgw(:)==xundef)
        zgw(:)=0.0
  ELSEWHERE(zgw(:)>0.0)
        zgw(:)=1.0
  ENDWHERE
ELSE
  zgw(:) = 0.0
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       3.     Comput masks :
!               --------------
!
zmask_land(:) = u%XNATURE(:)+u%XTOWN(:)
zmask_sea(:) = u%XSEA   (:)
IF(u%CWATER=='FLAKE ')THEN
  zmask_lake(:) = u%XWATER (:)
ELSE
  zmask_lake(:) = xundef
ENDIF
IF(lcpl_sea.AND.lwater)THEN
  zmask_sea(:) = u%XSEA (:)+u%XWATER(:)
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       5.     Write grid definition :
!               -----------------------
!
!
!
 CALL oasis_start_grids_writing(iflag)
!
!*       1.1    Grid definition for Land surface :
!               ----------------------------------
!
IF(lcpl_land)THEN  
!
  zarea(:,1) = ug%XMESH_SIZE(:) * zmask_land(:)
  !0 = not masked ; 1 = masked
  WHERE(zarea(:,1)>0.0)
        imask(:,1) = 0
  ELSEWHERE
        imask(:,1) = 1
  ENDWHERE
  CALL oasis_write_grid(ysfx_land,u%NDIM_FULL,1,zlon(:,:),zlat(:,:))  
  CALL oasis_write_corner(ysfx_land,u%NDIM_FULL,1,inc,zcorner_lon(:,:,:),zcorner_lat(:,:,:))
  CALL oasis_write_area(ysfx_land,u%NDIM_FULL,1,zarea(:,:))
  CALL oasis_write_mask(ysfx_land,u%NDIM_FULL,1,imask(:,:))
!
  zarea(:,1) = ug%XMESH_SIZE(:) * zmask_land(:) * (1.0-zgw(:))
  !0 = not masked ; 1 = masked
  WHERE(zarea(:,1)>0.0)
        imask(:,1) = 0
  ELSEWHERE
        imask(:,1) = 1
  ENDWHERE
  CALL oasis_write_grid(ysfx_qsb,u%NDIM_FULL,1,zlon(:,:),zlat(:,:))  
  CALL oasis_write_corner(ysfx_qsb,u%NDIM_FULL,1,inc,zcorner_lon(:,:,:),zcorner_lat(:,:,:))
  CALL oasis_write_area(ysfx_qsb,u%NDIM_FULL,1,zarea(:,:))
  CALL oasis_write_mask(ysfx_qsb,u%NDIM_FULL,1,imask(:,:))
!
ENDIF
!
! groundwater surface coupling case
!
IF(lcpl_gw)THEN       
  zarea(:,1) = ug%XMESH_SIZE(:) * zgw(:)
  !0 = not masked ; 1 = masked
  WHERE(zarea(:,1)>0.0)
        imask(:,1) = 0
  ELSEWHERE
        imask(:,1) = 1
  ENDWHERE
  CALL oasis_write_grid(ysfx_gw,u%NDIM_FULL,1,zlon(:,:),zlat(:,:))  
  CALL oasis_write_corner(ysfx_gw,u%NDIM_FULL,1,inc,zcorner_lon(:,:,:),zcorner_lat(:,:,:))
  CALL oasis_write_area(ysfx_gw,u%NDIM_FULL,1,zarea(:,:))
  CALL oasis_write_mask(ysfx_gw,u%NDIM_FULL,1,imask(:,:))
ENDIF
!
!*       1.2    Grid definition for lake surface :
!               ----------------------------------
!
IF(lcpl_lake)THEN
  zarea(:,1) = ug%XMESH_SIZE(:) * zmask_lake(:)
  !0 = not masked ; 1 = masked
  WHERE(zarea(:,1)>0.0)
        imask(:,1) = 0
  ELSEWHERE
        imask(:,1) = 1
  ENDWHERE
  CALL oasis_write_grid(ysfx_lake,u%NDIM_FULL,1,zlon(:,:),zlat(:,:))  
  CALL oasis_write_corner(ysfx_lake,u%NDIM_FULL,1,inc,zcorner_lon(:,:,:),zcorner_lat(:,:,:))
  CALL oasis_write_area(ysfx_lake,u%NDIM_FULL,1,zarea(:,:))
  CALL oasis_write_mask(ysfx_lake,u%NDIM_FULL,1,imask(:,:))
ENDIF
!
!*       1.3    Grid definition for sea/water :
!               -------------------------------
!
IF(lcpl_sea)THEN     
  zarea(:,1) = ug%XMESH_SIZE(:) * zmask_sea(:)
  !0 = not masked ; 1 = masked
  WHERE(zarea(:,1)>0.0)
        imask(:,1) = 0
  ELSEWHERE
        imask(:,1) = 1
  ENDWHERE
  CALL oasis_write_grid(ysfx_sea,u%NDIM_FULL,1,zlon(:,:),zlat(:,:))  
  CALL oasis_write_corner(ysfx_sea,u%NDIM_FULL,1,inc,zcorner_lon(:,:,:),zcorner_lat(:,:,:))
  CALL oasis_write_area(ysfx_sea,u%NDIM_FULL,1,zarea(:,:))
  CALL oasis_write_mask(ysfx_sea,u%NDIM_FULL,1,imask(:,:))
ENDIF
!
 CALL oasis_terminate_grids_writing()
!
 CALL oasis_enddef(ierr)
!
IF(ierr/=oasis_ok)THEN
   WRITE(iluout,*)'SFX_OASIS_PREP: OASIS enddef problem, err = ',ierr
   CALL abor1_sfx('SFX_OASIS_PREP: OASIS enddef problem')
ENDIF
!
!-------------------------------------------------------------------------------
#endif
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_PREP',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE sfx_oasis_prep