prep_snow_buffer.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_snow_buffer (IG, U, &
                             hprogram,hsurf,kluout,klayer,pfield)
!     #################################################################################
!
!!****  *PREP_SNOW_BUFFER* - prepares snow field from operational BUFFER
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    03/2005
!!------------------------------------------------------------------
!
!
USE modd_isba_grid_n, ONLY : isba_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE mode_snow3l
!
USE mode_read_buffer
!
USE modd_type_date_surf
!
USE modi_prep_buffer_grid
USE modi_snow_t_wliq_to_heat
#ifdef SFX_ARO
USE modi_oi_hor_extrapol_surf
#endif
USE modi_pack_same_rank
USE modi_unpack_same_rank
USE modi_abor1_sfx
!
USE modd_prep,           ONLY : cinterp_type
USE modd_prep_isba,      ONLY : lextrap_sn
USE modd_prep_snow,      ONLY : xgrid_snow
USE modd_data_cover_par, ONLY : nvegtype
USE modd_surf_par,       ONLY : xundef
USE modd_grid_buffer,    ONLY : nni
USE modd_snow_par,       ONLY : xansmin, xansmax, xrhosmax
USE modd_csts,           ONLY : xtt
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(isba_grid_t), INTENT(INOUT) :: ig
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),   INTENT(IN)   :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=10),  INTENT(IN)   :: hsurf     ! type of field
INTEGER,            INTENT(IN)   :: kluout    ! logical unit of output listing
INTEGER,            INTENT(IN)  :: klayer        ! Number of layer of output snow scheme
REAL,DIMENSION(:,:,:), POINTER   :: pfield    ! field to interpolate horizontally
!
!*      0.2    declarations of local variables
!
TYPE (date_time)                 :: tztime_buffer    ! current date and time
 CHARACTER(LEN=6)                 :: yinmodel       ! model from which GRIB file originates
REAL, DIMENSION(:),   POINTER    :: zfield1d       ! field read
REAL, DIMENSION(:),   POINTER    :: zheat          ! heat in snow
REAL, DIMENSION(:),   POINTER    :: zrho           ! density of snow
REAL,DIMENSION(:),POINTER        :: zlsm           ! Land/sea mask
INTEGER                          :: jvegtype       ! loop counter on vegtypes
INTEGER                          :: jlayer         ! loop on snow fine grid
REAL,ALLOCATABLE,DIMENSION(:)    :: zfield_ep
REAL,ALLOCATABLE,DIMENSION(:)    :: zfield_ep_in
REAL,ALLOCATABLE,DIMENSION(:)    :: zlsm_nature
LOGICAL,ALLOCATABLE,DIMENSION(:) :: ointerp
INTEGER                          :: ii
INTEGER,PARAMETER                :: idim2=10
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.     Reading of grid
!              ---------------
!
IF (lhook) CALL dr_hook('PREP_SNOW_BUFFER',0,zhook_handle)
 CALL prep_buffer_grid(kluout,yinmodel,tztime_buffer)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading of the physical field for urban areas
!              ---------------------------------------------
!
IF (hsurf(7:8)=='RO') THEN
  ! 
  SELECT CASE(hsurf(1:3))
    CASE('DEP')
      ALLOCATE(pfield(nni,klayer,1))
    CASE('ALB','WWW')
      ALLOCATE(pfield(nni,1,1))
    CASE('HEA','RHO')
      ALLOCATE(pfield(nni,SIZE(xgrid_snow),1))
  END SELECT
  !
  pfield(:,:,:) = 0.
!
!-------------------------------------------------------------------------------------
!
!*      3.     Reading of the physical field for vegetated areas
!              -------------------------------------------------
!
ELSE
!
  SELECT CASE(hsurf(1:3))
!
!*      3.1    Total snow content (kg/m2)
!
  CASE('WWW')
     CALL read_buffer_snow_veg(kluout,yinmodel,zfield1d)
     IF ( lextrap_sn ) THEN
       IF ( SIZE(u%NR_NATURE) /= u%NSIZE_NATURE ) THEN
         CALL abor1_sfx('ABORT: PREP_ISBA_BUFFER - DIFFERENT SIZES')
       ELSE
         ! Allocate working arrays
         ALLOCATE(zfield_ep(u%NSIZE_NATURE))
         ALLOCATE(zfield_ep_in(u%NSIZE_NATURE))
         ALLOCATE(ointerp(u%NSIZE_NATURE))
         ALLOCATE(zlsm_nature(u%NSIZE_NATURE))

         ! Read LSM
         CALL read_buffer_land_mask(kluout,yinmodel,zlsm)

         ! Pack nature points to reduce dimension to nsize_nature
         CALL pack_same_rank(u%NR_NATURE,zlsm,zlsm_nature)

         ! Do extrapolation
         WRITE(kluout,*) 'Extrapolating WWW from nearest land point in points where LSM < 0.5.'

         ! Pack nature points to reduce dimension
         CALL pack_same_rank(u%NR_NATURE,zfield1d(:),zfield_ep(:))

         ! Set values to be extrapolated
         ointerp=.false.
         DO ii=1,u%NSIZE_NATURE
           IF ( zlsm_nature(ii) < 0.5 ) THEN
             ointerp(ii)  = .true.
             zfield_ep(ii) = xundef
           ENDIF
         ENDDO

         zfield_ep_in(:) = zfield_ep
