prep_hor_flake_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_hor_flake_field (DTCO, UG, U, USS, &
                                  fg, f, &
                                 hprogram,hsurf,hatmfile,hatmfiletype,&
                                hpgdfile,hpgdfiletype,onovalue)
!     #################################################################################
!
!!****  *PREP_HOR_FLAKE_FIELD* - Reads, interpolates and prepares a water field
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      P. Le Moigne 10/2005, Phasage Arome
!!      E. Kourzeneva 09/2010, Make possible to interpolate 
!!                             only lake surface temperature, 
!!                             but not profiles
!!------------------------------------------------------------------
!
!
!
!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_flake_grid_n, ONLY : flake_grid_t
USE modd_flake_n, ONLY : flake_t
!
USE modd_surf_par,     ONLY : xundef
USE modd_prep,         ONLY : cingrid_type, cinterp_type, xzs_ls, xlat_out, xlon_out, &
                               xx_out, xy_out, cmask
!
!
USE modd_csts,       ONLY : xtt
USE modd_prep_flake, ONLY : lclim_lake
!
USE modi_read_prep_flake_conf
USE modi_prep_flake_grib
USE modi_prep_flake_ascllv
USE modi_prep_flake_unif
USE modi_prep_flake_buffer
USE modi_hor_interpol
USE modi_get_luout
USE modi_prep_flake_extern
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
TYPE(flake_grid_t), INTENT(INOUT) :: fg
TYPE(flake_t), INTENT(INOUT) :: f
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
LOGICAL, OPTIONAL, INTENT(OUT) :: onovalue  ! flag for the not given value
!
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=6)              :: yfiletype ! type of input file
 CHARACTER(LEN=28)             :: yfile     ! name of file
 CHARACTER(LEN=6)              :: yfilepgdtype ! type of input file
 CHARACTER(LEN=28)             :: yfilepgd     ! name of file
REAL, POINTER, DIMENSION(:,:) :: zfieldin  ! field to interpolate horizontally
REAL, ALLOCATABLE, DIMENSION(:,:) :: zfieldout ! field interpolated   horizontally
INTEGER                       :: iluout    ! output listing logical unit
!
LOGICAL                       :: gunif     ! flag for prescribed uniform field
LOGICAL                       :: gdefault  ! flag for prescribed default field
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!
!*      1.     Reading of input file name and type
!
IF (lhook) CALL dr_hook('PREP_HOR_FLAKE_FIELD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL read_prep_flake_conf(hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,&
                          hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,iluout,gunif)
!
 cmask = 'WATER'
!
gdefault = (yfiletype=='      ' .OR. (hsurf(1:2)/='ZS' .AND. hsurf(1:2)/='TS' &
                .AND. SIZE(fg%XLAT).NE.1)) .AND. .NOT.gunif
