read_slope_file.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!-----------------------------------------------------------------
!     #######################     
      SUBROUTINE read_slope_file(HPROGRAM,HFILE,HFORM,KNMC,PTANB,PSLOP,PDAREA,PLAMBDA)
!     #######################
!
!!****  *READ_SLOPE_FILE*  
!!
!!    PURPOSE
!!    -------
!     This routine aims at reading topographic files
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!    
!!    
!!
!!      
!!    REFERENCE
!!    ---------
!!
!!    
!!      
!!    AUTHOR
!!    ------
!!
!!      B. Vincendon    * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!
!!      Original   11/2006
!!                 03/2014 (B. Vincendon) add the possibility of reading topographic
!!                         files produced by a new chain (based of java+GRASS)
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modi_get_luout
USE modi_open_file
USE modi_close_file
!
USE modd_topd_par, ONLY : nunit
USE modd_topodyn, ONLY : npmax
USE modd_surf_par,  ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=*),  INTENT(IN)  :: hprogram    !
 CHARACTER(LEN=*),  INTENT(IN)  :: hfile       ! File to be read
 CHARACTER(LEN=*),  INTENT(IN)  :: hform       ! Format of the file to be read
INTEGER,           INTENT(IN)  :: knmc        ! Number of pixels in the catchment
REAL, DIMENSION(:),  INTENT(OUT)   :: ptanb    ! pixels topographic slope(tan(beta)
REAL, DIMENSION(:),  INTENT(OUT)   :: pslop   ! pixels topographic slope/length flow
REAL, DIMENSION(:),  INTENT(OUT)   :: pdarea  ! drainage area (aire drainee)
REAL, DIMENSION(:),  INTENT(OUT)   :: plambda ! pure topographic index
!
!*      0.2    declarations of local variables
!
!
INTEGER                   :: jj ! loop control 
INTEGER                   :: iwrk        ! work variable
INTEGER                   :: iluout      ! Unit of the files
!
REAL                      :: zwrk        ! work variable
REAL, DIMENSION(KNMC)     :: zdarea      ! drainage area (aire drainee)
REAL(KIND=JPRB) :: zhook_handle
!
 CHARACTER(LEN=100)    :: yheader    ! Header File to be read
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('READ_SLOPE_FILE',0,zhook_handle)
!
!*       0.2    preparing file openning
!               ----------------------
 CALL get_luout(hprogram,iluout)
!
 CALL open_file(hprogram,nunit,hfile,hform,haction='READ')
!
READ(nunit,*) yheader
!
IF (index(yheader,'pixel_REF')/=0) THEN !Slope file from new java+GRASS chain
 write(iluout,*) 'Slope file from new java + GRASS chain'
 DO jj=1,knmc
  READ(nunit,*,end=110) iwrk, ptanb(jj),plambda(jj) 
 ENDDO
 pslop(:)=plambda(:) !not used
 pdarea(:)=plambda(:) !not used
ELSE !slope file from old f77  chain
 write(*,*) 'Slope file from old f77 chain'
 DO jj=1,knmc
   READ(nunit,*,end=110) iwrk, ptanb(jj), pslop(jj), zwrk, pdarea(jj)
  plambda(jj) = log(pdarea(jj)/pslop(jj))
 ENDDO
ENDIF
110 CALL close_file(hprogram,nunit)
!
IF (lhook) CALL dr_hook('READ_SLOPE_FILE',1,zhook_handle)
!
END SUBROUTINE read_slope_file