#ifdef SFX_ARO
         CALL oi_hor_extrapol_surf(u%NSIZE_NATURE,ig%XLAT,ig%XLON,zfield_ep_in(:),ig%XLAT,ig%XLON,zfield_ep(:),ointerp,ndim2=idim2)
#endif

         ! Unpack to full rank
         CALL unpack_same_rank(u%NR_NATURE,zfield_ep(:),zfield1d(:))
         DEALLOCATE(zfield_ep)
         DEALLOCATE(zfield_ep_in)
         DEALLOCATE(zlsm_nature)
         DEALLOCATE(ointerp)
       ENDIF
     ENDIF

     !
     ALLOCATE(pfield(nni,1,nvegtype))
     DO jvegtype=1,nvegtype
       pfield(:,1,jvegtype)=zfield1d(:)
     END DO
     DEALLOCATE(zfield1d)
!
!
!*      3.2    Total snow depth (m) to snow layers ticknesses (m)
!
  CASE('DEP')
     CALL read_buffer_snow_veg_depth(kluout,yinmodel,zfield1d)
     IF ( lextrap_sn ) THEN
       IF ( SIZE(u%NR_NATURE) /= u%NSIZE_NATURE ) THEN
         CALL abor1_sfx('ABORT: PREP_ISBA_BUFFER - DIFFERENT SIZES')
       ELSE
         ! Allocate working arrays
         ALLOCATE(zfield_ep(u%NSIZE_NATURE))
         ALLOCATE(zfield_ep_in(u%NSIZE_NATURE))
         ALLOCATE(ointerp(u%NSIZE_NATURE))
         ALLOCATE(zlsm_nature(u%NSIZE_NATURE))

         ! Read LSM
         CALL read_buffer_land_mask(kluout,yinmodel,zlsm)

         ! Pack nature points to reduce dimension to nsize_nature
         CALL pack_same_rank(u%NR_NATURE,zlsm,zlsm_nature)

         ! Do extrapolation
         WRITE(kluout,*) 'Extrapolating DEP from nearest land point in points where LSM < 0.5.'

         ! Pack nature points to reduce dimension
         CALL pack_same_rank(u%NR_NATURE,zfield1d(:),zfield_ep(:))
         ! Set values to be extrapolated
         ointerp=.false.
         DO ii=1,u%NSIZE_NATURE
           IF ( zlsm_nature(ii) < 0.5 ) THEN
             ointerp(ii)  = .true.
             zfield_ep(ii) = xundef
           ENDIF
         ENDDO

         zfield_ep_in(:) = zfield_ep
#ifdef SFX_ARO
         CALL oi_hor_extrapol_surf(u%NSIZE_NATURE,ig%XLAT,ig%XLON,zfield_ep_in(:),ig%XLAT,ig%XLON,zfield_ep(:),ointerp,ndim2=idim2)
#endif
       
         ! Unpack to full rank
         CALL unpack_same_rank(u%NR_NATURE,zfield_ep(:),zfield1d(:))
         DEALLOCATE(zfield_ep)
         DEALLOCATE(zfield_ep_in)
         DEALLOCATE(zlsm_nature)
         DEALLOCATE(ointerp)
       ENDIF
     ENDIF

     !
     ALLOCATE(pfield(nni,klayer,nvegtype))
     DO jvegtype=1,nvegtype
        CALL snow3lgrid(pfield(:,:,jvegtype),zfield1d(:))
     END DO
     DEALLOCATE(zfield1d)
!
!
!*      3.3    Profile of heat in the snow
!
  CASE('HEA')
     !* read temperature
     CALL read_buffer_ts(kluout,yinmodel,zfield1d)
     WHERE (zfield1d/=xundef) zfield1d(:) = min(zfield1d,xtt)
     !* assumes no liquid water in the snow
     ALLOCATE(zheat(SIZE(zfield1d)))
     ALLOCATE(zrho(SIZE(zfield1d)))
     zrho(:) = xrhosmax
     !
     CALL snow_t_wliq_to_heat(zheat,zrho,zfield1d)
     !
     ALLOCATE(pfield(nni,SIZE(xgrid_snow),nvegtype))
     DO jvegtype=1,nvegtype
       DO jlayer=1,SIZE(xgrid_snow)
         pfield(:,jlayer,jvegtype)=zheat(:)
       END DO
     END DO
     DEALLOCATE(zfield1d)
     DEALLOCATE(zheat   )
     DEALLOCATE(zrho    )
!
!*      3.4    Albedo
!
  CASE('ALB')    
    ALLOCATE(pfield(nni,1,nvegtype))
    pfield = 0.5 * ( xansmin + xansmax )
!
!*      3.5    Density
!
  CASE('RHO')    
    ALLOCATE(pfield(nni,SIZE(xgrid_snow),nvegtype))
    pfield = xrhosmax

  END SELECT
  !
END IF
!
!-------------------------------------------------------------------------------------
!
!*      4.     Interpolation method
!              --------------------
!
 cinterp_type='BUFFER'
IF (lhook) CALL dr_hook('PREP_SNOW_BUFFER',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
END SUBROUTINE prep_snow_buffer