read_seaflux_confn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_seaflux_conf_n (CHS, DGO, DGS, DGSI, O, S, &
                                      hprogram)
!     #############################################################
!
!!****  *READ_SEAFLUX_CONF* - routine to read the configuration for SEAFLUX
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*      
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!!      Modified    01/2006 : sea flux parameterization.
!!      Modified    09/2013 : S. Senesi : introduce 1D version of sea-ice model Gelato
!!      Modified    01/2015 : R. Séférian: introduce ocean surface albedo
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
!
!
!
!
USE modd_ch_seaflux_n, ONLY : ch_seaflux_t
USE modd_diag_ocean_n, ONLY : diag_ocean_t
USE modd_diag_seaflux_n, ONLY : diag_seaflux_t
USE modd_diag_seaice_n, ONLY : diag_seaice_t
USE modd_ocean_n, ONLY : ocean_t
USE modd_seaflux_n, ONLY : seaflux_t
!
USE mode_modeln_surfex_handler
!
USE mode_pos_surf
!
USE modi_test_nam_var_surf
USE modi_get_luout
USE modi_open_namelist
USE modi_close_namelist
!
USE modn_seaflux_n
!
USE modd_read_namelist, ONLY : lnam_read
USE modd_surf_par,   ONLY : xundef
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(ch_seaflux_t), INTENT(INOUT) :: chs
TYPE(diag_ocean_t), INTENT(INOUT) :: dgo
TYPE(diag_seaflux_t), INTENT(INOUT) :: dgs
TYPE(diag_seaice_t), INTENT(INOUT) :: dgsi
TYPE(ocean_t), INTENT(INOUT) :: o
TYPE(seaflux_t), INTENT(INOUT) :: s
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! program calling ISBA
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!
LOGICAL           :: gfound         ! Return code when searching namelist
INTEGER           :: iluout         ! logical unit of output file
INTEGER           :: inam           ! logical unit of namelist file
INTEGER           :: imi
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!* get output listing file logical unit
!
IF (lhook) CALL dr_hook('READ_SEAFLUX_CONF_N',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
imi=get_current_model_index_surfex()
!
IF (imi.NE.-1 .AND. lnam_read) THEN
 CALL init_nam_seafluxn(o, s)
 CALL init_nam_diag_surfn(dgs)
 CALL init_nam_ch_seafluxn(chs)
 CALL init_nam_diag_oceann(dgo)
 CALL init_nam_seaicen(dgsi, s)
ENDIF
!
IF (lnam_read) THEN
 !        
 !* open namelist file
 !
 CALL open_namelist(hprogram,inam)
 !
 !* reading of namelist
 !  -------------------
 !
 CALL posnam(inam,'NAM_SEAFLUXN',gfound,iluout)
 IF (gfound) READ(unit=inam,nml=nam_seafluxn)
 CALL posnam(inam,'NAM_DIAG_SURFN',gfound,iluout)
 IF (gfound) READ(unit=inam,nml=nam_diag_surfn)
 CALL posnam(inam,'NAM_CH_SEAFLUXN',gfound,iluout)
 IF (gfound) READ(unit=inam,nml=nam_ch_seafluxn)
 CALL posnam(inam,'NAM_DIAG_OCEANN',gfound,iluout)
 IF (gfound) READ(unit=inam,nml=nam_diag_oceann)
 !
 CALL posnam(inam,'NAM_SEAICEN',gfound,iluout)
 IF (gfound) READ(unit=inam,nml=nam_seaicen)

 !
 CALL test_nam_var_surf(iluout,'CSEA_FLUX',csea_flux,'DIRECT','ITERAT','ECUME ','ECUME6','COARE3')
 CALL test_nam_var_surf(iluout,'CSEA_ALB',csea_alb,'UNIF','TA96','MK10','RS14')
 CALL test_nam_var_surf(iluout,'CCH_DRY_DEP',cch_dry_dep,'      ','WES89 ','NONE  ')
 CALL test_nam_var_surf(iluout,'CINTERPOL_SST',cinterpol_sst,'LINEAR','UNIF  ','QUADRA','NONE  ')
 CALL test_nam_var_surf(iluout,'CINTERPOL_SSS',cinterpol_sss,'LINEAR','UNIF  ','QUADRA','NONE  ')
 CALL test_nam_var_surf(iluout,'CINTERPOL_SIC',cinterpol_sic,'LINEAR','UNIF  ','NONE  ')
 CALL test_nam_var_surf(iluout,'CINTERPOL_SIT',cinterpol_sit,'LINEAR','UNIF  ','NONE  ')
 !
 !
 !* close namelist file
 !
 CALL close_namelist(hprogram,inam)
 !
ENDIF
!
IF (imi.NE.-1) THEN
 CALL update_nam_seafluxn(o, s)
 CALL update_nam_diag_surfn(dgs)
 CALL update_nam_ch_seafluxn(chs)
 CALL update_nam_diag_oceann(dgo)
 CALL update_nam_seaicen(dgsi, s)
ENDIF
!
!-------------------------------------------------------------------------------
!
!* surface time-step forced by the atmosphere
!
xtstep = xundef
IF (lhook) CALL dr_hook('READ_SEAFLUX_CONF_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_seaflux_conf_n