prep_grid_gauss.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE prep_grid_gauss (&
                                  hfiletype,hinterp_type,kni)
!     ##########################################################################
!
!!****  *PREP_GRID_GAUSS* - reads EXTERNALIZED Surface grid.
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!
!!      V. Masson
!!
!!    MODIFICATIONS
!!    -------------
!!      Original   06/2003
!!      M. Jidane    Nov 2013 : correct allocation of NINLO and reading of INLOPA
!!      F. Taillefer Dec 2013 : debug estimation of XILO2
!-------------------------------------------------------------------------------
!
!*      0. DECLARATIONS
!          ------------
!
!
!
!
USE modi_read_surf
!
USE modd_grid_gauss, ONLY : xila1, xilo1, xila2, xilo2, ninla, ninlo, nilen, lrotpole, xcoef, xlap, xlop
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!* 0.1. Declaration of arguments
!       ------------------------
!
!
!
 CHARACTER(LEN=6),  INTENT(IN)    :: hfiletype    ! file type
 CHARACTER(LEN=6),  INTENT(OUT)   :: hinterp_type ! Grid type
INTEGER,           INTENT(OUT)   :: kni          ! number of points
!
!* 0.2 Declaration of local variables
!      ------------------------------
!
 CHARACTER(LEN=12) :: yrecfm    ! Name of the article to be read
INTEGER           :: iresp
!
!
INTEGER           :: jl        ! loop counter
REAL, DIMENSION(:), ALLOCATABLE :: zw ! work array
!
INTEGER :: inlati  ! number of pseudo-latitudes
INTEGER :: inlati2 ! number of half pseudo-latitudes
REAL    :: zlapo   ! latitude of the rotated pole  (deg)
REAL    :: zlopo   ! longitude of the rotated pole (deg)
REAL    :: zcodil  ! stretching factor (must be greater than or equal to 1)
INTEGER, DIMENSION(:), ALLOCATABLE :: inlopa ! number of pseudo-longitudes on each
                                             ! pseudo-latitude circle
REAL(KIND=JPRB) :: zhook_handle
!
!-----------------------------------------------------------------------
IF (lhook) CALL dr_hook('PREP_GRID_GAUSS',0,zhook_handle)
!-----------------------------------------------------------------------
!
!*   1 Projection
!      ----------
!
yrecfm = 'LAPO'
 CALL read_surf(&
                hfiletype,yrecfm,zlapo,iresp)
yrecfm = 'LOPO'
 CALL read_surf(&
                hfiletype,yrecfm,zlopo,iresp)
yrecfm = 'CODIL'
 CALL read_surf(&
                hfiletype,yrecfm,zcodil,iresp)
!
!-----------------------------------------------------------------------
!
!*   2 Grid
!      ----
!
yrecfm = 'NLATI'
 CALL read_surf(&
                hfiletype,yrecfm,inlati,iresp)
!
IF (ALLOCATED(inlopa)) DEALLOCATE(inlopa)
ALLOCATE(inlopa(inlati))
IF (ALLOCATED(ninlo)) DEALLOCATE(ninlo)
ALLOCATE(ninlo(inlati))
yrecfm = 'NLOPA'
 CALL read_surf(&
                hfiletype,yrecfm,inlopa,iresp,hdir='A')
!
kni = sum(inlopa)
!
!-----------------------------------------------------------------------
!
!*   3 Computes additional quantities used in interpolation
!      ----------------------------------------------------
!
inlati2  = nint(REAL(inlati)/2.0)
ninla    = inlati
nilen    = kni
xlop     = zlopo
xlap     = zlapo
xcoef    = zcodil
!
ninlo(:) = inlopa(:)
!
!* type of transform
IF (zlapo>89.99 .AND. abs(zlopo)<0.00001) THEN
  lrotpole = .false.
ELSE
  lrotpole = .true.
ENDIF
!
xila1=90.0*(1.0-0.5/REAL(inlati))
xilo1=0.0
xila2=-90.0*(1.0-0.5/REAL(inlati))
xilo2=360.0*(REAL(inlopa(inlati2))-1.0)/REAL(inlopa(inlati2))
!
hinterp_type = 'HORIBL'
!-----------------------------------------------------------------------
IF (lhook) CALL dr_hook('PREP_GRID_GAUSS',1,zhook_handle)
!-----------------------------------------------------------------------
!
END SUBROUTINE prep_grid_gauss