sfx_oasis_def_ol.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!#########
SUBROUTINE sfx_oasis_def_ol (I, &
                              u, &
                             hprogram,halg_mpi)
!#############################################
!
!!****  *SFX_OASIS_DEF_OL* - Offline driver for definitions for exchange of coupling fields
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_isba_n, ONLY : isba_t
!
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par,       ONLY : xundef
!
USE modd_surfex_mpi,     ONLY : nproc, nrank, nindex
!
!
USE modi_sfx_oasis_define
!
#ifdef CPLOASIS
USE mod_oasis
#endif
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
!
TYPE(isba_t), INTENT(INOUT) :: i
!
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram   ! program calling surf. schemes
 CHARACTER(LEN=4),   INTENT(IN)  :: halg_mpi   ! decomposition algorithm
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER, DIMENSION(:), ALLOCATABLE :: iparal
INTEGER, DIMENSION(:), ALLOCATABLE :: iseg_size
INTEGER, DIMENSION(:), ALLOCATABLE :: iseg_offset
!
INTEGER, DIMENSION(U%NDIM_FULL+1) :: iindex
!
INTEGER :: jproc, ji, jseg
INTEGER :: isegment, icount, inpar, inpts
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_DEF_OL',0,zhook_handle)
!
!-------------------------------------------------------------------------------
#ifdef CPLOASIS 
!-------------------------------------------------------------------------------
!
!*       1.     Define ORANGE parallel partitions:
!               ----------------------------------
!
! Number of segments for this proc
!
iindex(1:u%NDIM_FULL)=nindex(:)
iindex(u%NDIM_FULL+1)=nproc+10
isegment=0
DO ji=1,u%NDIM_FULL
   IF(nindex(ji)==nrank.AND.nindex(ji)/=iindex(ji+1))THEN
      isegment=isegment+1
   ENDIF
ENDDO
!  
inpar=2+2*isegment
!
! Local offset and extent for this proc
!
ALLOCATE(iseg_size(isegment))
ALLOCATE(iseg_offset(isegment))
!
isegment=0
icount=0
DO ji=1,u%NDIM_FULL
   IF(nindex(ji)==nrank)THEN
     icount=icount+1
   ENDIF
   IF(nindex(ji)==nrank.AND.nindex(ji)/=iindex(ji+1))THEN
      isegment             =isegment+1
      iseg_size(isegment)=icount
      iseg_offset(isegment)=ji-icount
      icount=0
   ENDIF
ENDDO
!
ALLOCATE(iparal(inpar))
!
! OASIS orange partition
!
iparal(clim_strategy) = clim_orange
!
! Number of proc segments for OASIS
!
iparal(2) = isegment
!
! Local offset and extent for OASIS
!
ji=2
inpts=0
DO jseg=1,isegment
   ji=ji+1
   iparal(ji) = iseg_offset(jseg)
   ji=ji+1
   iparal(ji) = iseg_size(jseg)
   inpts=inpts+iseg_size(jseg)
ENDDO
!  
DEALLOCATE(iseg_size  )
DEALLOCATE(iseg_offset)
!
!
!*       2.     Put definitions for exchange of coupling fields :
!               -------------------------------------------------
!
 CALL sfx_oasis_define(i, u, &
                      hprogram,inpts,iparal)
!
DEALLOCATE(iparal)
!
!-------------------------------------------------------------------------------
#endif
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('SFX_OASIS_DEF_OL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE sfx_oasis_def_ol