prep_snow_grib.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_snow_grib(HPROGRAM,HSURF,HFILE,KLUOUT,KLAYER,PFIELD)
!     #################################################################################
!
!!****  *PREP_SNOW_GRIB* - prepares snow field from operational GRIB
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original     01/2004
!!      C. Ardilouze 06/2013 read snow albedo and density (for Erai-land)
!!------------------------------------------------------------------
!
!
USE mode_read_grib
USE mode_snow3l
!
USE modd_type_date_surf
!
USE modi_prep_grib_grid
USE modi_snow_t_wliq_to_heat
!
USE modd_prep,           ONLY : cingrid_type, cinterp_type
USE modd_prep_snow,      ONLY : ngrid_level, xgrid_snow
USE modd_data_cover_par, ONLY : nvegtype
USE modd_surf_par,       ONLY : xundef
USE modd_grid_grib,      ONLY : cgrib_file, nni
USE modd_snow_par,       ONLY : xansmin, xansmax, xrhosmax
USE modd_csts,           ONLY : xtt
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=6),   INTENT(IN)    :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=10),   INTENT(IN)   :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)    :: hfile     ! name of file
INTEGER,            INTENT(IN)    :: kluout    ! logical unit of output listing
INTEGER,            INTENT(IN)    :: klayer    ! Number of layer of output snow scheme
REAL,DIMENSION(:,:,:), POINTER    :: pfield    ! field to interpolate horizontally
!
!*      0.2    declarations of local variables
!
TYPE (date_time)                :: tztime_grib    ! current date and time
 CHARACTER(LEN=6)                :: yinmodel       ! model from which GRIB file originates
REAL, DIMENSION(:)  , POINTER   :: zmask => null()          ! Land mask
REAL, DIMENSION(:),   POINTER   :: zfield1d => null()       ! field read
REAL, DIMENSION(:),   POINTER   :: zheat => null()          ! heat in snow
REAL, DIMENSION(:),   POINTER   :: zrho => null()          ! density of snow
INTEGER                         :: jvegtype       ! loop counter on vegtypes
INTEGER                         :: jlayer         ! loop on snow fine grid
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.     Reading of grid
!              ---------------
!
IF (lhook) CALL dr_hook('PREP_SNOW_GRIB',0,zhook_handle)
!
IF (trim(hfile).NE.cgrib_file) cgrib_file=""
!
 CALL prep_grib_grid(hfile,kluout,yinmodel,cingrid_type,tztime_grib)
!
 CALL read_grib_land_mask(hfile,kluout,yinmodel,zmask)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading of the physical field for urban areas
!              ---------------------------------------------
!
IF (hsurf(7:8)=='RO') THEN
  ! 
  SELECT CASE(hsurf(1:3))
    CASE('DEP')
      ALLOCATE(pfield(nni,klayer,1))
    CASE('ALB','WWW')
      ALLOCATE(pfield(nni,1,1))
    CASE('HEA','RHO')
      ALLOCATE(pfield(nni,ngrid_level,1))
  END SELECT
  !
  pfield(:,:,:) = 0.
!
!-------------------------------------------------------------------------------------
!
!*      3.     Reading of the physical field for vegetated areas
!              -------------------------------------------------
!
ELSE
!
  SELECT CASE(hsurf(1:3))
!
!*      3.1    Total snow content (kg/m2)
!
  CASE('WWW')
     CALL read_grib_snow_veg_and_depth(hfile,kluout,yinmodel,zmask,psnv=zfield1d)
     !
     ALLOCATE(pfield(SIZE(zfield1d),1,nvegtype))
     DO jvegtype=1,nvegtype
       pfield(:,1,jvegtype)=zfield1d(:)
     END DO
     DEALLOCATE(zfield1d)
!
!
!*      3.2    Total snow depth (m)
!
  CASE('DEP')
     CALL read_grib_snow_veg_and_depth(hfile,kluout,yinmodel,zmask,psnvd=zfield1d)
     !
     ALLOCATE(pfield(SIZE(zfield1d),klayer,nvegtype))
     DO jvegtype=1,nvegtype
        CALL snow3lgrid(pfield(:,:,jvegtype),zfield1d(:))
     END DO
     DEALLOCATE(zfield1d)
!
!
!*      3.3    Profile of heat in the snow
!
  CASE('HEA')
     !* read temperature
     CALL read_grib_ts(hfile,kluout,yinmodel,zmask,zfield1d)
     WHERE (zfield1d/=xundef) zfield1d(:) = min(zfield1d,xtt)
     !* assumes no liquid water in the snow
     ALLOCATE(zheat(SIZE(zfield1d)))
     CALL read_grib_snow_den(hfile,kluout,yinmodel,zmask,zrho) 
     WHERE(zfield1d(:)==xundef)zrho(:)=xundef
     !
     CALL snow_t_wliq_to_heat(zheat,zrho,zfield1d)
     !
     ALLOCATE(pfield(SIZE(zfield1d),ngrid_level,nvegtype))
     DO jvegtype=1,nvegtype
       DO jlayer=1,ngrid_level
         pfield(:,jlayer,jvegtype)=zheat(:)
       END DO
     END DO
     DEALLOCATE(zfield1d)
     DEALLOCATE(zheat   )
     DEALLOCATE(zrho    )
!
!*      3.4    Albedo
!
  CASE('ALB')    
    CALL read_grib_snow_alb(hfile,kluout,yinmodel,zmask,zfield1d)      
    ALLOCATE(pfield(SIZE(zfield1d),1,nvegtype))
    DO jvegtype=1,nvegtype
      pfield(:,1,jvegtype)=zfield1d(:)
    END DO
    DEALLOCATE(zfield1d)
!
!*      3.5    Density
!
  CASE('RHO')    
    CALL read_grib_snow_den(hfile,kluout,yinmodel,zmask,zfield1d)      
    ALLOCATE(pfield(SIZE(zfield1d),1,nvegtype))
    DO jvegtype=1,nvegtype
      pfield(:,1,jvegtype)=zfield1d(:)
    END DO
    DEALLOCATE(zfield1d)
!
!*      3.6    SG1: initial grain is partially rounded
!
  CASE('SG1')
    ALLOCATE(pfield(nni,ngrid_level,nvegtype))
    pfield = -20
!
!*      3.7    SG2: initial grain is partially rounded
!
  CASE('SG2')
    ALLOCATE(pfield(nni,ngrid_level,nvegtype))
    pfield = 80
!
!*      3.8    AGE: snow is 3-days old
!
  CASE('AGE')
    ALLOCATE(pfield(nni,ngrid_level,nvegtype))
    pfield = 3
!
!*      3.9    HIS: 0 by default
!
  CASE('HIS')
    ALLOCATE(pfield(nni,ngrid_level,nvegtype))
    pfield = 0
!
  END SELECT
!
END IF
!
DEALLOCATE(zmask)
!
!-------------------------------------------------------------------------------------
!
!*      4.     Interpolation method
!              --------------------
!
 cinterp_type='HORIBL'
!
IF (lhook) CALL dr_hook('PREP_SNOW_GRIB',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
END SUBROUTINE prep_snow_grib