read_gridtype_cartesian.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ################################################################
      SUBROUTINE read_gridtype_cartesian (&
                                          hprogram,kgrid_par,klu,oread,ksize,pgrid_par,kresp,hdir)
!     ################################################################
!
!!****  *READ_GRIDTYPE_CARTESIAN* - routine to initialise the horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modi_read_surf
USE modi_get_luout
!
USE mode_gridtype_cartesian
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
!
 CHARACTER(LEN=6),       INTENT(IN)    :: hprogram   ! calling program
INTEGER,                INTENT(INOUT) :: kgrid_par  ! real size of PGRID_PAR
INTEGER,                INTENT(IN)    :: klu        ! number of points
LOGICAL,                INTENT(IN)    :: oread      ! flag to read the grid
INTEGER,                INTENT(IN)    :: ksize      ! estimated size of PGRID_PAR
REAL, DIMENSION(KSIZE), INTENT(OUT)   :: pgrid_par  ! parameters defining this grid
INTEGER,                INTENT(OUT)   :: kresp      ! error return code
 CHARACTER(LEN=1),       INTENT(OUT)   :: hdir       ! reading directive ('A','H')
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL                              :: zlat0    ! reference latitude
REAL                              :: zlon0    ! reference longitude
INTEGER                           :: iimax    ! number of points in I direction
INTEGER                           :: ijmax    ! number of points in J direction
REAL, DIMENSION(KLU)              :: zx       ! X conformal coordinate of grid mesh
REAL, DIMENSION(KLU)              :: zy       ! Y conformal coordinate of grid mesh
REAL, DIMENSION(KLU)              :: zdx      ! X grid mesh size
REAL, DIMENSION(KLU)              :: zdy      ! Y grid mesh size
!
INTEGER                           :: iluout
!---------------------------------------------------------------------------
REAL, DIMENSION(:),   POINTER     :: zgrid_par=>null()
!$OMP THREADPRIVATE(ZGRID_PAR)
REAL(KIND=JPRB) :: zhook_handle
!---------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('READ_GRIDTYPE_CARTESIAN',0,zhook_handle)
 CALL read_surf(&
                hprogram,'LAT0',zlat0,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'LON0',zlon0,kresp,hdir=hdir)
!
 CALL read_surf(&
                hprogram,'IMAX ',iimax, kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'JMAX ',ijmax, kresp,hdir=hdir)
!
 CALL read_surf(&
                hprogram,'XX',zx,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'YY',zy,kresp,hdir=hdir)
!
 CALL read_surf(&
                hprogram,'DX',zdx,kresp,hdir=hdir)
 CALL read_surf(&
                hprogram,'DY',zdy,kresp,hdir=hdir)
!
!---------------------------------------------------------------------------
!
!*       4.    All this information stored into pointer PGRID_PAR
!              --------------------------------------------------
!
 CALL put_gridtype_cartesian(zgrid_par,zlat0,zlon0,           &
                              iimax,ijmax,                     &
                              zx,zy,zdx,zdy                    )  
!
!---------------------------------------------------------------------------
IF (oread) THEN
  IF (SIZE(pgrid_par) /= SIZE(zgrid_par)) THEN
    CALL get_luout(hprogram,iluout)
    WRITE(iluout,*)'size of PGRID_PAR =', SIZE(pgrid_par)
    WRITE(iluout,*)'size of ZGRID_PAR =', SIZE(zgrid_par)
    CALL abor1_sfx('READ_GRIDTYPE_CARTESIAN: SIZE OF PGRID_PAR IS NOT CORRECT')
  END IF
  !
  pgrid_par = zgrid_par
ELSE
  kgrid_par = SIZE(zgrid_par)
END IF
!
DEALLOCATE(zgrid_par)
IF (lhook) CALL dr_hook('READ_GRIDTYPE_CARTESIAN',1,zhook_handle)
!---------------------------------------------------------------------------
!
END SUBROUTINE read_gridtype_cartesian