read_nam_grid_ign.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE read_nam_grid_ign(HPROGRAM,KGRID_PAR,KL,PGRID_PAR)
!     ################################################################
!
!!****  *READ_NAM_GRID_IGN* - routine to read in namelist the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      E. Martin   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2007 
!!      07/2011     add maximum domain dimension for output (B. Decharme)
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_surf_par, ONLY : xundef
!
USE mode_pos_surf
!
USE modi_open_namelist
USE modi_close_namelist
USE modi_get_luout
USE modi_test_nam_var_surf
!
USE mode_gridtype_ign
USE modi_get_xyall_ign
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
 CHARACTER(LEN=6),           INTENT(IN)    :: hprogram   ! calling program
INTEGER,                    INTENT(INOUT) :: kgrid_par  ! size of PGRID_PAR
INTEGER,                    INTENT(OUT)   :: kl         ! number of points
REAL, DIMENSION(KGRID_PAR), INTENT(OUT)   :: pgrid_par  ! parameters defining this grid
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: iluout ! output listing logical unit
INTEGER :: ilunam ! namelist file  logical unit
INTEGER :: ilambert ! Lambert type

REAL, DIMENSION(:),   ALLOCATABLE :: zx       ! X conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: zy       ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: zdx      ! X grid mesh size
REAL, DIMENSION(:),   ALLOCATABLE :: zdy      ! Y grid mesh size
!
!*       0.3   Declarations of namelist
!              ------------------------
!
 CHARACTER(LEN=3) :: clambert  ! Lambert type
INTEGER :: npoints  ! number of points
REAL, DIMENSION(100000) :: xx  ! X coordinate of grid mesh center (in meters)
REAL, DIMENSION(100000) :: xy  ! Y coordinate of grid mesh center (in meters)
REAL, DIMENSION(100000) :: xdx ! X mesh size (in meters)
REAL, DIMENSION(100000) :: xdy ! Y mesh size (in meters)
!
REAL :: xx_llcorner ! X coordinate of left  side of the domain
REAL :: xy_llcorner ! Y coordinate of lower side of the domain
REAL :: xcellsize   ! size of the cell (equal in X and Y)
INTEGER :: ncols    ! number of columns
INTEGER :: nrows    ! number of rows
!
REAL, DIMENSION(:), ALLOCATABLE :: zxall  ! maximum domain X coordinate of grid mesh
REAL, DIMENSION(:), ALLOCATABLE :: zyall  ! maximum domain Y coordinate of grid mesh
INTEGER                         :: idimx  ! maximum domain length in X
INTEGER                         :: idimy  ! maximum domain length in Y
!
REAL, DIMENSION(:), POINTER :: zgrid_par
!
INTEGER :: jcols, jrows, iindex ! loop counters
LOGICAL :: gfound
REAL(KIND=JPRB) :: zhook_handle
!
namelist/nam_ign/clambert,npoints,xx,xy,xdx,xdy,      &
                 xx_llcorner, xy_llcorner, xcellsize, &
                 ncols, nrows
!
!------------------------------------------------------------------------------
!
!*       1.    opening of namelist
! 
IF (lhook) CALL dr_hook('READ_NAM_GRID_IGN',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL open_namelist(hprogram,ilunam)
!
xx_llcorner = xundef
xy_llcorner = xundef
xcellsize   = xundef
ncols = 0
nrows = 0
!
!---------------------------------------------------------------------------
!
!*       2.    Reading of projection parameters
!              --------------------------------
!
 CALL posnam(ilunam,'NAM_IGN',gfound,iluout)
IF (gfound) READ(unit=ilunam,nml=nam_ign)
!
!---------------------------------------------------------------------------
 CALL close_namelist(hprogram,ilunam)
!---------------------------------------------------------------------------
!
!*       3.    Initialisation for a regular grid
!              ---------------------------------
!
IF (xcellsize/=xundef) THEN
  !
  WRITE(iluout,*) 'Initialisation of IGN Coordinates for a regular grid'
  !      
  xdx(:) = xcellsize
  xdy(:) = xcellsize
  !
  IF ( xx_llcorner/=xundef .AND. xy_llcorner/=xundef &
            .AND. ncols>0 .AND. nrows>0 ) THEN
    !
    npoints = ncols * nrows
    !
    DO jrows=1,nrows
      DO jcols=1,ncols
        !
        iindex = jcols + (jrows-1) * ncols
        xx(iindex) = xx_llcorner + (jcols-0.5) * xcellsize
        xy(iindex) = xy_llcorner + (jrows-0.5) * xcellsize
        !
      END DO
    END DO
    !
  ENDIF
  !
END IF
!
!---------------------------------------------------------------------------
!
!*       3.    Number of points
!              ----------------
!
kl = npoints
!
!---------------------------------------------------------------------------
!
!*       3.    Array of X and Y coordinates
!              ----------------------------
!
!
ALLOCATE(zx(kl))
ALLOCATE(zy(kl))
zx(:) = xx(:kl)
zy(:) = xy(:kl)
!
!---------------------------------------------------------------------------
!
!*       4.    Array of X and Y increments
!              ---------------------------
!
ALLOCATE(zdx(kl))
ALLOCATE(zdy(kl))
zdx(:) = xdx(:kl)
zdy(:) = xdy(:kl)
!
!---------------------------------------------------------------------------
!
!*       5.    Lambert type
!              ------------
!
 CALL test_nam_var_surf(iluout,'CLAMBERT',clambert,'L1 ','L2 ','L3 ',&
                         'L4 ','L2E','L93' )  
!
SELECT CASE (clambert)
  CASE ('L1 ')
    ilambert=1
  CASE ('L2 ')
    ilambert=2
  CASE ('L3 ')
    ilambert=3
  CASE ('L4 ')
    ilambert=4
  CASE ('L2E')
    ilambert=5
  CASE ('L93')
    ilambert=6
END SELECT
!
!---------------------------------------------------------------------------
!
!*       7.    maximum domain lengths
!              ----------------------
!
ALLOCATE(zxall(kl*3))
ALLOCATE(zyall(kl*3))
 CALL get_xyall_ign(zx,zy,zdx,zdy,zxall,zyall,idimx,idimy)
!
!---------------------------------------------------------------------------
!
!*       8.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
 CALL put_gridtype_ign(zgrid_par,ilambert,zx,zy,zdx,zdy,        &
                      idimx,idimy,zxall(1:idimx),zyall(1:idimy))
!
!---------------------------------------------------------------------------
DEALLOCATE(zx)
DEALLOCATE(zy)
DEALLOCATE(zdx)
DEALLOCATE(zdy)
DEALLOCATE(zxall)
DEALLOCATE(zyall)
!---------------------------------------------------------------------------
!
!* 1st call : initializes dimension
!
IF (kgrid_par==0) THEN
  kgrid_par = SIZE(zgrid_par)
!
ELSE
!
!* 2nd call : initializes grid array
!
  pgrid_par(:) = 0.
  pgrid_par(:) = zgrid_par
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('READ_NAM_GRID_IGN',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE read_nam_grid_ign