IF (present(onovalue)) onovalue = gdefault
!
IF (.NOT. gdefault) THEN
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading of input  configuration (Grid and interpolation type)
!
  IF (gunif) THEN
    CALL prep_flake_unif(iluout,hsurf,zfieldin)
  ELSE IF (yfiletype=='ASCLLV') THEN
    CALL prep_flake_ascllv(dtco, ug, u, uss, &
                           hprogram,hsurf,iluout,zfieldin)
  ELSE IF (yfiletype=='GRIB  ') THEN
    CALL prep_flake_grib(hprogram,hsurf,yfile,iluout,zfieldin)
  ELSE IF (yfiletype=='MESONH' .OR. yfiletype=='ASCII ' .OR. yfiletype=='LFI   '.OR. yfiletype=='FA    ') THEN
    CALL prep_flake_extern(&
                           hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,iluout,zfieldin)
  ELSE IF (yfiletype=='BUFFER') THEN
    CALL prep_flake_buffer(hprogram,hsurf,iluout,zfieldin)
  ELSE
    CALL abor1_sfx('PREP_HOR_FLAKE_FIELD: data file type not supported : '//yfiletype)
  END IF
!
!
!*      4.     Horizontal interpolation
!
  !ALLOCATE(ZFIELDOUT(SIZE(XLAT),SIZE(ZFIELDIN,2)))
  ALLOCATE(zfieldout(SIZE(fg%XLAT),1))
!
!Impossible to interpolate lake profiles, only the lake surface temperature! 
!But in uniform case and 1 point case
  IF(gunif .OR. SIZE(fg%XLAT).EQ.1) THEN
    CALL hor_interpol(dtco, u, &
                      iluout,zfieldin,zfieldout)
  ELSE IF(hsurf(1:2)=='ZS' .OR. hsurf(1:2)=='TS') THEN
    WRITE(iluout,*) "WARNING! Impossible to interpolate lake profiles in horisontal!"
    WRITE(iluout,*) "So, interoplate only surface temperature and start from lakes mixed down to the bottom"
    CALL hor_interpol(dtco, u, &
                      iluout,zfieldin,zfieldout)
  END IF
!
!*      5.     Return to historical variable
!
  SELECT CASE (hsurf)
   CASE('ZS     ') 
    ALLOCATE(xzs_ls(SIZE(zfieldout,1)))
    xzs_ls(:) = zfieldout(:,1)
   CASE('TS     ')
    ALLOCATE(f%XTS(SIZE(zfieldout,1)))
    f%XTS(:) = zfieldout(:,1)
   CASE('T_SNOW ')
    ALLOCATE(f%XT_SNOW(SIZE(zfieldout,1)))
    f%XT_SNOW(:) = zfieldout(:,1)
   CASE('T_ICE  ')
    ALLOCATE(f%XT_ICE(SIZE(zfieldout,1)))
    f%XT_ICE(:) = zfieldout(:,1)
   CASE('T_WML  ')
    ALLOCATE(f%XT_WML(SIZE(zfieldout,1)))
    f%XT_WML(:) = zfieldout(:,1)
   CASE('T_BOT  ')
    ALLOCATE(f%XT_BOT(SIZE(zfieldout,1)))
    f%XT_BOT(:) = zfieldout(:,1)
   CASE('T_B1   ')
    ALLOCATE(f%XT_B1(SIZE(zfieldout,1)))
    f%XT_B1(:) = zfieldout(:,1)
   CASE('CT     ')
    ALLOCATE(f%XCT(SIZE(zfieldout,1)))
    f%XCT(:) = zfieldout(:,1)
   CASE('H_SNOW ')
    ALLOCATE(f%XH_SNOW(SIZE(zfieldout,1)))
    f%XH_SNOW(:) = zfieldout(:,1)
   CASE('H_ICE  ')
    ALLOCATE(f%XH_ICE(SIZE(zfieldout,1)))
    f%XH_ICE(:) = zfieldout(:,1)
   CASE('H_ML   ')
    ALLOCATE(f%XH_ML(SIZE(zfieldout,1)))
    f%XH_ML(:) = zfieldout(:,1)
   CASE('H_B1   ')
    ALLOCATE(f%XH_B1(SIZE(zfieldout,1)))
    f%XH_B1(:) = zfieldout(:,1)
  END SELECT
!*      6.     Deallocations
!
  IF (all(zfieldout==xundef)) gdefault = .true.
!
  DEALLOCATE(zfieldin )
  DEALLOCATE(zfieldout)
!
END IF

!
IF (gdefault) THEN
!
!*      7.    Initial values of FLAKE variables are computed from TS
!             when uniform values are not prescribed 
  IF (hsurf(1:2)/='ZS') WRITE(iluout,*) 'NO FILE FOR FIELD ',hsurf, &
                                        ': UNIFORM DEFAULT FIELD IS PRESCRIBED'
  
END IF
!
IF (lhook) CALL dr_hook('PREP_HOR_FLAKE_FIELD',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_hor_flake_field