pgd_surf_atm.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###########################################################
      SUBROUTINE pgd_surf_atm (YSC, &
                               hprogram,hfile,hfiletype,ozs)
!     ###########################################################
!!
!!    PURPOSE
!!    -------
!!   This program prepares the physiographic data fields.
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson                   Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original     13/10/03
!!      A. Lemonsu      05/2009         Ajout de la clef LGARDEN pour TEB
!!      J. Escobar      11/2013         Add USE MODI_READ_NAM_PGD_CHEMISTRY
!!      B. Decharme     02/2014         Add LRM_RIVER
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surfex_n, ONLY : surfex_t
!
USE modd_surf_conf,       ONLY : cprogname
USE modd_pgd_grid,        ONLY : llatlonmask
!
USE modi_get_luout
USE modi_read_pgd_arrange_cover
USE modi_read_pgd_cover_garden
USE modi_ini_data_cover
USE modi_read_pgd_schemes
USE modi_read_nam_pgd_chemistry
USE modi_read_nam_write_cover_tex
USE modi_write_cover_tex_start
USE modi_write_cover_tex_cover
USE modi_latlon_grid
USE modi_put_pgd_grid
USE modi_latlonmask
USE modi_pgd_frac
USE modi_pgd_cover
USE modi_pgd_orography
USE modi_pgd_nature
USE modi_pgd_town
USE modi_pgd_inland_water
USE modi_pgd_sea
USE modi_pgd_dummy
USE modi_pgd_chemistry
USE modi_pgd_chemistry_snap
USE modi_write_cover_tex_end
USE modi_init_read_data_cover
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
!
IMPLICIT NONE
!
!*    0.1    Declaration of dummy arguments
!            ------------------------------
!
!
TYPE(surfex_t), INTENT(INOUT) :: ysc
!
 CHARACTER(LEN=6),     INTENT(IN)  :: hprogram ! program calling
 CHARACTER(LEN=28),    INTENT(IN)  :: hfile    ! atmospheric file name
 CHARACTER(LEN=6),     INTENT(IN)  :: hfiletype! atmospheric file type
LOGICAL,              INTENT(IN)  :: ozs      ! .true. if orography is imposed by atm. model
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
LOGICAL :: lrm_river   !delete inland river coverage. Default is false
!
INTEGER :: iluout ! logical unit of output listing file
!
REAL(KIND=JPRB) :: zhook_handle
!
!------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('PGD_SURF_ATM',0,zhook_handle)
!
lrm_river = .false.
!
 cprogname=hprogram
!
 CALL get_luout(hprogram,iluout)
!
!*    1.      Set default constant values 
!             ---------------------------
!
 CALL read_pgd_arrange_cover(hprogram,ysc%U%LWATER_TO_NATURE,ysc%U%LTOWN_TO_ROCK)
!
 CALL read_pgd_cover_garden(hprogram,ysc%U%LGARDEN)
!
 CALL init_read_data_cover(hprogram)
!
 CALL ini_data_cover(ysc%DTCO, ysc%U)
!
!*    1.2     surface schemes
 CALL read_pgd_schemes(hprogram,ysc%U%CNATURE,ysc%U%CSEA,ysc%U%CTOWN,ysc%U%CWATER)
!
!*    1.3     prints all parameters in a Latex file
 CALL read_nam_write_cover_tex(hprogram)
!
 CALL write_cover_tex_start(hprogram)
 CALL write_cover_tex_cover
!-------------------------------------------------------------------------------
!
!*    2.      Grid
!             ----
!
ALLOCATE(ysc%UG%XLAT(ysc%U%NSIZE_FULL))
ALLOCATE(ysc%UG%XLON(ysc%U%NSIZE_FULL))
ALLOCATE(ysc%UG%XMESH_SIZE(ysc%U%NSIZE_FULL))
ALLOCATE(ysc%UG%XJPDIR(ysc%U%NSIZE_FULL))
 CALL latlon_grid(ysc%UG%CGRID,ysc%UG%NGRID_PAR,ysc%U%NSIZE_FULL,iluout,&
                  ysc%UG%XGRID_PAR,ysc%UG%XLAT,ysc%UG%XLON,ysc%UG%XMESH_SIZE,ysc%UG%XJPDIR)
