read_nam_grid_conf_proj.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE read_nam_grid_conf_proj(HPROGRAM,KGRID_PAR,KL,PGRID_PAR)
!     ################################################################
!
!!****  *READ_NAM_GRID_CONF_PROJ* - routine to read in namelist the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!!      A.Alias    10/2010 - XLATC/XLONC added to save the XLATCEN/XLONCEN values for FA
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE mode_pos_surf
!
USE modi_open_namelist
USE modi_close_namelist
USE modi_get_luout
!
USE mode_gridtype_conf_proj
USE modd_grid_conf_proj, ONLY : xlatc, xlonc
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
 CHARACTER(LEN=6),           INTENT(IN)    :: hprogram   ! calling program
INTEGER,                    INTENT(INOUT) :: kgrid_par  ! size of PGRID_PAR
INTEGER,                    INTENT(OUT)   :: kl         ! number of points
REAL, DIMENSION(KGRID_PAR), INTENT(OUT)   :: pgrid_par  ! parameters defining this grid
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: iluout ! output listing logical unit
INTEGER :: ilunam ! namelist file  logical unit
INTEGER :: ji, jj ! loop counters
INTEGER :: jl     ! loop counter

REAL, DIMENSION(:),   ALLOCATABLE :: zx       ! X conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: zy       ! Y conformal coordinate of grid mesh
REAL, DIMENSION(:),   ALLOCATABLE :: zdx      ! X grid mesh size
REAL, DIMENSION(:),   ALLOCATABLE :: zdy      ! Y grid mesh size
REAL, DIMENSION(1)                :: zxor     ! X conformal coordinate of origine point
REAL, DIMENSION(1)                :: zyor     ! Y conformal coordinate of origin point
REAL, DIMENSION(1)                :: zlator   ! latitude of origine point
REAL, DIMENSION(1)                :: zlonor   ! longitude of origin point
!
!*       0.3   Declarations of namelist
!              ------------------------
!
REAL    :: xlat0    ! reference latitude
REAL    :: xlon0    ! reference longitude
REAL    :: xrpk     ! projection parameter 
!                   !   K=1 : stereographic north pole
!                   ! 0<K<1 : Lambert, north hemisphere
!                   !   K=0 : Mercator
!                   !-1<K<0 : Lambert, south hemisphere
!                   !   K=-1: stereographic south pole
REAL    :: xbeta    ! angle between grid and reference longitude
REAL    :: xlatcen  ! latitude  of center point
REAL    :: xloncen  ! longitude of center point
INTEGER :: nimax    ! number of points in I direction
INTEGER :: njmax    ! number of points in J direction
REAL    :: xdx      ! increment in X direction (in meters)
REAL    :: xdy      ! increment in Y direction (in meters)
!
REAL, DIMENSION(:), POINTER :: zgrid_par
!
LOGICAL :: gfound
REAL(KIND=JPRB) :: zhook_handle
!
namelist/nam_conf_proj/xlat0, xlon0, xrpk, xbeta
namelist/nam_conf_proj_grid/nimax,njmax,xlatcen,xloncen,xdx,xdy
!
!------------------------------------------------------------------------------
!
!*       1.    opening of namelist
! 
IF (lhook) CALL dr_hook('READ_NAM_GRID_CONF_PROJ',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL open_namelist(hprogram,ilunam)
!
!---------------------------------------------------------------------------
!
!*       2.    Reading of projection parameters
!              --------------------------------
!
 CALL posnam(ilunam,'NAM_CONF_PROJ',gfound,iluout)
IF (gfound) READ(unit=ilunam,nml=nam_conf_proj)
!
!---------------------------------------------------------------------------
!
!*       2.    Reading parameters of the grid
!              ------------------------------
!
 CALL posnam(ilunam,'NAM_CONF_PROJ_GRID',gfound,iluout)
IF (gfound) READ(unit=ilunam,nml=nam_conf_proj_grid)
!
!---------------------------------------------------------------------------
 CALL close_namelist(hprogram,ilunam)
!---------------------------------------------------------------------------
!
!*       3.    Number of points
!              ----------------
!
kl = nimax * njmax
!
!---------------------------------------------------------------------------
!
!*       3.    Array of X and Y coordinates
!              ----------------------------
!
!
ALLOCATE(zx(kl))
ALLOCATE(zy(kl))
DO jj=1,njmax
  DO ji=1,nimax
    jl = ji + (jj-1) * nimax
    zx(jl) = float(ji) * xdx
    zy(jl) = float(jj) * xdy
  END DO
END DO
!
!---------------------------------------------------------------------------
!
!*       4.    Array of X and Y increments
!              ---------------------------
!
ALLOCATE(zdx(kl))
ALLOCATE(zdy(kl))
zdx(:) = xdx
zdy(:) = xdy
!
!---------------------------------------------------------------------------
!
!*       5.    Latitude and longitude of point of coordinates 0,0
!              --------------------------------------------------
!
! Coordinates of origin point are here defined from center point, that
! is then used as substitute reference point.
! In all further computations, origin point will be of course be x=0, y=0
!
zxor = - float(nimax+1)/2.*xdx
zyor = - float(njmax+1)/2.*xdy
!
 CALL latlon_conf_proj(xlat0,xlon0,xrpk,xbeta,xlatcen,xloncen, &
                        zxor,zyor,zlator,zlonor                 )  
!
xlatc=xlatcen
xlonc=xloncen
!---------------------------------------------------------------------------
!
!*       8.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
 CALL put_gridtype_conf_proj(zgrid_par,xlat0,xlon0,xrpk,xbeta,    &
                              zlator(1),zlonor(1),nimax,njmax,     &
                              zx,zy,zdx,zdy                        )  
!
!---------------------------------------------------------------------------
DEALLOCATE(zx)
DEALLOCATE(zy)
DEALLOCATE(zdx)
DEALLOCATE(zdy)
!---------------------------------------------------------------------------
!
!* 1st call : initializes dimension
!
IF (kgrid_par==0) THEN
  kgrid_par = SIZE(zgrid_par)
!
ELSE
!
!* 2nd call : initializes grid array
!
  pgrid_par(:) = 0.
  pgrid_par(:) = zgrid_par
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('READ_NAM_GRID_CONF_PROJ',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE read_nam_grid_conf_proj