prep_watflux.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_watflux (DTCO, UG, U, WM, &
                         hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!     #################################################################################
!
!!****  *PREP_WATFLUX* - prepares WATFLUX fields
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette   06/2009 PREP_WATFLUX_SBL has no more argument
!!------------------------------------------------------------------
!
!
!
USE modd_surfex_n, ONLY : watflux_model_t
!
!
USE modd_data_cover_n, ONLY : data_cover_t
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modi_prep_hor_watflux_field
USE modi_prep_ver_watflux
USE modi_prep_output_grid
USE modi_get_luout
USE modi_prep_watflux_sbl
!
USE modd_read_namelist,  ONLY : lnam_read
USE modn_prep_watflux
USE modd_prep,           ONLY : xzs_ls
USE modd_surf_atm,       ONLY : lvertshift

!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_clean_prep_output_grid
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(watflux_model_t), INTENT(INOUT) :: wm
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
!
!*      0.2    declarations of local variables
!
INTEGER :: jmth, inmth
!
INTEGER :: iluout
LOGICAL :: gfound         ! Return code when searching namelist
INTEGER :: ilunam         ! logical unit of namelist file
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!*      1.     Default of configuration
!
!
IF (lhook) CALL dr_hook('PREP_WATFLUX',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL prep_output_grid(ug, u, &
                       iluout,wm%WG%CGRID,wm%WG%XGRID_PAR,wm%WG%XLAT,wm%WG%XLON)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations
!
!
!*      2.0    Large scale orography
!
 CALL prep_hor_watflux_field(dtco, u, &
                             wm%WG, wm%W, &
                             hprogram,'ZS     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!
!*      2.1    Temperature
!
 CALL prep_hor_watflux_field(dtco, u, &
                             wm%WG, wm%W, &
                             hprogram,'TSWATER',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!
!*      2.2    Roughness
!
ALLOCATE(wm%W%XZ0(SIZE(wm%W%XTS)))
wm%W%XZ0 = 0.001
!
!-------------------------------------------------------------------------------------
 CALL clean_prep_output_grid
!-------------------------------------------------------------------------------------
!
!*      3.     Vertical interpolations of all variables
!
IF(lvertshift)THEN
  CALL prep_ver_watflux(wm%W)
ENDIF
!
DEALLOCATE(xzs_ls)
!-------------------------------------------------------------------------------------
!
!*      4.     Preparation of optional interpolation of monthly ts water
!
wm%W%LINTERPOL_TS=.false.
IF(wm%W%CINTERPOL_TS/='NONE  ')THEN
  wm%W%LINTERPOL_TS=.true.
ENDIF
!
IF(wm%W%LINTERPOL_TS)THEN
!
! Precedent, Current, Next, and Second-next Monthly TS water
  inmth=4
!
  ALLOCATE(wm%W%XTS_MTH(SIZE(wm%W%XTS),inmth))
  DO jmth=1,inmth
     wm%W%XTS_MTH(:,jmth)=wm%W%XTS(:)
  ENDDO
!
ENDIF
!
!-------------------------------------------------------------------------------------
!
!*      5.     Preparation of SBL air variables
!
wm%W%LSBL = lwat_sbl
IF (wm%W%LSBL) CALL prep_watflux_sbl(wm%WG, wm%WSB)
IF (lhook) CALL dr_hook('PREP_WATFLUX',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_watflux