!
!
!*    2.3     Stores the grid in the module MODD_PGD_GRID
!
 CALL put_pgd_grid(ysc%UG%CGRID,ysc%U%NSIZE_FULL,ysc%UG%NGRID_PAR,ysc%UG%XGRID_PAR)
!
!*    2.4     mask to limit the number of input data to read
 CALL latlonmask(ysc%UG%CGRID,ysc%UG%NGRID_PAR,ysc%UG%XGRID_PAR,llatlonmask)
!
!-------------------------------------------------------------------------------
!
!*    3.      surface cover
!             -------------
!
 CALL pgd_frac(ysc%DTCO, ysc%UG, ysc%U, ysc%USS, &
               hprogram,ysc%U%LECOCLIMAP)
IF (ysc%U%LECOCLIMAP) CALL pgd_cover(ysc%DGU, ysc%DTCO, ysc%UG, ysc%U, ysc%USS, &
                                 hprogram,lrm_river)
!
!-------------------------------------------------------------------------------
!
!*    4.      Orography
!             ---------
!
 CALL pgd_orography(ysc%DGU, ysc%DTCO, ysc%UG, ysc%U, ysc%USS, &
                    hprogram,ysc%U%XSEA,ysc%U%XWATER,hfile,hfiletype,ozs)
!
!_______________________________________________________________________________
!
!*    5.      Additionnal fields for nature scheme
!             ------------------------------------
!
IF (ysc%U%NDIM_NATURE>0) CALL pgd_nature(ysc%DTCO, ysc%IM%DTI, ysc%DTZ, ysc%DGU, ysc%IM%IG, &
                                         ysc%IM%I, ysc%UG, ysc%U, ysc%USS, &
                                         hprogram,ysc%U%LECOCLIMAP)  
!_______________________________________________________________________________
!
!*    6.      Additionnal fields for town scheme
!             ----------------------------------
!
IF (ysc%U%NDIM_TOWN>0) CALL pgd_town(ysc%DTCO, ysc%DGU, ysc%UG, ysc%U, ysc%USS, &
                                     ysc%IM%DTI, ysc%TM, ysc%GDM, ysc%GRM, &
                                 hprogram,ysc%U%LECOCLIMAP,ysc%U%LGARDEN)  
!_______________________________________________________________________________
!
!*    7.      Additionnal fields for inland water scheme
!             ------------------------------------------
!
IF (ysc%U%NDIM_WATER>0) CALL pgd_inland_water(ysc%DTCO, ysc%FM%FG, ysc%FM%F, ysc%UG, ysc%U, &
                                           ysc%USS, ysc%WM%WG, ysc%WM%W, &
                                          hprogram,ysc%U%LECOCLIMAP,lrm_river)   
!_______________________________________________________________________________
!
!*    8.      Additionnal fields for sea scheme
!             ---------------------------------
!
IF (ysc%U%NDIM_SEA>0) CALL pgd_sea(ysc%DTCO, ysc%SM%DTS, ysc%SM%SG, ysc%SM%S, ysc%UG, ysc%U, ysc%USS, &
                               hprogram)  
!
!_______________________________________________________________________________
!
!*    9.      Dummy fields
!             ------------
!
 CALL pgd_dummy(ysc%DTCO, ysc%DUU, ysc%UG, ysc%U, ysc%USS, &
                hprogram)
!_______________________________________________________________________________
!
!*   10.      Chemical Emission fields
!             ------------------------
!
 CALL read_nam_pgd_chemistry(hprogram,ysc%CHU%CCH_EMIS)
IF (ysc%CHU%CCH_EMIS=='SNAP') THEN
  CALL pgd_chemistry_snap(ysc%CHN, ysc%DTCO, ysc%UG, ysc%U, ysc%USS, &
                          hprogram,ysc%CHU%LCH_EMIS)
ELSE IF (ysc%CHU%CCH_EMIS=='AGGR') THEN
  CALL pgd_chemistry(ysc%CHE, ysc%DTCO, ysc%UG, ysc%U, ysc%USS, &
                     hprogram,ysc%CHU%LCH_EMIS)
ENDIF
!_______________________________________________________________________________
!
!*   11.     Writing in cover latex file
!            ---------------------------
!
 CALL write_cover_tex_end(hprogram)
IF (lhook) CALL dr_hook('PGD_SURF_ATM',1,zhook_handle)
!_______________________________________________________________________________
!
END SUBROUTINE pgd_surf_atm