read_gridtype_gauss.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!################################################################
SUBROUTINE read_gridtype_gauss (&
                                hprogram,kgrid_par,klu,oread,ksize,pgrid_par,kresp,hdir)
!################################################################
!
!!****  *READ_GRIDTYPE_GAUSS* - routine to initialise the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modi_read_surf
USE modi_get_luout
!
USE mode_gridtype_gauss
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
!
 CHARACTER(LEN=6),       INTENT(IN)    :: hprogram   ! calling program
INTEGER,                INTENT(INOUT) :: kgrid_par  ! real size of PGRID_PAR
INTEGER,                INTENT(IN)    :: klu        ! number of points
LOGICAL,                INTENT(IN)    :: oread      ! flag to read the grid
INTEGER,                INTENT(IN)    :: ksize      ! estimated size of PGRID_PAR
REAL, DIMENSION(KSIZE), INTENT(OUT)   :: pgrid_par  ! parameters defining this grid
INTEGER,                INTENT(OUT)   :: kresp      ! error return code
 CHARACTER(LEN=1),       INTENT(IN)    :: hdir       ! reading directive
!                                                   ! 'A' : all field
!                                                   ! 'H' : field on this processor only
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: inlati  ! number of pseudo-latitudes
REAL    :: zlapo   ! latitude  of the rotated pole (deg)
REAL    :: zlopo   ! longitude of the rotated pole (deg)
REAL    :: zcodil  ! stretching factor (must be greater than or equal to 1)
INTEGER, DIMENSION(:), ALLOCATABLE :: inlopa ! number of pseudo-longitudes on each
                                             ! pseudo-latitude circle
REAL,    DIMENSION(KLU) :: zlat    ! latitudes
REAL,    DIMENSION(KLU) :: zlon    ! longitudes
REAL,    DIMENSION(KLU) :: zlat_xy ! pseudo-latitudes
REAL,    DIMENSION(KLU) :: zlon_xy ! pseudo-longitudes
REAL,    DIMENSION(KLU) :: zmesh_size ! Mesh size
!                                                                 _____ Sup
REAL,    DIMENSION(KLU) :: zlatsup     ! Grid corner Latitude    |     |
REAL,    DIMENSION(KLU) :: zlonsup     ! Grid corner Longitude   |     |
REAL,    DIMENSION(KLU) :: zlatinf     ! Grid corner Latitude    |_____|
REAL,    DIMENSION(KLU) :: zloninf     ! Grid corner Longitude  Inf
!
INTEGER                 :: iluout
!---------------------------------------------------------------------------
REAL, DIMENSION(:),   POINTER     :: zgrid_par=>null()
!$OMP THREADPRIVATE(ZGRID_PAR)
REAL(KIND=JPRB) :: zhook_handle
!---------------------------------------------------------------------------
!
!*       1.    Reading of projection parameters
!              --------------------------------
!
IF (lhook) CALL dr_hook('READ_GRIDTYPE_GAUSS',0,zhook_handle)
 CALL read_surf(&
                hprogram,'LAPO',zlapo, kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LOPO',zlopo,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'CODIL',zcodil,kresp,hdir=hdir)
!
!---------------------------------------------------------------------------
!
!*       2.    Reading parameters of the grid
!              ------------------------------
!
 CALL read_surf(&
                hprogram,'NLATI',inlati,kresp,hdir=hdir)
ALLOCATE(inlopa(inlati))
IF (hdir=='A') THEN
  CALL read_surf(&
                hprogram,'NLOPA',inlopa(:),kresp,hdir=hdir)
ELSE
  CALL read_surf(&
                hprogram,'NLOPA',inlopa(:),kresp,hdir='-')
ENDIF
 CALL read_surf(&
                hprogram,'LATGAUSS',zlat(:),kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LONGAUSS',zlon(:),kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LAT_G_XY',zlat_xy(:),kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LON_G_XY',zlon_xy(:),kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'MESHGAUSS',zmesh_size(:),kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LONINF',zloninf(:),kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LATINF',zlatinf(:),kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LONSUP',zlonsup(:),kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LATSUP',zlatsup(:),kresp,hdir=hdir)

!---------------------------------------------------------------------------
!
!*       4.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
 CALL put_gridtype_gauss(zgrid_par,inlati,zlapo,zlopo,zcodil,inlopa, &
                          klu,zlat,zlon,zlat_xy,zlon_xy,zmesh_size,  & 
                          zloninf,zlatinf,zlonsup,zlatsup            )  
!
DEALLOCATE(inlopa)
!---------------------------------------------------------------------------
IF (oread) THEN
  IF (SIZE(pgrid_par) /= SIZE(zgrid_par)) THEN
    CALL get_luout(hprogram,iluout)
    WRITE(iluout,*)'size of PGRID_PAR =', SIZE(pgrid_par)
    WRITE(iluout,*)'size of ZGRID_PAR =', SIZE(zgrid_par)
    CALL abor1_sfx('READ_GRIDTYPE_GAUSS: SIZE OF PGRID_PAR IS NOT CORRECT')
  END IF
  !
  pgrid_par = zgrid_par
ELSE
  kgrid_par = SIZE(zgrid_par)
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('READ_GRIDTYPE_GAUSS',1,zhook_handle)
!---------------------------------------------------------------------------
!
END SUBROUTINE read_gridtype_gauss